llvm/test/Transforms/GVN/opt-remarks-non-dominating.ll

   1 ; RUN: opt < %s -passes=gvn -o /dev/null  -pass-remarks-output=%t -S
   2 ; RUN: cat %t | FileCheck %s
   3
   4
   5 ; ModuleID = 'bugpoint-reduced-simplified.bc'
   6 source_filename = "gvn-test.c"
   7 target datalayout = "e-m:e-p270:32:32-p271:32:32-p272:64:64-i64:64-f80:128-n8:16:32:64-S128"
   8 target triple = "x86_64-unknown-linux-gnu"
   9
  10 ; CHECK:      --- !Missed
  11 ; CHECK-NEXT: Pass:            gvn
  12 ; CHECK-NEXT: Name:            LoadClobbered
  13 ; CHECK-NEXT: Function:        nonDominating1
  14 ; CHECK-NEXT: Args:
  15 ; CHECK-NEXT:   - String:          'load of type '
  16 ; CHECK-NEXT:   - Type:            i32
  17 ; CHECK-NEXT:   - String:          ' not eliminated'
  18 ; CHECK-NEXT:   - String:          ' in favor of '
  19 ; CHECK-NEXT:   - OtherAccess:     store
  20 ; CHECK-NEXT:   - String:          ' because it is clobbered by '
  21 ; CHECK-NEXT:   - ClobberedBy:     call
  22 ; CHECK-NEXT: ...
  23
  24 ; Confirm that the partial redundancy being clobbered by the call to
  25 ; clobberingFunc() between store and load is identified.
  26
  27 define dso_local void @nonDominating1(ptr %a, i1 %cond, i32 %b) local_unnamed_addr #0 {
  28 entry:
  29   br i1 %cond, label %if.then, label %if.end
  30
  31 if.then:                                          ; preds = %entry
  32   store i32 %b, ptr %a, align 4
  33   br label %if.end
  34
  35 if.end:                                           ; preds = %if.then, %entry
  36   tail call void @clobberingFunc() #1
  37   %0 = load i32, ptr %a, align 4
  38   %mul2 = shl nsw i32 %0, 1
  39   store i32 %mul2, ptr %a, align 4
  40   ret void
  41 }
  42
  43 declare dso_local void @clobberingFunc() local_unnamed_addr #0
  44
  45 ; CHECK:      --- !Missed
  46 ; CHECK-NEXT: Pass:            gvn
  47 ; CHECK-NEXT: Name:            LoadClobbered
  48 ; CHECK-NEXT: DebugLoc:        { File: '/tmp/s.c', Line: 3, Column: 3 }
  49 ; CHECK-NEXT: Function:        nonDominating2
  50 ; CHECK-NEXT: Args:
  51 ; CHECK-NEXT:   - String:          'load of type '
  52 ; CHECK-NEXT:   - Type:            i32
  53 ; CHECK-NEXT:   - String:          ' not eliminated'
  54 ; CHECK-NEXT:   - String:          ' in favor of '
  55 ; CHECK-NEXT:   - OtherAccess:     load
  56 ; CHECK-NEXT:     DebugLoc: { File: '/tmp/s.c', Line: 1, Column: 1 }
  57 ; CHECK-NEXT:   - String:          ' because it is clobbered by '
  58 ; CHECK-NEXT:   - ClobberedBy:     call
  59 ; CHECK-NEXT:     DebugLoc: { File: '/tmp/s.c', Line: 2, Column: 2 }
  60 ; CHECK-NEXT: ...
  61 ; CHECK:      --- !Missed
  62 ; CHECK-NEXT: Pass:            gvn
  63 ; CHECK-NEXT: Name:            LoadClobbered
  64 ; CHECK-NEXT: DebugLoc:        { File: '/tmp/s.c', Line: 5, Column: 5 }
  65 ; CHECK-NEXT: Function:        nonDominating2
  66 ; CHECK-NEXT: Args:
  67 ; CHECK-NEXT:   - String:          'load of type '
  68 ; CHECK-NEXT:   - Type:            i32
  69 ; CHECK-NEXT:   - String:          ' not eliminated'
  70 ; CHECK-NEXT:   - String:          ' in favor of '
  71 ; CHECK-NEXT:   - OtherAccess:     load
  72 ; CHECK-NEXT:     DebugLoc: { File: '/tmp/s.c', Line: 3, Column: 3 }
  73 ; CHECK-NEXT:   - String:          ' because it is clobbered by '
  74 ; CHECK-NEXT:   - ClobberedBy:     call
  75 ; CHECK-NEXT:     DebugLoc: { File: '/tmp/s.c', Line: 4, Column: 4 }
  76 ; CHECK-NEXT: ...
  77
  78 ; More complex version of nonDominating1(), this time with loads. The values
  79 ; already loaded into %0 and %1 cannot replace %2 due to clobbering calls.
  80 ; %1 is not clobbered by the first call however, and %0 is irrelevant for the
  81 ; second one since %1 is more recently available.
  82
  83 define dso_local void @nonDominating2(ptr %a, i1 %cond) local_unnamed_addr #0 {
  84 entry:
  85   br i1 %cond, label %if.then, label %if.end5
  86
  87 if.then:                                          ; preds = %entry
  88   %0 = load i32, ptr %a, align 4, !dbg !14
  89   %mul = mul nsw i32 %0, 10
  90   tail call void @clobberingFunc() #1, !dbg !15
  91   %1 = load i32, ptr %a, align 4, !dbg !16
  92   %mul3 = mul nsw i32 %1, 5
  93   tail call void @clobberingFunc() #1, !dbg !17
  94   br label %if.end5
  95
  96 if.end5:                                          ; preds = %if.then, %entry
  97   %2 = load i32, ptr %a, align 4, !dbg !18
  98   %mul9 = shl nsw i32 %2, 1
  99   store i32 %mul9, ptr %a, align 4
 100   ret void
 101 }
 102
 103 ; CHECK:      --- !Missed
 104 ; CHECK-NEXT: Pass:            gvn
 105 ; CHECK-NEXT: Name:            LoadClobbered
 106 ; CHECK-NEXT: Function:        nonDominating3
 107 ; CHECK-NEXT: Args:
 108 ; CHECK-NEXT:   - String:          'load of type '
 109 ; CHECK-NEXT:   - Type:            i32
 110 ; CHECK-NEXT:   - String:          ' not eliminated'
 111 ; CHECK-NEXT:   - String:          ' because it is clobbered by '
 112 ; CHECK-NEXT:   - ClobberedBy:     call
 113 ; CHECK-NEXT: ...
 114
 115 ; The two stores are both partially available at %0 (were it not for the
 116 ; clobbering call), however neither is strictly more recent than the other, so
 117 ; no attempt is made to identify what value could have potentially been reused
 118 ; otherwise. Just report that the load cannot be eliminated.
 119
 120 define dso_local void @nonDominating3(ptr %a, i32 %b, i32 %c, i1 %cond) local_unnamed_addr #0 {
 121 entry:
 122   br i1 %cond, label %if.end5.sink.split, label %if.else
 123
 124 if.else:                                          ; preds = %entry
 125   store i32 %b, ptr %a, align 4
 126   br label %if.end5
 127
 128 if.end5.sink.split:                               ; preds = %entry
 129   store i32 %c, ptr %a, align 4
 130   br label %if.end5
 131
 132 if.end5:                                          ; preds = %if.end5.sink.split, %if.else
 133   tail call void @clobberingFunc() #1
 134   %0 = load i32, ptr %a, align 4
 135   %mul7 = shl nsw i32 %0, 1
 136   ret void
 137 }
 138
 139 ; CHECK:      --- !Missed
 140 ; CHECK-NEXT: Pass:            gvn
 141 ; CHECK-NEXT: Name:            LoadClobbered
 142 ; CHECK-NEXT: Function:        nonDominating4
 143 ; CHECK-NEXT: Args:
 144 ; CHECK-NEXT:   - String:          'load of type '
 145 ; CHECK-NEXT:   - Type:            i32
 146 ; CHECK-NEXT:   - String:          ' not eliminated'
 147 ; CHECK-NEXT:   - String:          ' in favor of '
 148 ; CHECK-NEXT:   - OtherAccess:     store
 149 ; CHECK-NEXT:   - String:          ' because it is clobbered by '
 150 ; CHECK-NEXT:   - ClobberedBy:     call
 151 ; CHECK-NEXT: ...
 152
 153 ; Make sure isPotentiallyReachable() is not called for an instruction
 154 ; outside the current function, as it will cause a crash.
 155
 156 define dso_local void @nonDominating4(i1 %cond, i32 %b) local_unnamed_addr #0 {
 157 entry:
 158   br i1 %cond, label %if.then, label %if.end
 159
 160 if.then:                                          ; preds = %entry
 161   store i32 %b, ptr @g, align 4
 162   br label %if.end
 163
 164 if.end:                                           ; preds = %if.then, %entry
 165   tail call void @clobberingFunc() #1
 166   %0 = load i32, ptr @g, align 4
 167   %mul2 = shl nsw i32 %0, 1
 168   store i32 %mul2, ptr @g, align 4
 169   ret void
 170 }
 171
 172 @g = external global i32
 173
 174 define dso_local void @globalUser(i32 %b) local_unnamed_addr #0 {
 175 entry:
 176   store i32 %b, ptr @g, align 4
 177   ret void
 178 }
 179
 180 attributes #0 = { "use-soft-float"="false" }
 181 attributes #1 = { nounwind }
 182
 183 !llvm.ident = !{!0}
 184 !llvm.dbg.cu = !{!1}
 185 !llvm.module.flags = !{!4, !5, !6}
 186
 187 !0 = !{!"clang version 10.0.0 (git@github.com:llvm/llvm-project.git a2f6ae9abffcba260c22bb235879f0576bf3b783)"}
 188
 189 !1 = distinct !DICompileUnit(language: DW_LANG_C99, file: !2, producer: "clang version 4.0.0 (trunk 282540) (llvm/trunk 282542)", isOptimized: true, runtimeVersion: 0, emissionKind: LineTablesOnly, enums: !3)
 190 !2 = !DIFile(filename: "/tmp/s.c", directory: "/tmp")
 191 !3 = !{}
 192 !4 = !{i32 2, !"Dwarf Version", i32 4}
 193 !5 = !{i32 2, !"Debug Info Version", i32 3}
 194 !6 = !{i32 1, !"PIC Level", i32 2}
 195 !8 = distinct !DISubprogram(name: "nonDominating2", scope: !2, file: !2, line: 1, type: !9, isLocal: false, isDefinition: true, scopeLine: 1, isOptimized: true, unit: !1, retainedNodes: !3)
 196 !9 = !DISubroutineType(types: !10)
 197 !10 = !{null, !11, !12, !12, !13}
 198 !11 = !DIDerivedType(tag: DW_TAG_pointer_type, baseType: !12, size: 64)
 199 !12 = !DIBasicType(name: "int", size: 32, encoding: DW_ATE_signed)
 200 !13 = !DIBasicType(name: "_Bool", size: 8, encoding: DW_ATE_boolean)
 201 !14 = !DILocation(line: 1, column: 1, scope: !8)
 202 !15 = !DILocation(line: 2, column: 2, scope: !8)
 203 !16 = !DILocation(line: 3, column: 3, scope: !8)
 204 !17 = !DILocation(line: 4, column: 4, scope: !8)
 205 !18 = !DILocation(line: 5, column: 5, scope: !8)