cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(CheckCompilerVersion)
  10 include(HandleLLVMStdlib)
  11 include(CheckCCompilerFlag)
  12 include(CheckCXXCompilerFlag)
  13 include(CheckSymbolExists)
  14
  15 if(CMAKE_LINKER MATCHES "lld-link\.exe" OR (WIN32 AND LLVM_USE_LINKER STREQUAL "lld") OR LLVM_ENABLE_LLD)
  16   set(LINKER_IS_LLD_LINK TRUE)
  17 else()
  18   set(LINKER_IS_LLD_LINK FALSE)
  19 endif()
  20
  21 set(LLVM_CXX_STD_default "c++11")
  22 # Preserve behaviour of legacy cache variables
  23 if (LLVM_ENABLE_CXX1Y)
  24   set(LLVM_CXX_STD_default "c++1y")
  25 elseif (LLVM_ENABLE_CXX1Z)
  26   set(LLVM_CXX_STD_default "c++1z")
  27 endif()
  28 set(LLVM_CXX_STD ${LLVM_CXX_STD_default}
  29     CACHE STRING "C++ standard to use for compilation.")
  30
  31 set(LLVM_ENABLE_LTO OFF CACHE STRING "Build LLVM with LTO. May be specified as Thin or Full to use a particular kind of LTO")
  32 string(TOUPPER "${LLVM_ENABLE_LTO}" uppercase_LLVM_ENABLE_LTO)
  33
  34 # Ninja Job Pool support
  35 # The following only works with the Ninja generator in CMake >= 3.0.
  36 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  37   "Define the maximum number of concurrent compilation jobs (Ninja only).")
  38 if(LLVM_PARALLEL_COMPILE_JOBS)
  39   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
  40     message(WARNING "Job pooling is only available with Ninja generators.")
  41   else()
  42     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  43     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  44   endif()
  45 endif()
  46
  47 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  48   "Define the maximum number of concurrent link jobs (Ninja only).")
  49 if(CMAKE_MAKE_PROGRAM MATCHES "ninja")
  50   if(NOT LLVM_PARALLEL_LINK_JOBS AND uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
  51     message(STATUS "ThinLTO provides its own parallel linking - limiting parallel link jobs to 2.")
  52     set(LLVM_PARALLEL_LINK_JOBS "2")
  53   endif()
  54   if(LLVM_PARALLEL_LINK_JOBS)
  55     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  56     set(CMAKE_JOB_POOL_LINK link_job_pool)
  57   endif()
  58 elseif(LLVM_PARALLEL_LINK_JOBS)
  59   message(WARNING "Job pooling is only available with Ninja generators.")
  60 endif()
  61
  62 if( LLVM_ENABLE_ASSERTIONS )
  63   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  64   if( NOT MSVC )
  65     add_definitions( -D_DEBUG )
  66   endif()
  67   # On non-Debug builds cmake automatically defines NDEBUG, so we
  68   # explicitly undefine it:
  69   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  70     add_definitions( -UNDEBUG )
  71     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  72     foreach (flags_var_to_scrub
  73         CMAKE_CXX_FLAGS_RELEASE
  74         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  75         CMAKE_CXX_FLAGS_MINSIZEREL
  76         CMAKE_C_FLAGS_RELEASE
  77         CMAKE_C_FLAGS_RELWITHDEBINFO
  78         CMAKE_C_FLAGS_MINSIZEREL)
  79       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  80         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  81     endforeach()
  82   endif()
  83 endif()
  84
  85 if(LLVM_ENABLE_EXPENSIVE_CHECKS)
  86   add_definitions(-DEXPENSIVE_CHECKS)
  87   add_definitions(-D_GLIBCXX_DEBUG)
  88 endif()
  89
  90 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
  91
  92 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
  93   if( LLVM_ENABLE_ASSERTIONS )
  94     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  95   endif()
  96 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
  97   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  98 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
  99   # We don't need to do anything special to turn off ABI breaking checks.
 100 elseif( NOT DEFINED LLVM_ABI_BREAKING_CHECKS )
 101   # Treat LLVM_ABI_BREAKING_CHECKS like "FORCE_OFF" when it has not been
 102   # defined.
 103 else()
 104   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
 105 endif()
 106
 107 if( LLVM_REVERSE_ITERATION )
 108   set( LLVM_ENABLE_REVERSE_ITERATION 1 )
 109 endif()
 110
 111 if(WIN32)
 112   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 113   if(CYGWIN)
 114     set(LLVM_ON_WIN32 0)
 115     set(LLVM_ON_UNIX 1)
 116   else(CYGWIN)
 117     set(LLVM_ON_WIN32 1)
 118     set(LLVM_ON_UNIX 0)
 119   endif(CYGWIN)
 120 else(WIN32)
 121   if(FUCHSIA OR UNIX)
 122     set(LLVM_ON_WIN32 0)
 123     set(LLVM_ON_UNIX 1)
 124     if(APPLE OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 125       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 126     else()
 127       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
 128     endif()
 129   else(FUCHSIA OR UNIX)
 130     MESSAGE(SEND_ERROR "Unable to determine platform")
 131   endif(FUCHSIA OR UNIX)
 132 endif(WIN32)
 133
 134 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 135 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 136
 137 # We use *.dylib rather than *.so on darwin.
 138 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 139
 140 if(APPLE)
 141   if(LLVM_ENABLE_LLD AND LLVM_ENABLE_LTO)
 142     message(FATAL_ERROR "lld does not support LTO on Darwin")
 143   endif()
 144   # Darwin-specific linker flags for loadable modules.
 145   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 146 endif()
 147
 148 if(${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 149   if(NOT LLVM_BUILD_32_BITS)
 150     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 151       append("-q64" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 152     else()
 153       append("-maix64" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 154     endif()
 155     set(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> -X64 qc <TARGET> <LINK_FLAGS> <OBJECTS>")
 156     set(CMAKE_CXX_ARCHIVE_APPEND "<CMAKE_AR> -X64 q  <TARGET> <LINK_FLAGS> <OBJECTS>")
 157     set(CMAKE_C_ARCHIVE_FINISH "<CMAKE_RANLIB> -X64 <TARGET>")
 158     set(CMAKE_CXX_ARCHIVE_FINISH "<CMAKE_RANLIB> -X64 <TARGET>")
 159   endif()
 160   # -fPIC does not enable the large code model for GCC on AIX but does for XL.
 161   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 162     append("-mcmodel=large" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 163   elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 164     # XL generates a small number of relocations not of the large model, -bbigtoc is needed.
 165     append("-Wl,-bbigtoc"
 166            CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 167   endif()
 168 endif()
 169
 170 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 171 # build might work on ELF but fail on MachO/COFF.
 172 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|FreeBSD|OpenBSD|DragonFly|AIX" OR
 173         WIN32 OR CYGWIN) AND
 174    NOT LLVM_USE_SANITIZER)
 175   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 176 endif()
 177
 178 # Pass -Wl,-z,nodelete. This makes sure our shared libraries are not unloaded
 179 # by dlclose(). We need that since the CLI API relies on cross-references
 180 # between global objects which became horribly broken when one of the libraries
 181 # is unloaded.
 182 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 183   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,nodelete")
 184   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-z,nodelete")
 185 endif()
 186
 187
 188 function(append value)
 189   foreach(variable ${ARGN})
 190     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 191   endforeach(variable)
 192 endfunction()
 193
 194 function(append_if condition value)
 195   if (${condition})
 196     foreach(variable ${ARGN})
 197       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 198     endforeach(variable)
 199   endif()
 200 endfunction()
 201
 202 macro(add_flag_if_supported flag name)
 203   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 204   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 205   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 206   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 207 endmacro()
 208
 209 function(add_flag_or_print_warning flag name)
 210   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 211   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 212   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 213     message(STATUS "Building with ${flag}")
 214     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 215     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 216     set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} ${flag}" PARENT_SCOPE)
 217   else()
 218     message(WARNING "${flag} is not supported.")
 219   endif()
 220 endfunction()
 221
 222 if( LLVM_ENABLE_LLD )
 223         if ( LLVM_USE_LINKER )
 224                 message(FATAL_ERROR "LLVM_ENABLE_LLD and LLVM_USE_LINKER can't be set at the same time")
 225         endif()
 226         set(LLVM_USE_LINKER "lld")
 227 endif()
 228
 229 if( LLVM_USE_LINKER )
 230   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 231   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fuse-ld=${LLVM_USE_LINKER}")
 232   check_cxx_source_compiles("int main() { return 0; }" CXX_SUPPORTS_CUSTOM_LINKER)
 233   if ( NOT CXX_SUPPORTS_CUSTOM_LINKER )
 234           message(FATAL_ERROR "Host compiler does not support '-fuse-ld=${LLVM_USE_LINKER}'")
 235   endif()
 236   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 237   append("-fuse-ld=${LLVM_USE_LINKER}"
 238     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 239 endif()
 240
 241 if( LLVM_ENABLE_PIC )
 242   if( XCODE )
 243     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 244     # know how to disable this, so just force ENABLE_PIC off for now.
 245     message(WARNING "-fPIC not supported with Xcode.")
 246   elseif( WIN32 OR CYGWIN)
 247     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 248   else()
 249     add_flag_or_print_warning("-fPIC" FPIC)
 250   endif()
 251 endif()
 252
 253 if(NOT WIN32 AND NOT CYGWIN AND NOT (${CMAKE_SYSTEM_NAME} MATCHES "AIX" AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU"))
 254   # MinGW warns if -fvisibility-inlines-hidden is used.
 255   # GCC on AIX warns if -fvisibility-inlines-hidden is used.
 256   check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 257   append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 258 endif()
 259
 260 if(CMAKE_SIZEOF_VOID_P EQUAL 8 AND MINGW)
 261   add_definitions( -D_FILE_OFFSET_BITS=64 )
 262 endif()
 263
 264 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 265   # TODO: support other platforms and toolchains.
 266   if( LLVM_BUILD_32_BITS )
 267     message(STATUS "Building 32 bits executables and libraries.")
 268     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 269     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -m32")
 270     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 271     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 272     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 273
 274     # FIXME: CMAKE_SIZEOF_VOID_P is still 8
 275     add_definitions(-D_LARGEFILE_SOURCE)
 276     add_definitions(-D_FILE_OFFSET_BITS=64)
 277   endif( LLVM_BUILD_32_BITS )
 278 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 279
 280 # If building on a GNU specific 32-bit system, make sure off_t is 64 bits
 281 # so that off_t can stored offset > 2GB.
 282 # Android until version N (API 24) doesn't support it.
 283 if (ANDROID AND (ANDROID_NATIVE_API_LEVEL LESS 24))
 284   set(LLVM_FORCE_SMALLFILE_FOR_ANDROID TRUE)
 285 endif()
 286 if( CMAKE_SIZEOF_VOID_P EQUAL 4 AND NOT LLVM_FORCE_SMALLFILE_FOR_ANDROID)
 287   # FIXME: It isn't handled in LLVM_BUILD_32_BITS.
 288   add_definitions( -D_LARGEFILE_SOURCE )
 289   add_definitions( -D_FILE_OFFSET_BITS=64 )
 290 endif()
 291
 292 if( XCODE )
 293   # For Xcode enable several build settings that correspond to
 294   # many warnings that are on by default in Clang but are
 295   # not enabled for historical reasons.  For versions of Xcode
 296   # that do not support these options they will simply
 297   # be ignored.
 298   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 299   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 300   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 301   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 302   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 303   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 304   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 305   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 306   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 307   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 308   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 309   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 310   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 311   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 312   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 313 endif()
 314
 315 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 316 # to use.
 317 if( MSVC_IDE )
 318   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 319     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 320   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 321     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 322       add_definitions( /MP )
 323     else()
 324       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 325       add_definitions( /MP${LLVM_COMPILER_JOBS} )
 326     endif()
 327   else()
 328     message(STATUS "Parallel compilation disabled")
 329   endif()
 330 endif()
 331
 332 # set stack reserved size to ~10MB
 333 if(MSVC)
 334   # CMake previously automatically set this value for MSVC builds, but the
 335   # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 336   # value (1 MB) which is not enough for us in tasks such as parsing recursive
 337   # C++ templates in Clang.
 338   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 339 elseif(MINGW) # FIXME: Also cygwin?
 340   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,16777216")
 341
 342   # Pass -mbig-obj to mingw gas on Win64. COFF has a 2**16 section limit, and
 343   # on Win64, every COMDAT function creates at least 3 sections: .text, .pdata,
 344   # and .xdata.
 345   if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 346     append("-Wa,-mbig-obj" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 347   endif()
 348 endif()
 349
 350 if( MSVC )
 351   if( CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.0 )
 352     # For MSVC 2013, disable iterator null pointer checking in debug mode,
 353     # especially so std::equal(nullptr, nullptr, nullptr) will not assert.
 354     add_definitions("-D_DEBUG_POINTER_IMPL=")
 355   endif()
 356
 357   include(ChooseMSVCCRT)
 358
 359   if( MSVC11 )
 360     add_definitions(-D_VARIADIC_MAX=10)
 361   endif()
 362
 363   # Add definitions that make MSVC much less annoying.
 364   add_definitions(
 365     # For some reason MS wants to deprecate a bunch of standard functions...
 366     -D_CRT_SECURE_NO_DEPRECATE
 367     -D_CRT_SECURE_NO_WARNINGS
 368     -D_CRT_NONSTDC_NO_DEPRECATE
 369     -D_CRT_NONSTDC_NO_WARNINGS
 370     -D_SCL_SECURE_NO_DEPRECATE
 371     -D_SCL_SECURE_NO_WARNINGS
 372     )
 373
 374   # Tell MSVC to use the Unicode version of the Win32 APIs instead of ANSI.
 375   add_definitions(
 376     -DUNICODE
 377     -D_UNICODE
 378   )
 379
 380   if (LLVM_ENABLE_WERROR)
 381     append("/WX" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 382   endif (LLVM_ENABLE_WERROR)
 383
 384   append("/Zc:inline" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 385
 386   # Allow users to request PDBs in release mode. CMake offeres the
 387   # RelWithDebInfo configuration, but it uses different optimization settings
 388   # (/Ob1 vs /Ob2 or -O2 vs -O3). LLVM provides this flag so that users can get
 389   # PDBs without changing codegen.
 390   option(LLVM_ENABLE_PDB OFF)
 391   if (LLVM_ENABLE_PDB AND uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
 392     append("/Zi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 393     # /DEBUG disables linker GC and ICF, but we want those in Release mode.
 394     append("/DEBUG /OPT:REF /OPT:ICF"
 395           CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS
 396           CMAKE_SHARED_LINKER_FLAGS)
 397   endif()
 398
 399   # /Zc:strictStrings is incompatible with VS12's (Visual Studio 2013's)
 400   # debug mode headers. Instead of only enabling them in VS2013's debug mode,
 401   # we'll just enable them for Visual Studio 2015 (VS 14, MSVC_VERSION 1900)
 402   # and up.
 403   if (NOT (MSVC_VERSION LESS 1900))
 404     # Disable string literal const->non-const type conversion.
 405     # "When specified, the compiler requires strict const-qualification
 406     # conformance for pointers initialized by using string literals."
 407     append("/Zc:strictStrings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 408   endif(NOT (MSVC_VERSION LESS 1900))
 409
 410   # "Generate Intrinsic Functions".
 411   append("/Oi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 412
 413   # "Enforce type conversion rules".
 414   append("/Zc:rvalueCast" CMAKE_CXX_FLAGS)
 415
 416   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND NOT LLVM_ENABLE_LTO)
 417     # clang-cl and cl by default produce non-deterministic binaries because
 418     # link.exe /incremental requires a timestamp in the .obj file.  clang-cl
 419     # has the flag /Brepro to force deterministic binaries. We want to pass that
 420     # whenever you're building with clang unless you're passing /incremental
 421     # or using LTO (/Brepro with LTO would result in a warning about the flag
 422     # being unused, because we're not generating object files).
 423     # This checks CMAKE_CXX_COMPILER_ID in addition to check_cxx_compiler_flag()
 424     # because cl.exe does not emit an error on flags it doesn't understand,
 425     # letting check_cxx_compiler_flag() claim it understands all flags.
 426     check_cxx_compiler_flag("/Brepro" SUPPORTS_BREPRO)
 427     if (SUPPORTS_BREPRO)
 428       # Check if /INCREMENTAL is passed to the linker and complain that it
 429       # won't work with /Brepro.
 430       string(TOUPPER "${CMAKE_EXE_LINKER_FLAGS}" upper_exe_flags)
 431       string(TOUPPER "${CMAKE_MODULE_LINKER_FLAGS}" upper_module_flags)
 432       string(TOUPPER "${CMAKE_SHARED_LINKER_FLAGS}" upper_shared_flags)
 433
 434       string(FIND "${upper_exe_flags} ${upper_module_flags} ${upper_shared_flags}"
 435         "/INCREMENTAL" linker_flag_idx)
 436
 437       if (${linker_flag_idx} GREATER -1)
 438         message(WARNING "/Brepro not compatible with /INCREMENTAL linking - builds will be non-deterministic")
 439       else()
 440         append("/Brepro" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 441       endif()
 442     endif()
 443   endif()
 444
 445 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 446   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 447   append_if(LLVM_ENABLE_WERROR "-Wno-error" CMAKE_REQUIRED_FLAGS)
 448   add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 449   add_flag_if_supported("-Werror=unguarded-availability-new" WERROR_UNGUARDED_AVAILABILITY_NEW)
 450   check_cxx_compiler_flag("-std=${LLVM_CXX_STD}" CXX_SUPPORTS_CXX_STD)
 451   if (CXX_SUPPORTS_CXX_STD)
 452    if (CYGWIN OR MINGW)
 453       # MinGW and Cygwin are a bit stricter and lack things like
 454       # 'strdup', 'stricmp', etc in c++11 mode.
 455       string(REPLACE "c++" "gnu++" gnu_LLVM_CXX_STD "${LLVM_CXX_STD}")
 456       append("-std=${gnu_LLVM_CXX_STD}" CMAKE_CXX_FLAGS)
 457     else()
 458       append("-std=${LLVM_CXX_STD}" CMAKE_CXX_FLAGS)
 459     endif()
 460   else()
 461     message(FATAL_ERROR "The host compiler does not support '-std=${LLVM_CXX_STD}'.")
 462   endif()
 463   if (LLVM_ENABLE_MODULES)
 464     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 465     set(module_flags "-fmodules -fmodules-cache-path=${PROJECT_BINARY_DIR}/module.cache")
 466     if (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 467       # On Darwin -fmodules does not imply -fcxx-modules.
 468       set(module_flags "${module_flags} -fcxx-modules")
 469     endif()
 470     if (LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY)
 471       set(module_flags "${module_flags} -Xclang -fmodules-local-submodule-visibility")
 472     endif()
 473     if (LLVM_ENABLE_MODULE_DEBUGGING AND
 474         ((uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG") OR
 475          (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")))
 476       set(module_flags "${module_flags} -gmodules")
 477     endif()
 478     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${module_flags}")
 479
 480     # Check that we can build code with modules enabled, and that repeatedly
 481     # including <cassert> still manages to respect NDEBUG properly.
 482     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 483                                #include <cassert>
 484                                #define NDEBUG
 485                                #include <cassert>
 486                                int main() { assert(this code is not compiled); }"
 487                                CXX_SUPPORTS_MODULES)
 488     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 489     if (CXX_SUPPORTS_MODULES)
 490       append("${module_flags}" CMAKE_CXX_FLAGS)
 491     else()
 492       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 493     endif()
 494   endif(LLVM_ENABLE_MODULES)
 495 endif( MSVC )
 496
 497 if (MSVC)
 498   if (NOT CLANG_CL)
 499     set(msvc_warning_flags
 500       # Disabled warnings.
 501       -wd4141 # Suppress ''modifier' : used more than once' (because of __forceinline combined with inline)
 502       -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 503       -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 504       -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 505       -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 506       -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 507       -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 508       -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 509       -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 510       -wd4355 # Suppress ''this' : used in base member initializer list'
 511       -wd4456 # Suppress 'declaration of 'var' hides local variable'
 512       -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 513       -wd4458 # Suppress 'declaration of 'var' hides class member'
 514       -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 515       -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 516       -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 517       -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 518       -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 519       -wd4100 # Suppress 'unreferenced formal parameter'
 520       -wd4127 # Suppress 'conditional expression is constant'
 521       -wd4512 # Suppress 'assignment operator could not be generated'
 522       -wd4505 # Suppress 'unreferenced local function has been removed'
 523       -wd4610 # Suppress '<class> can never be instantiated'
 524       -wd4510 # Suppress 'default constructor could not be generated'
 525       -wd4702 # Suppress 'unreachable code'
 526       -wd4245 # Suppress 'signed/unsigned mismatch'
 527       -wd4706 # Suppress 'assignment within conditional expression'
 528       -wd4310 # Suppress 'cast truncates constant value'
 529       -wd4701 # Suppress 'potentially uninitialized local variable'
 530       -wd4703 # Suppress 'potentially uninitialized local pointer variable'
 531       -wd4389 # Suppress 'signed/unsigned mismatch'
 532       -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
 533       -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
 534       -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
 535       -wd4577 # Suppress 'noexcept used with no exception handling mode specified; termination on exception is not guaranteed'
 536       -wd4091 # Suppress 'typedef: ignored on left of '' when no variable is declared'
 537           # C4592 is disabled because of false positives in Visual Studio 2015
 538           # Update 1. Re-evaluate the usefulness of this diagnostic with Update 2.
 539       -wd4592 # Suppress ''var': symbol will be dynamically initialized (implementation limitation)
 540       -wd4319 # Suppress ''operator' : zero extending 'type' to 'type' of greater size'
 541           # C4709 is disabled because of a bug with Visual Studio 2017 as of
 542           # v15.8.8. Re-evaluate the usefulness of this diagnostic when the bug
 543           # is fixed.
 544       -wd4709 # Suppress comma operator within array index expression
 545
 546       # Ideally, we'd like this warning to be enabled, but MSVC 2013 doesn't
 547       # support the 'aligned' attribute in the way that clang sources requires (for
 548       # any code that uses the LLVM_ALIGNAS macro), so this is must be disabled to
 549       # avoid unwanted alignment warnings.
 550       # When we switch to requiring a version of MSVC that supports the 'alignas'
 551       # specifier (MSVC 2015?) this warning can be re-enabled.
 552       -wd4324 # Suppress 'structure was padded due to __declspec(align())'
 553
 554       # Promoted warnings.
 555       -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 556
 557       # Promoted warnings to errors.
 558       -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 559       )
 560   endif(NOT CLANG_CL)
 561
 562   # Enable warnings
 563   if (LLVM_ENABLE_WARNINGS)
 564     # Put /W4 in front of all the -we flags. cl.exe doesn't care, but for
 565     # clang-cl having /W4 after the -we flags will re-enable the warnings
 566     # disabled by -we.
 567     set(msvc_warning_flags "/W4 ${msvc_warning_flags}")
 568     # CMake appends /W3 by default, and having /W3 followed by /W4 will result in
 569     # cl : Command line warning D9025 : overriding '/W3' with '/W4'.  Since this is
 570     # a command line warning and not a compiler warning, it cannot be suppressed except
 571     # by fixing the command line.
 572     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 573     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 574
 575     if (LLVM_ENABLE_PEDANTIC)
 576       # No MSVC equivalent available
 577     endif (LLVM_ENABLE_PEDANTIC)
 578   endif (LLVM_ENABLE_WARNINGS)
 579
 580   foreach(flag ${msvc_warning_flags})
 581     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 582   endforeach(flag)
 583 endif (MSVC)
 584
 585 if (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 586
 587   # Don't add -Wall for clang-cl, because it maps -Wall to -Weverything for
 588   # MSVC compatibility.  /W4 is added above instead.
 589   if (NOT CLANG_CL)
 590     append("-Wall" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 591   endif()
 592
 593   append("-Wextra -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 594   append("-Wcast-qual" CMAKE_CXX_FLAGS)
 595
 596   # Turn off missing field initializer warnings for gcc to avoid noise from
 597   # false positives with empty {}. Turn them on otherwise (they're off by
 598   # default for clang).
 599   check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 600   if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 601     if (CMAKE_COMPILER_IS_GNUCXX)
 602       append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 603     else()
 604       append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 605     endif()
 606   endif()
 607
 608   if (LLVM_ENABLE_PEDANTIC AND LLVM_COMPILER_IS_GCC_COMPATIBLE)
 609     append("-pedantic" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 610     append("-Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 611   endif()
 612
 613   add_flag_if_supported("-Wimplicit-fallthrough" IMPLICIT_FALLTHROUGH_FLAG)
 614   add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 615   append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 616   append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 617
 618   # Disable -Wclass-memaccess, a C++-only warning from GCC 8 that fires on
 619   # LLVM's ADT classes.
 620   check_cxx_compiler_flag("-Wclass-memaccess" CXX_SUPPORTS_CLASS_MEMACCESS_FLAG)
 621   append_if(CXX_SUPPORTS_CLASS_MEMACCESS_FLAG "-Wno-class-memaccess" CMAKE_CXX_FLAGS)
 622
 623   # The LLVM libraries have no stable C++ API, so -Wnoexcept-type is not useful.
 624   check_cxx_compiler_flag("-Wnoexcept-type" CXX_SUPPORTS_NOEXCEPT_TYPE_FLAG)
 625   append_if(CXX_SUPPORTS_NOEXCEPT_TYPE_FLAG "-Wno-noexcept-type" CMAKE_CXX_FLAGS)
 626
 627   # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 628   # If it does, don't add it. So it won't be added on clang 3.4 and older.
 629   # This also catches cases when -Wnon-virtual-dtor isn't supported by
 630   # the compiler at all.  This flag is not activated for gcc since it will
 631   # incorrectly identify a protected non-virtual base when there is a friend
 632   # declaration. Don't activate this in general on Windows as this warning has
 633   # too many false positives on COM-style classes, which are destroyed with
 634   # Release() (PR32286).
 635   if (NOT CMAKE_COMPILER_IS_GNUCXX AND NOT WIN32)
 636     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 637     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 638     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 639                                class derived final : public base { public: ~derived();};
 640                                int main() { return 0; }"
 641                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 642     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 643     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 644               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 645   endif()
 646
 647   # Enable -Wdelete-non-virtual-dtor if available.
 648   add_flag_if_supported("-Wdelete-non-virtual-dtor" DELETE_NON_VIRTUAL_DTOR_FLAG)
 649
 650   # Check if -Wcomment is OK with an // comment ending with '\' if the next
 651   # line is also a // comment.
 652   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 653   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 654   CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 655                           C_WCOMMENT_ALLOWS_LINE_WRAP)
 656   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 657   if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 658     append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 659   endif()
 660
 661   # Enable -Wstring-conversion to catch misuse of string literals.
 662   add_flag_if_supported("-Wstring-conversion" STRING_CONVERSION_FLAG)
 663 endif (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 664
 665 if (LLVM_COMPILER_IS_GCC_COMPATIBLE AND NOT LLVM_ENABLE_WARNINGS)
 666   append("-w" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 667 endif()
 668
 669 macro(append_common_sanitizer_flags)
 670   if (NOT MSVC)
 671     # Append -fno-omit-frame-pointer and turn on debug info to get better
 672     # stack traces.
 673     add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 674     if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 675         NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 676       add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 677     endif()
 678     # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 679     if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND LLVM_OPTIMIZE_SANITIZED_BUILDS)
 680       add_flag_if_supported("-O1" O1)
 681     endif()
 682   elseif (CLANG_CL)
 683     # Keep frame pointers around.
 684     append("/Oy-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 685     if (LINKER_IS_LLD_LINK)
 686       # Use DWARF debug info with LLD.
 687       append("-gdwarf" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 688     else()
 689       # Enable codeview otherwise.
 690       append("/Z7" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 691     endif()
 692     # Always ask the linker to produce symbols with asan.
 693     append("-debug" CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 694   endif()
 695 endmacro()
 696
 697 # Turn on sanitizers if necessary.
 698 if(LLVM_USE_SANITIZER)
 699   if (LLVM_ON_UNIX)
 700     if (LLVM_USE_SANITIZER STREQUAL "Address")
 701       append_common_sanitizer_flags()
 702       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 703     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 704       append_common_sanitizer_flags()
 705       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 706       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 707         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 708       endif()
 709     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 710       append_common_sanitizer_flags()
 711       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 712               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 713     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 714       append_common_sanitizer_flags()
 715       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 716     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
 717             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
 718       append_common_sanitizer_flags()
 719       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 720               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 721     elseif (LLVM_USE_SANITIZER STREQUAL "Leaks")
 722       append_common_sanitizer_flags()
 723       append("-fsanitize=leak" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 724     else()
 725       message(FATAL_ERROR "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 726     endif()
 727   elseif(MSVC)
 728     if (LLVM_USE_SANITIZER STREQUAL "Address")
 729       append_common_sanitizer_flags()
 730       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 731     else()
 732       message(FATAL_ERROR "This sanitizer not yet supported in the MSVC environment: ${LLVM_USE_SANITIZER}")
 733     endif()
 734   else()
 735     message(FATAL_ERROR "LLVM_USE_SANITIZER is not supported on this platform.")
 736   endif()
 737   if (LLVM_USE_SANITIZER MATCHES "(Undefined;)?Address(;Undefined)?")
 738     add_flag_if_supported("-fsanitize-address-use-after-scope"
 739                           FSANITIZE_USE_AFTER_SCOPE_FLAG)
 740   endif()
 741   if (LLVM_USE_SANITIZE_COVERAGE)
 742     append("-fsanitize=fuzzer-no-link" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 743   endif()
 744   if (LLVM_USE_SANITIZER MATCHES ".*Undefined.*")
 745     set(BLACKLIST_FILE "${CMAKE_SOURCE_DIR}/utils/sanitizers/ubsan_blacklist.txt")
 746     if (EXISTS "${BLACKLIST_FILE}")
 747       append("-fsanitize-blacklist=${BLACKLIST_FILE}"
 748              CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 749     endif()
 750   endif()
 751 endif()
 752
 753 # Turn on -gsplit-dwarf if requested
 754 if(LLVM_USE_SPLIT_DWARF)
 755   add_definitions("-gsplit-dwarf")
 756 endif()
 757
 758 add_definitions( -D__STDC_CONSTANT_MACROS )
 759 add_definitions( -D__STDC_FORMAT_MACROS )
 760 add_definitions( -D__STDC_LIMIT_MACROS )
 761
 762 # clang and gcc don't default-print colored diagnostics when invoked from Ninja.
 763 if (UNIX AND
 764     CMAKE_GENERATOR STREQUAL "Ninja" AND
 765     (CMAKE_CXX_COMPILER_ID MATCHES "Clang" OR
 766      (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND
 767       NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.9))))
 768   append("-fdiagnostics-color" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 769 endif()
 770
 771 # lld doesn't print colored diagnostics when invoked from Ninja
 772 if (UNIX AND CMAKE_GENERATOR STREQUAL "Ninja")
 773   include(CheckLinkerFlag)
 774   check_linker_flag("-Wl,--color-diagnostics" LINKER_SUPPORTS_COLOR_DIAGNOSTICS)
 775   append_if(LINKER_SUPPORTS_COLOR_DIAGNOSTICS "-Wl,--color-diagnostics"
 776     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 777 endif()
 778
 779 # Add flags for add_dead_strip().
 780 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 781 # But MinSizeRel seems to add that automatically, so maybe disable these
 782 # flags instead if LLVM_NO_DEAD_STRIP is set.
 783 if(NOT CYGWIN AND NOT WIN32)
 784   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND
 785      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 786     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 787     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 788       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 789       # Doing so will break sanitizers.
 790       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 791     endif()
 792     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 793   endif()
 794 endif()
 795
 796 if(MSVC)
 797   # Remove flags here, for exceptions and RTTI.
 798   # Each target property or source property should be responsible to control
 799   # them.
 800   # CL.EXE complains to override flags like "/GR /GR-".
 801   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 802   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 803 endif()
 804
 805 # Provide public options to globally control RTTI and EH
 806 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 807 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 808 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 809   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 810 endif()
 811
 812 option(LLVM_USE_NEWPM "Build LLVM using the experimental new pass manager" Off)
 813 mark_as_advanced(LLVM_USE_NEWPM)
 814 if (LLVM_USE_NEWPM)
 815   append("-fexperimental-new-pass-manager"
 816     CMAKE_CXX_FLAGS
 817     CMAKE_C_FLAGS
 818     CMAKE_EXE_LINKER_FLAGS
 819     CMAKE_SHARED_LINKER_FLAGS)
 820 endif()
 821
 822 option(LLVM_ENABLE_IR_PGO "Build LLVM and tools with IR PGO instrumentation (deprecated)" Off)
 823 mark_as_advanced(LLVM_ENABLE_IR_PGO)
 824
 825 set(LLVM_BUILD_INSTRUMENTED OFF CACHE STRING "Build LLVM and tools with PGO instrumentation. May be specified as IR or Frontend")
 826 mark_as_advanced(LLVM_BUILD_INSTRUMENTED)
 827 string(TOUPPER "${LLVM_BUILD_INSTRUMENTED}" uppercase_LLVM_BUILD_INSTRUMENTED)
 828
 829 if (LLVM_BUILD_INSTRUMENTED)
 830   if (LLVM_ENABLE_IR_PGO OR uppercase_LLVM_BUILD_INSTRUMENTED STREQUAL "IR")
 831     append("-fprofile-generate='${LLVM_PROFILE_DATA_DIR}'"
 832       CMAKE_CXX_FLAGS
 833       CMAKE_C_FLAGS
 834       CMAKE_EXE_LINKER_FLAGS
 835       CMAKE_SHARED_LINKER_FLAGS)
 836   elseif(uppercase_LLVM_BUILD_INSTRUMENTED STREQUAL "CSIR")
 837     append("-fcs-profile-generate='${LLVM_CSPROFILE_DATA_DIR}'"
 838       CMAKE_CXX_FLAGS
 839       CMAKE_C_FLAGS
 840       CMAKE_EXE_LINKER_FLAGS
 841       CMAKE_SHARED_LINKER_FLAGS)
 842   else()
 843     append("-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}'"
 844       CMAKE_CXX_FLAGS
 845       CMAKE_C_FLAGS
 846       CMAKE_EXE_LINKER_FLAGS
 847       CMAKE_SHARED_LINKER_FLAGS)
 848   endif()
 849 endif()
 850
 851 # Need to pass -fprofile-instr-use to linker for context-sensitive PGO
 852 # compilation.
 853 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 854     append("-fprofile-instr-use='${LLVM_PROFDATA_FILE}'"
 855       CMAKE_EXE_LINKER_FLAGS
 856       CMAKE_SHARED_LINKER_FLAGS)
 857 endif()
 858
 859 option(LLVM_BUILD_INSTRUMENTED_COVERAGE "Build LLVM and tools with Code Coverage instrumentation" Off)
 860 mark_as_advanced(LLVM_BUILD_INSTRUMENTED_COVERAGE)
 861 append_if(LLVM_BUILD_INSTRUMENTED_COVERAGE "-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}' -fcoverage-mapping"
 862   CMAKE_CXX_FLAGS
 863   CMAKE_C_FLAGS
 864   CMAKE_EXE_LINKER_FLAGS
 865   CMAKE_SHARED_LINKER_FLAGS)
 866
 867 if (LLVM_BUILD_INSTRUMENTED AND LLVM_BUILD_INSTRUMENTED_COVERAGE)
 868   message(FATAL_ERROR "LLVM_BUILD_INSTRUMENTED and LLVM_BUILD_INSTRUMENTED_COVERAGE cannot both be specified")
 869 endif()
 870
 871 if(LLVM_ENABLE_LTO AND LLVM_ON_WIN32 AND NOT LINKER_IS_LLD_LINK)
 872   message(FATAL_ERROR "When compiling for Windows, LLVM_ENABLE_LTO requires using lld as the linker (point CMAKE_LINKER at lld-link.exe)")
 873 endif()
 874 if(uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
 875   append("-flto=thin" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 876   if(NOT LINKER_IS_LLD_LINK)
 877     append("-flto=thin" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 878   endif()
 879   # If the linker supports it, enable the lto cache. This improves initial build
 880   # time a little since we re-link a lot of the same objects, and significantly
 881   # improves incremental build time.
 882   # FIXME: We should move all this logic into the clang driver.
 883   if(APPLE)
 884     append("-Wl,-cache_path_lto,${PROJECT_BINARY_DIR}/lto.cache"
 885            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 886   elseif(UNIX AND LLVM_USE_LINKER STREQUAL "lld")
 887     append("-Wl,--thinlto-cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 888            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 889   elseif(LLVM_USE_LINKER STREQUAL "gold")
 890     append("-Wl,--plugin-opt,cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 891            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 892   endif()
 893 elseif(uppercase_LLVM_ENABLE_LTO STREQUAL "FULL")
 894   append("-flto=full" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 895   if(NOT LINKER_IS_LLD_LINK)
 896     append("-flto=full" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 897   endif()
 898 elseif(LLVM_ENABLE_LTO)
 899   append("-flto" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 900   if(NOT LINKER_IS_LLD_LINK)
 901     append("-flto" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 902   endif()
 903 endif()
 904
 905 # This option makes utils/extract_symbols.py be used to determine the list of
 906 # symbols to export from LLVM tools. This is necessary when using MSVC if you
 907 # want to allow plugins, though note that the plugin has to explicitly link
 908 # against (exactly one) tool so we can't unilaterally turn on
 909 # LLVM_ENABLE_PLUGINS when it's enabled.
 910 option(LLVM_EXPORT_SYMBOLS_FOR_PLUGINS "Export symbols from LLVM tools so that plugins can import them" OFF)
 911 if(BUILD_SHARED_LIBS AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 912   message(FATAL_ERROR "BUILD_SHARED_LIBS not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 913 endif()
 914 if(LLVM_LINK_LLVM_DYLIB AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 915   message(FATAL_ERROR "LLVM_LINK_LLVM_DYLIB not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 916 endif()
 917
 918 # Plugin support
 919 # FIXME: Make this configurable.
 920 if(WIN32 OR CYGWIN)
 921   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 922     set(LLVM_ENABLE_PLUGINS ON)
 923   else()
 924     set(LLVM_ENABLE_PLUGINS OFF)
 925   endif()
 926 else()
 927   set(LLVM_ENABLE_PLUGINS ON)
 928 endif()
 929
 930 # By default we should enable LLVM_ENABLE_IDE only for multi-configuration
 931 # generators. This option disables optional build system features that make IDEs
 932 # less usable.
 933 set(LLVM_ENABLE_IDE_default OFF)
 934 if (CMAKE_CONFIGURATION_TYPES)
 935   set(LLVM_ENABLE_IDE_default ON)
 936 endif()
 937 option(LLVM_ENABLE_IDE
 938        "Disable optional build system features that cause problems for IDE generators"
 939        ${LLVM_ENABLE_IDE_default})
 940 if (CMAKE_CONFIGURATION_TYPES AND NOT LLVM_ENABLE_IDE)
 941   message(WARNING "Disabling LLVM_ENABLE_IDE on multi-configuration generators is not recommended.")
 942 endif()
 943
 944 function(get_compile_definitions)
 945   get_directory_property(top_dir_definitions DIRECTORY ${CMAKE_SOURCE_DIR} COMPILE_DEFINITIONS)
 946   foreach(definition ${top_dir_definitions})
 947     if(DEFINED result)
 948       string(APPEND result " -D${definition}")
 949     else()
 950       set(result "-D${definition}")
 951     endif()
 952   endforeach()
 953   set(LLVM_DEFINITIONS "${result}" PARENT_SCOPE)
 954 endfunction()
 955 get_compile_definitions()
 956
 957 option(LLVM_FORCE_ENABLE_STATS "Enable statistics collection for builds that wouldn't normally enable it" OFF)
 958
 959 check_symbol_exists(os_signpost_interval_begin "os/signpost.h" macos_signposts_available)
 960 if(macos_signposts_available)
 961   check_cxx_source_compiles(
 962     "#include <os/signpost.h>
 963     int main() { os_signpost_interval_begin(nullptr, 0, \"\", \"\"); return 0; }"
 964     macos_signposts_usable)
 965   if(macos_signposts_usable)
 966     set(LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS "WITH_ASSERTS" CACHE STRING
 967         "Enable support for Xcode signposts. Can be WITH_ASSERTS, FORCE_ON, FORCE_OFF")
 968     string(TOUPPER "${LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS}"
 969                    uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS)
 970     if( uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS STREQUAL "WITH_ASSERTS" )
 971       if( LLVM_ENABLE_ASSERTIONS )
 972         set( LLVM_SUPPORT_XCODE_SIGNPOSTS 1 )
 973       endif()
 974     elseif( uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS STREQUAL "FORCE_ON" )
 975       set( LLVM_SUPPORT_XCODE_SIGNPOSTS 1 )
 976     elseif( uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS STREQUAL "FORCE_OFF" )
 977       # We don't need to do anything special to turn off signposts.
 978     elseif( NOT DEFINED LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS )
 979       # Treat LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS like "FORCE_OFF" when it has not been
 980       # defined.
 981     else()
 982       message(FATAL_ERROR "Unknown value for LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS:"
 983                           " \"${LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS}\"!")
 984     endif()
 985   endif()
 986 endif()