cmake/modules/CrossCompile.cmake

   1 include(LLVMExternalProjectUtils)
   2
   3 function(llvm_create_cross_target_internal target_name toolchain buildtype)
   4
   5   if(NOT DEFINED LLVM_${target_name}_BUILD)
   6     set(LLVM_${target_name}_BUILD "${CMAKE_BINARY_DIR}/${target_name}")
   7     set(LLVM_${target_name}_BUILD ${LLVM_${target_name}_BUILD} PARENT_SCOPE)
   8     message(STATUS "Setting native build dir to " ${LLVM_${target_name}_BUILD})
   9   endif(NOT DEFINED LLVM_${target_name}_BUILD)
  10
  11   if (EXISTS ${LLVM_MAIN_SRC_DIR}/cmake/platforms/${toolchain}.cmake)
  12     set(CROSS_TOOLCHAIN_FLAGS_INIT
  13       -DCMAKE_TOOLCHAIN_FILE=\"${LLVM_MAIN_SRC_DIR}/cmake/platforms/${toolchain}.cmake\")
  14   else()
  15     set(CROSS_TOOLCHAIN_FLAGS_INIT
  16       -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
  17       -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
  18       )
  19   endif()
  20   set(CROSS_TOOLCHAIN_FLAGS_${target_name} ${CROSS_TOOLCHAIN_FLAGS_INIT}
  21     CACHE STRING "Toolchain configuration for ${target_name}")
  22
  23   if (buildtype)
  24     set(build_type_flags "-DCMAKE_BUILD_TYPE=${buildtype}")
  25   endif()
  26   if (LLVM_USE_LINKER AND NOT CMAKE_CROSSCOMPILING)
  27     set(linker_flag "-DLLVM_USE_LINKER=${LLVM_USE_LINKER}")
  28   endif()
  29   if (LLVM_EXTERNAL_CLANG_SOURCE_DIR)
  30     # Propagate LLVM_EXTERNAL_CLANG_SOURCE_DIR so that clang-tblgen can be built
  31     set(external_clang_dir "-DLLVM_EXTERNAL_CLANG_SOURCE_DIR=${LLVM_EXTERNAL_CLANG_SOURCE_DIR}")
  32   endif()
  33
  34   add_custom_command(OUTPUT ${LLVM_${target_name}_BUILD}
  35     COMMAND ${CMAKE_COMMAND} -E make_directory ${LLVM_${target_name}_BUILD}
  36     COMMENT "Creating ${LLVM_${target_name}_BUILD}...")
  37
  38   add_custom_target(CREATE_LLVM_${target_name}
  39                     DEPENDS ${LLVM_${target_name}_BUILD})
  40
  41   # Escape semicolons in the targets list so that cmake doesn't expand
  42   # them to spaces.
  43   string(REPLACE ";" "$<SEMICOLON>" targets_to_build_arg
  44          "${LLVM_TARGETS_TO_BUILD}")
  45   string(REPLACE ";" "$<SEMICOLON>" experimental_targets_to_build_arg
  46          "${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD}")
  47
  48   add_custom_command(OUTPUT ${LLVM_${target_name}_BUILD}/CMakeCache.txt
  49     COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}"
  50         -DCMAKE_MAKE_PROGRAM="${CMAKE_MAKE_PROGRAM}"
  51         ${CROSS_TOOLCHAIN_FLAGS_${target_name}} ${CMAKE_SOURCE_DIR}
  52         -DLLVM_TARGET_IS_CROSSCOMPILE_HOST=TRUE
  53         -DLLVM_TARGETS_TO_BUILD="${targets_to_build_arg}"
  54         -DLLVM_EXPERIMENTAL_TARGETS_TO_BUILD="${experimental_targets_to_build_arg}"
  55         -DLLVM_DEFAULT_TARGET_TRIPLE="${TARGET_TRIPLE}"
  56         -DLLVM_TARGET_ARCH="${LLVM_TARGET_ARCH}"
  57         -DLLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN="${LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN}"
  58         ${build_type_flags} ${linker_flag} ${external_clang_dir}
  59     WORKING_DIRECTORY ${LLVM_${target_name}_BUILD}
  60     DEPENDS CREATE_LLVM_${target_name}
  61     COMMENT "Configuring ${target_name} LLVM...")
  62
  63   add_custom_target(CONFIGURE_LLVM_${target_name}
  64                     DEPENDS ${LLVM_${target_name}_BUILD}/CMakeCache.txt)
  65
  66 endfunction()
  67
  68 function(llvm_create_cross_target target_name sysroot)
  69   llvm_create_cross_target_internal(${target_name} ${sysroot} ${CMAKE_BUILD_TYPE})
  70 endfunction()
  71
  72 # Sets up a native build for a tool, used e.g. for cross-compilation and
  73 # LLVM_OPTIMIZED_TABLEGEN. Always builds in Release.
  74 # - target: The target to build natively
  75 # - output_path_var: A variable name which receives the path to the built target
  76 # - DEPENDS: Any additional dependencies for the target
  77 function(build_native_tool target output_path_var)
  78   cmake_parse_arguments(ARG "" "" "DEPENDS" ${ARGN})
  79
  80   if(CMAKE_CONFIGURATION_TYPES)
  81     set(output_path "${LLVM_NATIVE_BUILD}/Release/bin/${target}")
  82   else()
  83     set(output_path "${LLVM_NATIVE_BUILD}/bin/${target}")
  84   endif()
  85
  86   llvm_ExternalProject_BuildCmd(build_cmd ${target} ${LLVM_NATIVE_BUILD}
  87                                 CONFIGURATION Release)
  88   add_custom_command(OUTPUT "${output_path}"
  89                      COMMAND ${build_cmd}
  90                      DEPENDS CONFIGURE_LLVM_NATIVE ${ARG_DEPENDS}
  91                      WORKING_DIRECTORY "${LLVM_NATIVE_BUILD}"
  92                      COMMENT "Building native ${target}..."
  93                      USES_TERMINAL)
  94   set(${output_path_var} "${output_path}" PARENT_SCOPE)
  95 endfunction()
  96
  97 llvm_create_cross_target_internal(NATIVE "" Release)