llvm/test/Assembler/getelementptr.ll

   1 ; RUN: llvm-as < %s | llvm-dis | llvm-as | llvm-dis | FileCheck %s
   2 ; RUN: verify-uselistorder %s
   3
   4 ; Verify that over-indexed getelementptrs are folded.
   5 @A = external global [2 x [3 x [5 x [7 x i32]]]]
   6 @B = global ptr getelementptr ([2 x [3 x [5 x [7 x i32]]]], ptr @A, i64 0, i64 0, i64 2, i64 1, i64 7523)
   7 ; CHECK: @B = global ptr getelementptr ([2 x [3 x [5 x [7 x i32]]]], ptr @A, i64 36, i64 0, i64 1, i64 0, i64 5)
   8 @C = global ptr getelementptr ([2 x [3 x [5 x [7 x i32]]]], ptr @A, i64 3, i64 2, i64 0, i64 0, i64 7523)
   9 ; CHECK: @C = global ptr getelementptr ([2 x [3 x [5 x [7 x i32]]]], ptr @A, i64 39, i64 1, i64 1, i64 4, i64 5)
  10
  11 ; Verify that constant expression GEPs work with i84 indices.
  12 @D = external global [1 x i32]
  13
  14 @E = global ptr getelementptr inbounds ([1 x i32], ptr @D, i84 0, i64 1)
  15 ; CHECK: @E = global ptr getelementptr inbounds ([1 x i32], ptr @D, i84 1, i64 0)
  16
  17 ; Verify that i16 indices work.
  18 @x = external global {i32, i32}
  19 @y = global ptr getelementptr ({ i32, i32 }, ptr @x, i16 42, i32 0)
  20 ; CHECK: @y = global ptr getelementptr ({ i32, i32 }, ptr @x, i16 42, i32 0)
  21
  22 @PR23753_a = external global i8
  23 @PR23753_b = global ptr getelementptr (i8, ptr @PR23753_a, i64 ptrtoint (ptr @PR23753_a to i64))
  24 ; CHECK: @PR23753_b = global ptr getelementptr (i8, ptr @PR23753_a, i64 ptrtoint (ptr @PR23753_a to i64))
  25
  26 ; Verify that inrange on an index inhibits over-indexed getelementptr folding.
  27
  28 @nestedarray = global [2 x [4 x ptr]] zeroinitializer
  29
  30 ; CHECK: @nestedarray.1 = alias ptr, getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, inrange i32 0, i64 1, i32 0)
  31 @nestedarray.1 = alias ptr, getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, inrange i32 0, i32 0, i32 4)
  32
  33 ; CHECK: @nestedarray.2 = alias ptr, getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, i32 0, inrange i32 0, i32 4)
  34 @nestedarray.2 = alias ptr, getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, i32 0, inrange i32 0, i32 4)
  35
  36 ; CHECK: @nestedarray.3 = alias ptr, getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, i32 0, inrange i32 0)
  37 @nestedarray.3 = alias ptr, getelementptr inbounds ([4 x ptr], ptr getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, i32 0, inrange i32 0), i32 0, i32 0)
  38
  39 ; CHECK: @nestedarray.4 = alias ptr, getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, i32 0, i32 1, i32 0)
  40 @nestedarray.4 = alias ptr, getelementptr inbounds ([4 x ptr], ptr getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, i32 0, inrange i32 0), i32 1, i32 0)
  41
  42 ; CHECK: @nestedarray.5 = alias ptr, getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, inrange i32 0, i32 1, i32 0)
  43 @nestedarray.5 = alias ptr, getelementptr inbounds ([4 x ptr], ptr getelementptr inbounds ([2 x [4 x ptr]], ptr @nestedarray, inrange i32 0, i32 0), i32 1, i32 0)
  44
  45 ; See if i92 indices work too.
  46 define ptr @test(ptr %t, i92 %n) {
  47 ; CHECK: @test
  48 ; CHECK: %B = getelementptr { i32, i32 }, ptr %t, i92 %n, i32 0
  49   %B = getelementptr {i32, i32}, ptr %t, i92 %n, i32 0
  50   ret ptr %B
  51 }
  52
  53 ; Verify that constant expression vector GEPs work.
  54
  55 @z = global <2 x ptr> getelementptr ([3 x {i32, i32}], <2 x ptr> zeroinitializer, <2 x i32> <i32 1, i32 2>, <2 x i32> <i32 2, i32 3>, <2 x i32> <i32 1, i32 1>)
  56
  57 ; Verify that struct GEP works with a vector of pointers.
  58 define <2 x ptr> @test7(<2 x ptr> %a) {
  59   %w = getelementptr {i32, i32}, <2 x ptr> %a, <2 x i32> <i32 5, i32 9>, <2 x i32> zeroinitializer
  60   ret <2 x ptr> %w
  61 }
  62
  63 ; Verify that array GEP works with a vector of pointers.
  64 define <2 x ptr> @test8(<2 x ptr> %a) {
  65   %w = getelementptr  [2 x i8], <2 x  ptr> %a, <2 x i32> <i32 0, i32 0>, <2 x i8> <i8 0, i8 1>
  66   ret <2 x ptr> %w
  67 }
  68
  69 @array = internal global [16 x i32] [i32 -200, i32 -199, i32 -198, i32 -197, i32 -196, i32 -195, i32 -194, i32 -193, i32 -192, i32 -191, i32 -190, i32 -189, i32 -188, i32 -187, i32 -186, i32 -185], align 16
  70
  71 ; Verify that array GEP doesn't incorrectly infer inbounds.
  72 define ptr @test9() {
  73 entry:
  74   ret ptr getelementptr ([16 x i32], ptr @array, i64 0, i64 -13)
  75 ; CHECK-LABEL: define ptr @test9(
  76 ; CHECK: ret ptr getelementptr ([16 x i32], ptr @array, i64 0, i64 -13)
  77 }