CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 cmake_policy(SET CMP0022 NEW)
   6
   7 cmake_policy(SET CMP0048 NEW)
   8
   9 # CMake 3.1 and higher include generator expressions of the form
  10 # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  11 # stripped everywhere that access the SOURCES property, so we just
  12 # defer to the OLD behavior of not including generator expressions
  13 # in the output for now.
  14 cmake_policy(SET CMP0051 OLD)
  15
  16 cmake_policy(SET CMP0056 NEW)
  17
  18 cmake_policy(SET CMP0057 NEW)
  19
  20 if(POLICY CMP0068)
  21   cmake_policy(SET CMP0068 NEW)
  22   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
  23 endif()
  24
  25 if(NOT DEFINED LLVM_VERSION_MAJOR)
  26   set(LLVM_VERSION_MAJOR 7)
  27 endif()
  28 if(NOT DEFINED LLVM_VERSION_MINOR)
  29   set(LLVM_VERSION_MINOR 0)
  30 endif()
  31 if(NOT DEFINED LLVM_VERSION_PATCH)
  32   set(LLVM_VERSION_PATCH 0)
  33 endif()
  34 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  35   set(LLVM_VERSION_SUFFIX svn)
  36 endif()
  37
  38 if (NOT PACKAGE_VERSION)
  39   set(PACKAGE_VERSION
  40     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  41 endif()
  42
  43 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  44   message(WARNING "Visual Studio generators use the x86 host compiler by "
  45                   "default, even for 64-bit targets. This can result in linker "
  46                   "instability and out of memory errors. To use the 64-bit "
  47                   "host compiler, pass -Thost=x64 on the CMake command line.")
  48 endif()
  49
  50 project(LLVM
  51   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  52   LANGUAGES C CXX ASM)
  53
  54 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  55   message(STATUS "No build type selected, default to Debug")
  56   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  57 endif()
  58
  59 # This should only apply if you are both on an Apple host, and targeting Apple.
  60 if(CMAKE_HOST_APPLE AND APPLE)
  61   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  62   if(NOT CMAKE_LIBTOOL)
  63     if(NOT CMAKE_XCRUN)
  64       find_program(CMAKE_XCRUN NAMES xcrun)
  65     endif()
  66     if(CMAKE_XCRUN)
  67       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  68         OUTPUT_VARIABLE CMAKE_LIBTOOL
  69         OUTPUT_STRIP_TRAILING_WHITESPACE)
  70     endif()
  71
  72     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  73       find_program(CMAKE_LIBTOOL NAMES libtool)
  74     endif()
  75   endif()
  76
  77   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  78   if(CMAKE_LIBTOOL)
  79     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  80     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  81
  82     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  83       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  84       OUTPUT_STRIP_TRAILING_WHITESPACE)
  85     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  86       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  87         ${LIBTOOL_V_OUTPUT})
  88       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  89         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  90       endif()
  91     endif()
  92
  93     foreach(lang ${languages})
  94       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  95         "${CMAKE_LIBTOOL} -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  96         <LINK_FLAGS> <OBJECTS> ")
  97     endforeach()
  98   endif()
  99
 100   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
 101   if(DYLD_LIBRARY_PATH)
 102     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
 103     foreach(lang ${languages})
 104       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 105         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
 106              "${dyld_envar} ${cmd}")
 107       endforeach()
 108       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 109         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 110     endforeach()
 111   endif()
 112 endif()
 113
 114 # Side-by-side subprojects layout: automatically set the
 115 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 116 # This allows an easy way of setting up a build directory for llvm and another
 117 # one for llvm+clang+... using the same sources.
 118 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly;debuginfo-tests")
 119 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 120         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 121 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 122   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 123 endif()
 124 foreach(proj ${LLVM_ENABLE_PROJECTS})
 125   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 126   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 127     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 128   endif()
 129   string(TOUPPER "${proj}" upper_proj)
 130   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 131   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 132   # There is a widely spread opinion that clang-tools-extra should be merged
 133   # into clang. The following simulates it by always enabling clang-tools-extra
 134   # when enabling clang.
 135   if (proj STREQUAL "clang")
 136     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 137   endif()
 138 endforeach()
 139
 140 # Build llvm with ccache if the package is present
 141 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 142 if(LLVM_CCACHE_BUILD)
 143   find_program(CCACHE_PROGRAM ccache)
 144   if(CCACHE_PROGRAM)
 145       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 146       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 147       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 148           CACHE STRING "Parameters to pass through to ccache")
 149
 150       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 151       if (LLVM_CCACHE_MAXSIZE)
 152         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 153       endif()
 154       if (LLVM_CCACHE_DIR)
 155         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 156       endif()
 157       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 158   else()
 159     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 160   endif()
 161 endif()
 162
 163 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 164
 165 # Some features of the LLVM build may be disallowed when dependency debugging is
 166 # enabled. In particular you cannot use ccache because we want to force compile
 167 # operations to always happen.
 168 if(LLVM_DEPENDENCY_DEBUGGING)
 169   if(NOT CMAKE_HOST_APPLE)
 170     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 171   endif()
 172   if(LLVM_CCACHE_BUILD)
 173     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 174   endif()
 175 endif()
 176
 177 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 178 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 179 if(LLVM_ENABLE_GISEL_COV)
 180   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 181 endif()
 182
 183 # Add path for custom modules
 184 set(CMAKE_MODULE_PATH
 185   ${CMAKE_MODULE_PATH}
 186   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 187   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 188   )
 189
 190 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 191 # for use by clang_complete, YouCompleteMe, etc.
 192 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 193
 194 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 195   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 196
 197 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 198
 199 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 200
 201 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 202 if ( LLVM_USE_FOLDERS )
 203   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 204 endif()
 205
 206 include(VersionFromVCS)
 207
 208 option(LLVM_APPEND_VC_REV
 209   "Embed the version control system revision id in LLVM" ON)
 210
 211 set(PACKAGE_NAME LLVM)
 212 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 213 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 214
 215 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 216   "Default URL where bug reports are to be submitted.")
 217
 218 # Configure CPack.
 219 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 220 set(CPACK_PACKAGE_VENDOR "LLVM")
 221 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 222 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 223 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 224 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 225 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 226 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 227 if(WIN32 AND NOT UNIX)
 228   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 229   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 230   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 231   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 232   set(CPACK_NSIS_MODIFY_PATH "ON")
 233   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 234   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 235     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 236   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 237     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 238   if( CMAKE_CL_64 )
 239     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 240   endif()
 241 endif()
 242 include(CPack)
 243
 244 # Sanity check our source directory to make sure that we are not trying to
 245 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 246 # sure that we don't have any stray generated files lying around in the tree
 247 # (which would end up getting picked up by header search, instead of the correct
 248 # versions).
 249 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 250   message(FATAL_ERROR "In-source builds are not allowed.
 251 CMake would overwrite the makefiles distributed with LLVM.
 252 Please create a directory and run cmake from there, passing the path
 253 to this source directory as the last argument.
 254 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 255 Please delete them.")
 256 endif()
 257 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 258   file(GLOB_RECURSE
 259     tablegenned_files_on_include_dir
 260     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 261   file(GLOB_RECURSE
 262     tablegenned_files_on_lib_dir
 263     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 264   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 265     message(FATAL_ERROR "Apparently there is a previous in-source build,
 266 probably as the result of running `configure' and `make' on
 267 ${CMAKE_CURRENT_SOURCE_DIR}.
 268 This may cause problems. The suspicious files are:
 269 ${tablegenned_files_on_lib_dir}
 270 ${tablegenned_files_on_include_dir}
 271 Please clean the source directory.")
 272   endif()
 273 endif()
 274
 275 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 276
 277 if (CMAKE_BUILD_TYPE AND
 278     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 279   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 280 endif()
 281
 282 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 283
 284 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 285 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 286
 287 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 288     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 289 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 290
 291 # They are used as destination of target generators.
 292 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 293 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 294 if(WIN32 OR CYGWIN)
 295   # DLL platform -- put DLLs into bin.
 296   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 297 else()
 298   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 299 endif()
 300
 301 # Each of them corresponds to llvm-config's.
 302 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 303 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 304 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 305 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 306 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 307
 308 # Note: LLVM_CMAKE_PATH does not include generated files
 309 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 310 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 311 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 312
 313 # List of all targets to be built by default:
 314 set(LLVM_ALL_TARGETS
 315   AArch64
 316   AMDGPU
 317   ARM
 318   BPF
 319   Hexagon
 320   Lanai
 321   Mips
 322   MSP430
 323   NVPTX
 324   PowerPC
 325   Sparc
 326   SystemZ
 327   X86
 328   XCore
 329   )
 330
 331 # List of targets with JIT support:
 332 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 333
 334 set(LLVM_TARGETS_TO_BUILD "all"
 335     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 336
 337 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 338   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 339
 340 option(BUILD_SHARED_LIBS
 341   "Build all libraries as shared libraries instead of static" OFF)
 342
 343 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 344 if(LLVM_ENABLE_BACKTRACES)
 345   set(ENABLE_BACKTRACES 1)
 346 endif()
 347
 348 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 349 if(LLVM_ENABLE_CRASH_OVERRIDES)
 350   set(ENABLE_CRASH_OVERRIDES 1)
 351 endif()
 352
 353 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 354 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 355 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 356
 357 set(LLVM_TARGET_ARCH "host"
 358   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 359
 360 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 361
 362 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 363
 364 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 365
 366 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 367
 368 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 369
 370 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 371
 372 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 373   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 374 endif()
 375
 376 set(LLVM_TARGETS_TO_BUILD
 377    ${LLVM_TARGETS_TO_BUILD}
 378    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 379 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 380
 381 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 382 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 383 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 384 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 385   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 386   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 387 else()
 388   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 389   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 390 endif()
 391 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 392 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 393 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 394 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 395 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 396 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 397
 398 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 399
 400 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 401   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 402 else()
 403   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 404 endif()
 405
 406 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 407
 408 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 409   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 410
 411 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 412        "Set to ON to force using an old, unsupported host toolchain." OFF)
 413
 414 option(LLVM_USE_INTEL_JITEVENTS
 415   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 416   OFF)
 417
 418 if( LLVM_USE_INTEL_JITEVENTS )
 419   # Verify we are on a supported platform
 420   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 421     message(FATAL_ERROR
 422       "Intel JIT API support is available on Linux and Windows only.")
 423   endif()
 424 endif( LLVM_USE_INTEL_JITEVENTS )
 425
 426 option(LLVM_USE_OPROFILE
 427   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 428
 429 option(LLVM_EXTERNALIZE_DEBUGINFO
 430   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 431
 432 # If enabled, verify we are on a platform that supports oprofile.
 433 if( LLVM_USE_OPROFILE )
 434   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 435     message(FATAL_ERROR "OProfile support is available on Linux only.")
 436   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 437 endif( LLVM_USE_OPROFILE )
 438
 439 set(LLVM_USE_SANITIZER "" CACHE STRING
 440   "Define the sanitizer used to build binaries and tests.")
 441 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 442 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 443   "Path to fuzzing library for linking with fuzz targets")
 444
 445 option(LLVM_USE_SPLIT_DWARF
 446   "Use -gsplit-dwarf when compiling llvm." OFF)
 447
 448 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 449 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 450
 451 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 452   set(POLLY_IN_TREE TRUE)
 453 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 454   set(POLLY_IN_TREE TRUE)
 455 else()
 456   set(POLLY_IN_TREE FALSE)
 457 endif()
 458
 459 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 460   set(WITH_POLLY ON)
 461 else()
 462   set(WITH_POLLY OFF)
 463 endif()
 464
 465 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 466   set(LINK_POLLY_INTO_TOOLS ON)
 467 else()
 468   set(LINK_POLLY_INTO_TOOLS OFF)
 469 endif()
 470
 471 # Define an option controlling whether we should build for 32-bit on 64-bit
 472 # platforms, where supported.
 473 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 474   # TODO: support other platforms and toolchains.
 475   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 476 endif()
 477
 478 # Define the default arguments to use with 'lit', and an option for the user to
 479 # override.
 480 set(LIT_ARGS_DEFAULT "-sv")
 481 if (MSVC_IDE OR XCODE)
 482   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 483 endif()
 484 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 485
 486 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 487 if( WIN32 AND NOT CYGWIN )
 488   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 489 endif()
 490
 491 # Define options to control the inclusion and default build behavior for
 492 # components which may not strictly be necessary (tools, examples, and tests).
 493 #
 494 # This is primarily to support building smaller or faster project files.
 495 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 496 option(LLVM_BUILD_TOOLS
 497   "Build the LLVM tools. If OFF, just generate build targets." ON)
 498
 499 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 500 option(LLVM_BUILD_UTILS
 501   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 502
 503 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 504 option(LLVM_BUILD_RUNTIMES
 505   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 506
 507 option(LLVM_BUILD_RUNTIME
 508   "Build the LLVM runtime libraries." ON)
 509 option(LLVM_BUILD_EXAMPLES
 510   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 511 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 512
 513 option(LLVM_BUILD_TESTS
 514   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 515 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 516 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 517
 518 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 519 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 520 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 521 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 522 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 523 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 524
 525 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 526     CACHE STRING "Doxygen-generated HTML documentation install directory")
 527 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 528     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 529
 530 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 531   "Build compiler-rt as an external project." OFF)
 532
 533 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 534   "Show target and host info when tools are invoked with --version." ON)
 535
 536 # You can configure which libraries from LLVM you want to include in the
 537 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 538 # list of LLVM components. All component names handled by llvm-config are valid.
 539 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 540   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 541     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 542 endif()
 543 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 544 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 545 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 546 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 547   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 548 endif()
 549 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 550
 551 option(LLVM_DYLIB_SYMBOL_VERSIONING OFF)
 552
 553 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 554 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 555   set(LLVM_USE_HOST_TOOLS ON)
 556 endif()
 557
 558 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 559   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 560 else()
 561   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 562 endif()
 563
 564 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 565     LLVM_ENABLE_IR_PGO)
 566   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 567     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 568     # for spining disks. Anything higher may only help on slower mediums.
 569     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 570   endif()
 571   if(NOT LLVM_PROFILE_FILE_PATTERN)
 572     if(NOT LLVM_PROFILE_DATA_DIR)
 573       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 574     endif()
 575                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 576   endif()
 577 endif()
 578
 579 if (LLVM_BUILD_STATIC)
 580   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 581 endif()
 582
 583 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 584 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 585 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 586
 587 # All options referred to from HandleLLVMOptions have to be specified
 588 # BEFORE this include, otherwise options will not be correctly set on
 589 # first cmake run
 590 include(config-ix)
 591
 592 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 593   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 594 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 595
 596 # By default, we target the host, but this can be overridden at CMake
 597 # invocation time.
 598 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 599   "Default target for which LLVM will generate code." )
 600 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 601 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 602 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 603
 604 include(HandleLLVMOptions)
 605
 606 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 607 # FIXME: We should support systems with only Python 3, but that requires work
 608 # on LLDB.
 609 set(Python_ADDITIONAL_VERSIONS 2.7)
 610 include(FindPythonInterp)
 611 if( NOT PYTHONINTERP_FOUND )
 612   message(FATAL_ERROR
 613 "Unable to find Python interpreter, required for builds and testing.
 614
 615 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 616 endif()
 617
 618 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 619   message(FATAL_ERROR "Python 2.7 or newer is required")
 620 endif()
 621
 622 ######
 623 # LLVMBuild Integration
 624 #
 625 # We use llvm-build to generate all the data required by the CMake based
 626 # build system in one swoop:
 627 #
 628 #  - We generate a file (a CMake fragment) in the object root which contains
 629 #    all the definitions that are required by CMake.
 630 #
 631 #  - We generate the library table used by llvm-config.
 632 #
 633 #  - We generate the dependencies for the CMake fragment, so that we will
 634 #    automatically reconfigure outselves.
 635
 636 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 637 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 638   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 639 set(LLVMBUILDCMAKEFRAG
 640   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 641
 642 # Create the list of optional components that are enabled
 643 if (LLVM_USE_INTEL_JITEVENTS)
 644   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 645 endif (LLVM_USE_INTEL_JITEVENTS)
 646 if (LLVM_USE_OPROFILE)
 647   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 648 endif (LLVM_USE_OPROFILE)
 649
 650 message(STATUS "Constructing LLVMBuild project information")
 651 execute_process(
 652   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 653             --native-target "${LLVM_NATIVE_ARCH}"
 654             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 655             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 656             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 657             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 658             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 659             ERROR_VARIABLE LLVMBUILDERRORS
 660             OUTPUT_STRIP_TRAILING_WHITESPACE
 661             ERROR_STRIP_TRAILING_WHITESPACE
 662   RESULT_VARIABLE LLVMBUILDRESULT)
 663
 664 # On Win32, CMake doesn't properly handle piping the default output/error
 665 # streams into the GUI console. So, we explicitly catch and report them.
 666 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 667   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 668 endif()
 669 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 670   message(FATAL_ERROR
 671     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 672 endif()
 673
 674 # Include the generated CMake fragment. This will define properties from the
 675 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 676 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 677 # files change.
 678 include(${LLVMBUILDCMAKEFRAG})
 679
 680 ######
 681
 682 # Configure all of the various header file fragments LLVM uses which depend on
 683 # configuration variables.
 684 set(LLVM_ENUM_TARGETS "")
 685 set(LLVM_ENUM_ASM_PRINTERS "")
 686 set(LLVM_ENUM_ASM_PARSERS "")
 687 set(LLVM_ENUM_DISASSEMBLERS "")
 688 foreach(t ${LLVM_TARGETS_TO_BUILD})
 689   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 690
 691   list(FIND LLVM_ALL_TARGETS ${t} idx)
 692   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 693   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 694   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 695   # this test just makes sure that any experimental targets were passed via
 696   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 697   if( idx LESS 0 AND idy LESS 0 )
 698     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 699       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 700   else()
 701     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 702   endif()
 703
 704   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 705   if( asmp_file )
 706     set(LLVM_ENUM_ASM_PRINTERS
 707       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 708   endif()
 709   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 710     set(LLVM_ENUM_ASM_PARSERS
 711       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 712   endif()
 713   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 714     set(LLVM_ENUM_DISASSEMBLERS
 715       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 716   endif()
 717 endforeach(t)
 718
 719 # Produce the target definition files, which provide a way for clients to easily
 720 # include various classes of targets.
 721 configure_file(
 722   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 723   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 724   )
 725 configure_file(
 726   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 727   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 728   )
 729 configure_file(
 730   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 731   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 732   )
 733 configure_file(
 734   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 735   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 736   )
 737
 738 # Configure the three LLVM configuration header files.
 739 configure_file(
 740   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 741   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 742 configure_file(
 743   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 744   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 745 configure_file(
 746   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 747   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 748
 749 # Add target for generating source rpm package.
 750 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 751     CACHE FILEPATH ".spec file to use for srpm generation")
 752 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 753 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 754
 755 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 756 # DUMMY_VAR contains a version string which we don't care about.
 757 add_version_info_from_vcs(DUMMY_VAR)
 758 if ( SVN_REVISION )
 759   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 760 elseif ( GIT_COMMIT )
 761   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 762 endif()
 763
 764 configure_file(
 765   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 766   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 767
 768 add_custom_target(srpm
 769   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 770   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 771 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 772
 773
 774 # They are not referenced. See set_output_directory().
 775 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 776 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 777 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 778
 779 if(APPLE AND DARWIN_LTO_LIBRARY)
 780   set(CMAKE_EXE_LINKER_FLAGS
 781     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 782   set(CMAKE_SHARED_LINKER_FLAGS
 783     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 784   set(CMAKE_MODULE_LINKER_FLAGS
 785     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 786 endif()
 787
 788 # Work around a broken bfd ld behavior. When linking a binary with a
 789 # foo.so library, it will try to find any library that foo.so uses and
 790 # check its symbols. This is wasteful (the check was done when foo.so
 791 # was created) and can fail since it is not the dynamic linker and
 792 # doesn't know how to handle search paths correctly.
 793 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 794   set(CMAKE_EXE_LINKER_FLAGS
 795       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 796 endif()
 797
 798 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 799
 800 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 801
 802 # when crosscompiling import the executable targets from a file
 803 if(LLVM_USE_HOST_TOOLS)
 804   include(CrossCompile)
 805 endif(LLVM_USE_HOST_TOOLS)
 806 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 807 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 808 # (this is a variable that CrossCompile sets on recursive invocations)
 809 endif()
 810
 811 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 812   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 813   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 814   include_directories(SYSTEM "/usr/local/include")
 815   link_directories("/usr/local/lib")
 816 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 817
 818 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 819    # special hack for Solaris to handle crazy system sys/regset.h
 820    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 821 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 822
 823 # Make sure we don't get -rdynamic in every binary. For those that need it,
 824 # use export_executable_symbols(target).
 825 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 826
 827 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 828   "Profiling data file to use when compiling in order to improve runtime performance.")
 829
 830 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 831   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 832     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 833   else()
 834     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 835   endif()
 836 endif()
 837
 838 include(AddLLVM)
 839 include(TableGen)
 840
 841 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 842   # People report that -O3 is unreliable on MinGW. The traditional
 843   # build also uses -O2 for that reason:
 844   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 845 endif()
 846
 847 # Put this before tblgen. Else we have a circular dependence.
 848 add_subdirectory(lib/Demangle)
 849 add_subdirectory(lib/Support)
 850 add_subdirectory(lib/TableGen)
 851
 852 add_subdirectory(utils/TableGen)
 853
 854 add_subdirectory(include/llvm)
 855
 856 add_subdirectory(lib)
 857
 858 if( LLVM_INCLUDE_UTILS )
 859   add_subdirectory(utils/FileCheck)
 860   add_subdirectory(utils/PerfectShuffle)
 861   add_subdirectory(utils/count)
 862   add_subdirectory(utils/not)
 863   add_subdirectory(utils/yaml-bench)
 864 else()
 865   if ( LLVM_INCLUDE_TESTS )
 866     message(FATAL_ERROR "Including tests when not building utils will not work.
 867     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 868   endif()
 869 endif()
 870
 871 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 872 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 873   add_subdirectory(utils/LLVMVisualizers)
 874 endif()
 875
 876 foreach( binding ${LLVM_BINDINGS_LIST} )
 877   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 878     add_subdirectory(bindings/${binding})
 879   endif()
 880 endforeach()
 881
 882 add_subdirectory(projects)
 883
 884 if( LLVM_INCLUDE_TOOLS )
 885   add_subdirectory(tools)
 886 endif()
 887
 888 if( LLVM_INCLUDE_RUNTIMES )
 889   add_subdirectory(runtimes)
 890 endif()
 891
 892 if( LLVM_INCLUDE_EXAMPLES )
 893   add_subdirectory(examples)
 894 endif()
 895
 896 if( LLVM_INCLUDE_TESTS )
 897   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 898     include(LLVMExternalProjectUtils)
 899     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 900       USE_TOOLCHAIN
 901       EXCLUDE_FROM_ALL
 902       NO_INSTALL
 903       ALWAYS_CLEAN)
 904   endif()
 905   add_subdirectory(utils/lit)
 906   add_subdirectory(test)
 907   add_subdirectory(unittests)
 908   if( LLVM_INCLUDE_UTILS )
 909     add_subdirectory(utils/unittest)
 910   endif()
 911
 912   if (WIN32)
 913     # This utility is used to prevent crashing tests from calling Dr. Watson on
 914     # Windows.
 915     add_subdirectory(utils/KillTheDoctor)
 916   endif()
 917
 918   # Add a global check rule now that all subdirectories have been traversed
 919   # and we know the total set of lit testsuites.
 920   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 921   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 922   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 923   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 924   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 925                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 926   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 927                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 928   add_lit_target(check-all
 929     "Running all regression tests"
 930     ${LLVM_LIT_TESTSUITES}
 931     PARAMS ${LLVM_LIT_PARAMS}
 932     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 933     ARGS ${LLVM_LIT_EXTRA_ARGS}
 934     )
 935   if(TARGET check-runtimes)
 936     add_dependencies(check-all check-runtimes)
 937   endif()
 938   add_custom_target(test-depends
 939                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 940   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 941 endif()
 942
 943 if (LLVM_INCLUDE_DOCS)
 944   add_subdirectory(docs)
 945 endif()
 946
 947 add_subdirectory(cmake/modules)
 948
 949 # Do this last so that all lit targets have already been created.
 950 if (LLVM_INCLUDE_UTILS)
 951   add_subdirectory(utils/llvm-lit)
 952 endif()
 953
 954 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 955   install(DIRECTORY include/llvm include/llvm-c
 956     DESTINATION include
 957     COMPONENT llvm-headers
 958     FILES_MATCHING
 959     PATTERN "*.def"
 960     PATTERN "*.h"
 961     PATTERN "*.td"
 962     PATTERN "*.inc"
 963     PATTERN "LICENSE.TXT"
 964     PATTERN ".svn" EXCLUDE
 965     )
 966
 967   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
 968     DESTINATION include
 969     COMPONENT llvm-headers
 970     FILES_MATCHING
 971     PATTERN "*.def"
 972     PATTERN "*.h"
 973     PATTERN "*.gen"
 974     PATTERN "*.inc"
 975     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 976     PATTERN "CMakeFiles" EXCLUDE
 977     PATTERN "config.h" EXCLUDE
 978     PATTERN ".svn" EXCLUDE
 979     )
 980
 981   # Installing the headers needs to depend on generating any public
 982   # tablegen'd headers.
 983   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 984   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
 985
 986   if (NOT CMAKE_CONFIGURATION_TYPES)
 987     add_llvm_install_targets(install-llvm-headers
 988                              COMPONENT llvm-headers)
 989   endif()
 990 endif()
 991
 992 # This must be at the end of the LLVM root CMakeLists file because it must run
 993 # after all targets are created.
 994 if(LLVM_DISTRIBUTION_COMPONENTS)
 995   if(CMAKE_CONFIGURATION_TYPES)
 996     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 997   endif()
 998
 999   add_custom_target(distribution)
1000   add_custom_target(install-distribution)
1001   add_custom_target(install-distribution-stripped)
1002   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS} ${LLVM_RUNTIME_DISTRIBUTION_COMPONENTS})
1003     if(TARGET ${target})
1004       add_dependencies(distribution ${target})
1005     else()
1006       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1007     endif()
1008
1009     if(TARGET install-${target})
1010       add_dependencies(install-distribution install-${target})
1011     else()
1012       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1013     endif()
1014
1015     if(TARGET install-${target}-stripped)
1016       add_dependencies(install-distribution-stripped install-${target}-stripped)
1017     else()
1018       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1019                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1020                          " or you should manually create the 'install-${target}-stripped' target.")
1021     endif()
1022   endforeach()
1023 endif()
1024
1025 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1026 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows")
1027   include(InstallRequiredSystemLibraries)
1028 endif()