llvm/cmake/modules/CheckCompilerVersion.cmake

   1 # Check if the host compiler is new enough.
   2 # These versions are updated based on the following policy:
   3 #   llvm.org/docs/DeveloperPolicy.html#toolchain
   4
   5 include(CheckCXXSourceCompiles)
   6
   7 set(GCC_MIN 5.1)
   8 set(GCC_SOFT_ERROR 5.1)
   9 set(CLANG_MIN 3.5)
  10 set(CLANG_SOFT_ERROR 3.5)
  11 set(APPLECLANG_MIN 6.0)
  12 set(APPLECLANG_SOFT_ERROR 6.0)
  13
  14 # https://en.wikipedia.org/wiki/Microsoft_Visual_C#Internal_version_numbering
  15 # _MSC_VER == 1914 MSVC++ 14.14 (Visual Studio 2017 version 15.4)
  16 set(MSVC_MIN 19.14)
  17 set(MSVC_SOFT_ERROR 19.14)
  18
  19 # Map the above GCC versions to dates: https://gcc.gnu.org/develop.html#timeline
  20 set(GCC_MIN_DATE 20150422)
  21 set(GCC_SOFT_ERROR_DATE 20150422)
  22
  23
  24 if(DEFINED LLVM_COMPILER_CHECKED)
  25   return()
  26 endif()
  27 set(LLVM_COMPILER_CHECKED ON)
  28
  29 if(LLVM_FORCE_USE_OLD_TOOLCHAIN)
  30   return()
  31 endif()
  32
  33 function(check_compiler_version NAME NICE_NAME MINIMUM_VERSION SOFT_ERROR_VERSION)
  34   if(NOT CMAKE_CXX_COMPILER_ID STREQUAL NAME)
  35     return()
  36   endif()
  37   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS MINIMUM_VERSION)
  38     message(FATAL_ERROR "Host ${NICE_NAME} version must be at least ${MINIMUM_VERSION}, your version is ${CMAKE_CXX_COMPILER_VERSION}.")
  39   elseif(CMAKE_CXX_COMPILER_VERSION VERSION_LESS SOFT_ERROR_VERSION)
  40     if(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN)
  41       message(WARNING "Host ${NICE_NAME} version should be at least ${SOFT_ERROR_VERSION} because LLVM will soon use new C++ features which your toolchain version doesn't support. Your version is ${CMAKE_CXX_COMPILER_VERSION}. Ignoring because you've set LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
  42     else()
  43       message(FATAL_ERROR "Host ${NICE_NAME} version should be at least ${SOFT_ERROR_VERSION} because LLVM will soon use new C++ features which your toolchain version doesn't support. Your version is ${CMAKE_CXX_COMPILER_VERSION}. You can temporarily opt out using LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
  44     endif()
  45   endif()
  46 endfunction(check_compiler_version)
  47
  48 check_compiler_version("GNU" "GCC" ${GCC_MIN} ${GCC_SOFT_ERROR})
  49 check_compiler_version("Clang" "Clang" ${CLANG_MIN} ${CLANG_SOFT_ERROR})
  50 check_compiler_version("AppleClang" "Apple Clang" ${APPLECLANG_MIN} ${APPLECLANG_SOFT_ERROR})
  51 check_compiler_version("MSVC" "Visual Studio" ${MSVC_MIN} ${MSVC_SOFT_ERROR})
  52
  53 # See https://developercommunity.visualstudio.com/content/problem/845933/miscompile-boolean-condition-deduced-to-be-always.html
  54 # and thread "[llvm-dev] Longstanding failing tests - clang-tidy, MachO, Polly"
  55 # on llvm-dev Jan 21-23 2020.
  56 if ((${CMAKE_CXX_COMPILER_ID} STREQUAL MSVC) AND
  57     (19.24 VERSION_LESS_EQUAL ${CMAKE_CXX_COMPILER_VERSION}) AND
  58     (${CMAKE_CXX_COMPILER_VERSION} VERSION_LESS 19.25))
  59   if(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN)
  60     message(WARNING "Host Visual Studio version 16.4 is known to miscompile part of LLVM")
  61   else()
  62     message(FATAL_ERROR "Host Visual Studio version 16.4 is known to miscompile part of LLVM, please use clang-cl or upgrade to 16.5 or above (use -DLLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN=ON to ignore)")
  63   endif()
  64 endif()
  65
  66
  67 if(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  68   if (CMAKE_CXX_SIMULATE_ID MATCHES "MSVC")
  69     if (CMAKE_CXX_SIMULATE_VERSION VERSION_LESS MSVC_MIN)
  70       message(FATAL_ERROR "Host Clang must have at least -fms-compatibility-version=${MSVC_MIN}, your version is ${CMAKE_CXX_SIMULATE_VERSION}.")
  71     endif()
  72     set(CLANG_CL 1)
  73   elseif(NOT LLVM_ENABLE_LIBCXX)
  74     # Test that we aren't using too old of a version of libstdc++.
  75     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  76     set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  77     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++0x")
  78     # Test for libstdc++ version of at least 4.8 by checking for _ZNKSt17bad_function_call4whatEv.
  79     # Note: We should check _GLIBCXX_RELEASE when possible (i.e., for GCC 7.1 and up).
  80     check_cxx_source_compiles("
  81 #include <iosfwd>
  82 #if defined(__GLIBCXX__)
  83 #if __GLIBCXX__ < ${GCC_MIN_DATE}
  84 #error Unsupported libstdc++ version
  85 #endif
  86 #endif
  87 #if defined(__GLIBCXX__)
  88 extern const char _ZNKSt17bad_function_call4whatEv[];
  89 const char *chk = _ZNKSt17bad_function_call4whatEv;
  90 #else
  91 const char *chk = \"\";
  92 #endif
  93 int main() { ++chk; return 0; }
  94 "
  95       LLVM_LIBSTDCXX_MIN)
  96     if(NOT LLVM_LIBSTDCXX_MIN)
  97       message(FATAL_ERROR "libstdc++ version must be at least ${GCC_MIN}.")
  98     endif()
  99     # Test for libstdc++ version of at least 5.1 by checking for std::iostream_category().
 100     # Note: We should check _GLIBCXX_RELEASE when possible (i.e., for GCC 7.1 and up).
 101     check_cxx_source_compiles("
 102 #include <iosfwd>
 103 #if defined(__GLIBCXX__)
 104 #if __GLIBCXX__ < ${GCC_SOFT_ERROR_DATE}
 105 #error Unsupported libstdc++ version
 106 #endif
 107 #endif
 108 #if defined(__GLIBCXX__)
 109 #include <ios>
 110 void foo(void) { (void) std::iostream_category(); }
 111 #endif
 112 int main() { return 0; }
 113 "
 114       LLVM_LIBSTDCXX_SOFT_ERROR)
 115     if(NOT LLVM_LIBSTDCXX_SOFT_ERROR)
 116       if(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN)
 117         message(WARNING "libstdc++ version should be at least ${GCC_SOFT_ERROR} because LLVM will soon use new C++ features which your toolchain version doesn't support. Ignoring because you've set LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
 118       else()
 119         message(FATAL_ERROR "libstdc++ version should be at least ${GCC_SOFT_ERROR} because LLVM will soon use new C++ features which your toolchain version doesn't support. You can temporarily opt out using LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
 120       endif()
 121     endif()
 122     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 123     set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
 124   endif()
 125 endif()