llvm/test/Transforms/LoopDistribute/outside-use.ll

   1 ; RUN: opt -passes=loop-distribute -enable-loop-distribute -verify-loop-info -verify-dom-info -S < %s \
   2 ; RUN:   | FileCheck %s
   3
   4 ; Check that definitions used outside the loop are handled correctly: (1) they
   5 ; are not dropped (2) when version the loop, a phi is added to merge the value
   6 ; from the non-distributed loop and the distributed loop.
   7 ;
   8 ;   for (i = 0; i < n; i++) {
   9 ;     A[i + 1] = A[i] * B[i];
  10 ;   ==========================
  11 ;     sum += C[i];
  12 ;   }
  13
  14 target datalayout = "e-m:o-i64:64-f80:128-n8:16:32:64-S128"
  15 target triple = "x86_64-apple-macosx10.10.0"
  16
  17 @B = common global ptr null, align 8
  18 @A = common global ptr null, align 8
  19 @C = common global ptr null, align 8
  20 @D = common global ptr null, align 8
  21 @E = common global ptr null, align 8
  22 @SUM = common global i32 0, align 8
  23
  24 define void @f() {
  25 entry:
  26   %a = load ptr, ptr @A, align 8
  27   %b = load ptr, ptr @B, align 8
  28   %c = load ptr, ptr @C, align 8
  29   %d = load ptr, ptr @D, align 8
  30   %e = load ptr, ptr @E, align 8
  31
  32   br label %for.body
  33
  34 ; CHECK: for.body.ldist1:
  35 ; CHECK:   %mulA.ldist1 = mul i32 %loadB.ldist1, %loadA.ldist1
  36 ; CHECK: for.body.ph:
  37 ; CHECK: for.body:
  38 ; CHECK:   %sum_add = add nuw nsw i32 %sum, %loadC
  39 ; CHECK: for.end.loopexit:
  40 ; CHECK:   %sum_add.lver.ph = phi i32 [ %sum_add.lver.orig, %for.body.lver.orig ]
  41 ; CHECK: for.end.loopexit2:
  42 ; CHECK:   %sum_add.lver.ph3 = phi i32 [ %sum_add, %for.body ]
  43 ; CHECK: for.end:
  44 ; CHECK:   %sum_add.lver = phi i32 [ %sum_add.lver.ph, %for.end.loopexit ], [ %sum_add.lver.ph3, %for.end.loopexit2 ]
  45
  46 for.body:                                         ; preds = %for.body, %entry
  47   %ind = phi i64 [ 0, %entry ], [ %add, %for.body ]
  48   %sum = phi i32 [ 0, %entry ], [ %sum_add, %for.body ]
  49
  50   %arrayidxA = getelementptr inbounds i32, ptr %a, i64 %ind
  51   %loadA = load i32, ptr %arrayidxA, align 4
  52
  53   %arrayidxB = getelementptr inbounds i32, ptr %b, i64 %ind
  54   %loadB = load i32, ptr %arrayidxB, align 4
  55
  56   %mulA = mul i32 %loadB, %loadA
  57
  58   %add = add nuw nsw i64 %ind, 1
  59   %arrayidxA_plus_4 = getelementptr inbounds i32, ptr %a, i64 %add
  60   store i32 %mulA, ptr %arrayidxA_plus_4, align 4
  61
  62   %arrayidxC = getelementptr inbounds i32, ptr %c, i64 %ind
  63   %loadC = load i32, ptr %arrayidxC, align 4
  64
  65   %sum_add = add nuw nsw i32 %sum, %loadC
  66
  67   %exitcond = icmp eq i64 %add, 20
  68   br i1 %exitcond, label %for.end, label %for.body
  69
  70 for.end:                                          ; preds = %for.body
  71   store i32 %sum_add, ptr @SUM, align 4
  72   ret void
  73 }