llvm/test/Transforms/InstCombine/lower-dbg-declare.ll

   1 ; RUN: opt -passes=instcombine < %s -S | FileCheck %s
   2 ; RUN: opt -passes=instcombine < %s -S --try-experimental-debuginfo-iterators | FileCheck %s
   3
   4 ; This tests dbg.declare lowering for CallInst users of an alloca. The
   5 ; resulting dbg.value expressions should add a deref to the declare's expression.
   6
   7 ; Hand-reduced from this example (-g -Og -mllvm -disable-llvm-optzns -gno-column-info):
   8
   9 ; static volatile int sink;
  10 ; static void escape(int &c) { sink = c; }
  11 ; static bool empty ( int p1 ) { return p1 == 0; }
  12 ; int main() {
  13 ;   int d1 = 42;
  14 ;   while (!empty(d1))
  15 ;     escape(d1);
  16 ;   return 0;
  17 ; }
  18
  19 target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
  20 target triple = "x86_64-unknown-linux-gnu"
  21
  22 @_ZL4sink = internal global i32 0, align 4, !dbg !0
  23
  24 ; CHECK-LABEL: @main
  25 define dso_local i32 @main() !dbg !12 {
  26 entry:
  27   %retval = alloca i32, align 4
  28   %d1 = alloca i32, align 4
  29   store i32 0, ptr %retval, align 4
  30   call void @llvm.lifetime.start.p0(i64 4, ptr %d1) #4, !dbg !17
  31 ; CHECK: dbg.value(metadata i32 42, metadata [[METADATA_IDX1:![0-9]+]], metadata !DIExpression())
  32 ; CHECK-NEXT: store
  33   call void @llvm.dbg.declare(metadata ptr %d1, metadata !16, metadata !DIExpression()), !dbg !17
  34   store i32 42, ptr %d1, align 4, !dbg !17
  35   br label %while.cond, !dbg !22
  36
  37 while.cond:                                       ; preds = %while.body, %entry
  38 ; CHECK: dbg.value(metadata i32 %0, metadata [[METADATA_IDX1]], metadata !DIExpression())
  39 ; CHECK-NEXT: call zeroext i1 @_ZL5emptyi
  40   %0 = load i32, ptr %d1, align 4, !dbg !22
  41   %call = call zeroext i1 @_ZL5emptyi(i32 %0), !dbg !22
  42   %lnot = xor i1 %call, true, !dbg !22
  43   br i1 %lnot, label %while.body, label %while.end, !dbg !22
  44
  45 while.body:                                       ; preds = %while.cond
  46 ; CHECK: dbg.value(metadata ptr %d1, metadata [[METADATA_IDX1]], metadata !DIExpression(DW_OP_deref))
  47 ; CHECK-NEXT: call void @_ZL6escapeRi
  48   call void @_ZL6escapeRi(ptr dereferenceable(4) %d1), !dbg !23
  49   br label %while.cond, !dbg !22, !llvm.loop !24
  50
  51 while.end:                                        ; preds = %while.cond
  52   call void @llvm.lifetime.end.p0(i64 4, ptr %d1) #4, !dbg !25
  53   ret i32 0, !dbg !26
  54 }
  55
  56 declare void @llvm.lifetime.start.p0(i64 immarg, ptr nocapture)
  57
  58 declare void @llvm.dbg.declare(metadata, metadata, metadata)
  59
  60 define internal zeroext i1 @_ZL5emptyi(i32 %p1) !dbg !27 {
  61   ret i1 false
  62 }
  63
  64 define internal void @_ZL6escapeRi(ptr dereferenceable(4) %c) #3 !dbg !34 {
  65   ret void
  66 }
  67
  68 declare void @llvm.lifetime.end.p0(i64 immarg, ptr nocapture) #1
  69
  70 !llvm.dbg.cu = !{!2}
  71 !llvm.module.flags = !{!8, !9, !10}
  72 !llvm.ident = !{!11}
  73
  74 ; CHECK: DIGlobalVariableExpression
  75 ; CHECK: [[METADATA_IDX1]] = !DILocalVariable(name: "d1"
  76
  77 !0 = !DIGlobalVariableExpression(var: !1, expr: !DIExpression())
  78 !1 = distinct !DIGlobalVariable(name: "sink", linkageName: "_ZL4sink", scope: !2, file: !3, line: 2, type: !6, isLocal: true, isDefinition: true)
  79 !2 = distinct !DICompileUnit(language: DW_LANG_C_plus_plus, file: !3, producer: "clang", isOptimized: true, runtimeVersion: 0, emissionKind: FullDebug, enums: !4, globals: !5, nameTableKind: None)
  80 !3 = !DIFile(filename: "lower-dbg-declare.cpp", directory: "")
  81 !4 = !{}
  82 !5 = !{!0}
  83 !6 = !DIDerivedType(tag: DW_TAG_volatile_type, baseType: !7)
  84 !7 = !DIBasicType(name: "int", size: 32, encoding: DW_ATE_signed)
  85 !8 = !{i32 2, !"Dwarf Version", i32 4}
  86 !9 = !{i32 2, !"Debug Info Version", i32 3}
  87 !10 = !{i32 1, !"wchar_size", i32 4}
  88 !11 = !{!"clang"}
  89 !12 = distinct !DISubprogram(name: "main", scope: !3, file: !3, line: 5, type: !13, scopeLine: 5, flags: DIFlagPrototyped, spFlags: DISPFlagDefinition | DISPFlagOptimized, unit: !2, retainedNodes: !15)
  90 !13 = !DISubroutineType(types: !14)
  91 !14 = !{!7}
  92 !15 = !{!16}
  93 !16 = !DILocalVariable(name: "d1", scope: !12, file: !3, line: 6, type: !7)
  94 !17 = !DILocation(line: 6, scope: !12)
  95 !22 = !DILocation(line: 7, scope: !12)
  96 !23 = !DILocation(line: 8, scope: !12)
  97 !24 = distinct !{!24, !22, !23}
  98 !25 = !DILocation(line: 10, scope: !12)
  99 !26 = !DILocation(line: 9, scope: !12)
 100 !27 = distinct !DISubprogram(name: "empty", linkageName: "_ZL5emptyi", scope: !3, file: !3, line: 4, type: !28, scopeLine: 4, flags: DIFlagPrototyped, spFlags: DISPFlagLocalToUnit | DISPFlagDefinition | DISPFlagOptimized, unit: !2, retainedNodes: !31)
 101 !28 = !DISubroutineType(types: !29)
 102 !29 = !{!30, !7}
 103 !30 = !DIBasicType(name: "bool", size: 8, encoding: DW_ATE_boolean)
 104 !31 = !{!32}
 105 !32 = !DILocalVariable(name: "p1", arg: 1, scope: !27, file: !3, line: 4, type: !7)
 106 !33 = !DILocation(line: 4, scope: !27)
 107 !34 = distinct !DISubprogram(name: "escape", linkageName: "_ZL6escapeRi", scope: !3, file: !3, line: 3, type: !35, scopeLine: 3, flags: DIFlagPrototyped, spFlags: DISPFlagLocalToUnit | DISPFlagDefinition | DISPFlagOptimized, unit: !2, retainedNodes: !38)
 108 !35 = !DISubroutineType(types: !36)
 109 !36 = !{null, !37}
 110 !37 = !DIDerivedType(tag: DW_TAG_reference_type, baseType: !7, size: 64)
 111 !38 = !{!39}
 112 !39 = !DILocalVariable(name: "c", arg: 1, scope: !34, file: !3, line: 3, type: !37)
 113 !42 = !DILocation(line: 3, scope: !34)