llvm/test/Transforms/LoopVectorize/AArch64/extractvalue-no-scalarization-required.ll

   1 ; REQUIRES: asserts
   2
   3 ; RUN: opt -passes=loop-vectorize -mtriple=arm64-apple-ios %s -S -debug -disable-output 2>&1 | FileCheck --check-prefix=CM %s
   4 ; RUN: opt -passes=loop-vectorize -force-vector-width=2 -force-vector-interleave=1 %s -S | FileCheck --check-prefix=FORCED %s
   5
   6 ; Test case from PR41294.
   7
   8 ; Check scalar cost for extractvalue. The constant and loop invariant operands are free,
   9 ; leaving cost 3 for scalarizing the result + 2 for executing the op with VF 2.
  10
  11 ; CM: LV: Found uniform instruction:   %a = extractvalue { i64, i64 } %sv, 0
  12 ; CM: LV: Found uniform instruction:   %b = extractvalue { i64, i64 } %sv, 1
  13
  14 ; CM: LV: Scalar loop costs: 5.
  15 ; CM: LV: Found an estimated cost of 0 for VF 2 For instruction:   %a = extractvalue { i64, i64 } %sv, 0
  16 ; CM-NEXT: LV: Found an estimated cost of 0 for VF 2 For instruction:   %b = extractvalue { i64, i64 } %sv, 1
  17
  18 ; Check that the extractvalue operands are actually free in vector code.
  19
  20 ; FORCED-LABEL: vector.body:                                      ; preds = %vector.body, %vector.ph
  21 ; FORCED-NEXT:    %index = phi i32 [ 0, %vector.ph ], [ %index.next, %vector.body ]
  22 ; FORCED-NEXT:    %0 = add i32 %index, 0
  23 ; FORCED-NEXT:    %1 = extractvalue { i64, i64 } %sv, 0
  24 ; FORCED-NEXT:    %broadcast.splatinsert = insertelement <2 x i64> poison, i64 %1, i64 0
  25 ; FORCED-NEXT:    %broadcast.splat = shufflevector <2 x i64> %broadcast.splatinsert, <2 x i64> poison, <2 x i32> zeroinitializer
  26 ; FORCED-NEXT:    %2 = extractvalue { i64, i64 } %sv, 1
  27 ; FORCED-NEXT:    %broadcast.splatinsert1 = insertelement <2 x i64> poison, i64 %2, i64 0
  28 ; FORCED-NEXT:    %broadcast.splat2 = shufflevector <2 x i64> %broadcast.splatinsert1, <2 x i64> poison, <2 x i32> zeroinitializer
  29 ; FORCED-NEXT:    %3 = getelementptr i64, ptr %dst, i32 %0
  30 ; FORCED-NEXT:    %4 = add <2 x i64> %broadcast.splat, %broadcast.splat2
  31 ; FORCED-NEXT:    %5 = getelementptr i64, ptr %3, i32 0
  32 ; FORCED-NEXT:    store <2 x i64> %4, ptr %5, align 4
  33 ; FORCED-NEXT:    %index.next = add nuw i32 %index, 2
  34 ; FORCED-NEXT:    %6 = icmp eq i32 %index.next, 1000
  35 ; FORCED-NEXT:    br i1 %6, label %middle.block, label %vector.body
  36
  37 define void @test1(ptr %dst, {i64, i64} %sv) {
  38 entry:
  39   br label %loop.body
  40
  41 loop.body:
  42   %iv = phi i32 [ 0, %entry ], [ %iv.next, %loop.body ]
  43   %a = extractvalue { i64, i64 } %sv, 0
  44   %b = extractvalue { i64, i64 } %sv, 1
  45   %addr = getelementptr i64, ptr %dst, i32 %iv
  46   %add = add i64 %a, %b
  47   store i64 %add, ptr %addr
  48   %iv.next = add nsw i32 %iv, 1
  49   %cond = icmp ne i32 %iv.next, 1000
  50   br i1 %cond, label %loop.body, label %exit
  51
  52 exit:
  53   ret void
  54 }
  55
  56
  57 ; Similar to the test case above, but checks getVectorCallCost as well.
  58 declare float @powf(float, float) readnone nounwind
  59
  60 ; CM: LV: Found uniform instruction:   %a = extractvalue { float, float } %sv, 0
  61 ; CM: LV: Found uniform instruction:   %b = extractvalue { float, float } %sv, 1
  62
  63 ; CM: LV: Scalar loop costs: 14.
  64 ; CM: LV: Found an estimated cost of 0 for VF 2 For instruction:   %a = extractvalue { float, float } %sv, 0
  65 ; CM-NEXT: LV: Found an estimated cost of 0 for VF 2 For instruction:   %b = extractvalue { float, float } %sv, 1
  66
  67 ; FORCED-LABEL: define void @test_getVectorCallCost
  68
  69 ; FORCED-LABEL: vector.body:                                      ; preds = %vector.body, %vector.ph
  70 ; FORCED-NEXT:    %index = phi i32 [ 0, %vector.ph ], [ %index.next, %vector.body ]
  71 ; FORCED-NEXT:    %0 = add i32 %index, 0
  72 ; FORCED-NEXT:    %1 = extractvalue { float, float } %sv, 0
  73 ; FORCED-NEXT:    %broadcast.splatinsert = insertelement <2 x float> poison, float %1, i64 0
  74 ; FORCED-NEXT:    %broadcast.splat = shufflevector <2 x float> %broadcast.splatinsert, <2 x float> poison, <2 x i32> zeroinitializer
  75 ; FORCED-NEXT:    %2 = extractvalue { float, float } %sv, 1
  76 ; FORCED-NEXT:    %broadcast.splatinsert1 = insertelement <2 x float> poison, float %2, i64 0
  77 ; FORCED-NEXT:    %broadcast.splat2 = shufflevector <2 x float> %broadcast.splatinsert1, <2 x float> poison, <2 x i32> zeroinitializer
  78 ; FORCED-NEXT:    %3 = getelementptr float, ptr %dst, i32 %0
  79 ; FORCED-NEXT:    %4 = call <2 x float> @llvm.pow.v2f32(<2 x float> %broadcast.splat, <2 x float> %broadcast.splat2)
  80 ; FORCED-NEXT:    %5 = getelementptr float, ptr %3, i32 0
  81 ; FORCED-NEXT:    store <2 x float> %4, ptr %5, align 4
  82 ; FORCED-NEXT:    %index.next = add nuw i32 %index, 2
  83 ; FORCED-NEXT:    %6 = icmp eq i32 %index.next, 1000
  84 ; FORCED-NEXT:    br i1 %6, label %middle.block, label %vector.body
  85
  86 define void @test_getVectorCallCost(ptr %dst, {float, float} %sv) {
  87 entry:
  88   br label %loop.body
  89
  90 loop.body:
  91   %iv = phi i32 [ 0, %entry ], [ %iv.next, %loop.body ]
  92   %a = extractvalue { float, float } %sv, 0
  93   %b = extractvalue { float, float } %sv, 1
  94   %addr = getelementptr float, ptr %dst, i32 %iv
  95   %p = call float @powf(float %a, float %b)
  96   store float %p, ptr %addr
  97   %iv.next = add nsw i32 %iv, 1
  98   %cond = icmp ne i32 %iv.next, 1000
  99   br i1 %cond, label %loop.body, label %exit
 100
 101 exit:
 102   ret void
 103 }