llvm/lib/Target/WebAssembly/WebAssemblyInstrControl.td

   1 //===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6 //
   7 //===----------------------------------------------------------------------===//
   8 ///
   9 /// \file
  10 /// WebAssembly control-flow code-gen constructs.
  11 ///
  12 //===----------------------------------------------------------------------===//
  13
  14 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
  15 // The condition operand is a boolean value which WebAssembly represents as i32.
  16 defm BR_IF : I<(outs), (ins bb_op:$dst, I32:$cond),
  17                (outs), (ins bb_op:$dst),
  18                [(brcond I32:$cond, bb:$dst)],
  19                 "br_if   \t$dst, $cond", "br_if   \t$dst", 0x0d>;
  20 let isCodeGenOnly = 1 in
  21 defm BR_UNLESS : I<(outs), (ins bb_op:$dst, I32:$cond),
  22                    (outs), (ins bb_op:$dst), []>;
  23 let isBarrier = 1 in
  24 defm BR   : NRI<(outs), (ins bb_op:$dst),
  25                 [(br bb:$dst)],
  26                 "br      \t$dst", 0x0c>;
  27 } // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
  28
  29 def : Pat<(brcond (i32 (setne I32:$cond, 0)), bb:$dst),
  30           (BR_IF bb_op:$dst, I32:$cond)>;
  31 def : Pat<(brcond (i32 (seteq I32:$cond, 0)), bb:$dst),
  32           (BR_UNLESS bb_op:$dst, I32:$cond)>;
  33 def : Pat<(brcond (i32 (xor bool_node:$cond, (i32 1))), bb:$dst),
  34           (BR_UNLESS bb_op:$dst, I32:$cond)>;
  35
  36 // A list of branch targets enclosed in {} and separated by comma.
  37 // Used by br_table only.
  38 def BrListAsmOperand : AsmOperandClass { let Name = "BrList"; }
  39 let OperandNamespace = "WebAssembly", OperandType = "OPERAND_BRLIST" in
  40 def brlist : Operand<i32> {
  41   let ParserMatchClass = BrListAsmOperand;
  42   let PrintMethod = "printBrList";
  43 }
  44
  45 // Duplicating a BR_TABLE is almost never a good idea. In particular, it can
  46 // lead to some nasty irreducibility due to tail merging when the br_table is in
  47 // a loop.
  48 let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1, isNotDuplicable = 1 in {
  49
  50 defm BR_TABLE_I32 : I<(outs), (ins I32:$index, variable_ops),
  51                       (outs), (ins brlist:$brl),
  52                       [(WebAssemblybr_table I32:$index)],
  53                       "br_table \t$index", "br_table \t$brl",
  54                       0x0e>;
  55 // TODO: SelectionDAG's lowering insists on using a pointer as the index for
  56 // jump tables, so in practice we don't ever use BR_TABLE_I64 in wasm32 mode
  57 // currently.
  58 defm BR_TABLE_I64 : I<(outs), (ins I64:$index, variable_ops),
  59                       (outs), (ins brlist:$brl),
  60                       [(WebAssemblybr_table I64:$index)],
  61                       "br_table \t$index", "br_table \t$brl",
  62                       0x0e>;
  63 } // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1, isNotDuplicable = 1
  64
  65 // This is technically a control-flow instruction, since all it affects is the
  66 // IP.
  67 defm NOP : NRI<(outs), (ins), [], "nop", 0x01>;
  68
  69 // Placemarkers to indicate the start or end of a block or loop scope.
  70 // These use/clobber VALUE_STACK to prevent them from being moved into the
  71 // middle of an expression tree.
  72 let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
  73 defm BLOCK : NRI<(outs), (ins Signature:$sig), [], "block   \t$sig", 0x02>;
  74 defm LOOP  : NRI<(outs), (ins Signature:$sig), [], "loop    \t$sig", 0x03>;
  75
  76 defm IF : I<(outs), (ins Signature:$sig, I32:$cond),
  77             (outs), (ins Signature:$sig),
  78             [], "if    \t$sig, $cond", "if    \t$sig", 0x04>;
  79 defm ELSE : NRI<(outs), (ins), [], "else", 0x05>;
  80
  81 // END_BLOCK, END_LOOP, END_IF and END_FUNCTION are represented with the same
  82 // opcode in wasm.
  83 defm END_BLOCK : NRI<(outs), (ins), [], "end_block", 0x0b>;
  84 defm END_LOOP  : NRI<(outs), (ins), [], "end_loop", 0x0b>;
  85 defm END_IF    : NRI<(outs), (ins), [], "end_if", 0x0b>;
  86 // Generic instruction, for disassembler.
  87 let IsCanonical = 1 in
  88 defm END       : NRI<(outs), (ins), [], "end", 0x0b>;
  89 let isTerminator = 1, isBarrier = 1 in
  90 defm END_FUNCTION : NRI<(outs), (ins), [], "end_function", 0x0b>;
  91 } // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
  92
  93
  94 let hasCtrlDep = 1, isBarrier = 1 in {
  95 let isTerminator = 1 in {
  96 let isReturn = 1 in {
  97
  98 defm RETURN : I<(outs), (ins variable_ops), (outs), (ins),
  99                 [(WebAssemblyreturn)],
 100                 "return", "return", 0x0f>;
 101 // Equivalent to RETURN, for use at the end of a function when wasm
 102 // semantics return by falling off the end of the block.
 103 let isCodeGenOnly = 1 in
 104 defm FALLTHROUGH_RETURN : I<(outs), (ins variable_ops), (outs), (ins), []>;
 105
 106 } // isReturn = 1
 107
 108 let IsCanonical = 1, isTrap = 1 in
 109 defm UNREACHABLE : NRI<(outs), (ins), [(trap)], "unreachable", 0x00>;
 110
 111 } // isTerminator = 1
 112
 113 // debugtrap explicitly returns despite trapping because it is supposed to just
 114 // get the attention of the debugger. Unfortunately, because UNREACHABLE is a
 115 // terminator, lowering debugtrap to UNREACHABLE can create an invalid
 116 // MachineBasicBlock when there is additional code after it. Lower it to this
 117 // non-terminator version instead.
 118 // TODO: Actually execute the debugger statement when running on the Web
 119 let isTrap = 1 in
 120 defm DEBUG_UNREACHABLE : NRI<(outs), (ins), [(debugtrap)], "unreachable", 0x00>;
 121
 122 } // hasCtrlDep = 1, isBarrier = 1
 123
 124 //===----------------------------------------------------------------------===//
 125 // Exception handling instructions
 126 //===----------------------------------------------------------------------===//
 127
 128 let Predicates = [HasExceptionHandling] in {
 129
 130 // Throwing an exception: throw / rethrow
 131 let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
 132 defm THROW : I<(outs), (ins tag_op:$tag, variable_ops),
 133                (outs), (ins tag_op:$tag), [],
 134                "throw   \t$tag", "throw   \t$tag", 0x08>;
 135 defm RETHROW : NRI<(outs), (ins i32imm:$depth), [], "rethrow \t$depth", 0x09>;
 136 } // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
 137 // The depth argument will be computed in CFGStackify. We set it to 0 here for
 138 // now.
 139 def : Pat<(int_wasm_rethrow), (RETHROW 0)>;
 140
 141 // Region within which an exception is caught: try / end_try
 142 let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
 143 defm TRY     : NRI<(outs), (ins Signature:$sig), [], "try     \t$sig", 0x06>;
 144 defm END_TRY : NRI<(outs), (ins), [], "end_try", 0x0b>;
 145 } // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
 146
 147 // Catching an exception: catch / catch_all
 148 let hasCtrlDep = 1, hasSideEffects = 1 in {
 149 let variadicOpsAreDefs = 1 in
 150 defm CATCH : I<(outs), (ins tag_op:$tag, variable_ops),
 151                (outs), (ins tag_op:$tag), [],
 152                "catch",  "catch   \t$tag", 0x07>;
 153 defm CATCH_ALL : NRI<(outs), (ins), [], "catch_all", 0x19>;
 154 }
 155
 156 // Delegating an exception: delegate
 157 let isTerminator = 1, hasCtrlDep = 1, hasSideEffects = 1 in
 158 defm DELEGATE : NRI<(outs), (ins bb_op:$dst), [], "delegate \t $dst", 0x18>;
 159
 160 // Pseudo instructions: cleanupret / catchret
 161 let isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
 162     isPseudo = 1, isEHScopeReturn = 1 in {
 163   defm CLEANUPRET : NRI<(outs), (ins), [(cleanupret)], "cleanupret", 0>;
 164   defm CATCHRET : NRI<(outs), (ins bb_op:$dst, bb_op:$from),
 165                       [(catchret bb:$dst, bb:$from)], "catchret", 0>;
 166 } // isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
 167   // isPseudo = 1, isEHScopeReturn = 1
 168 } // Predicates = [HasExceptionHandling]