llvm/test/Analysis/Delinearization/multidim_ivs_and_integer_offsets_3d.ll

   1 ; RUN: opt < %s -analyze -enable-new-pm=0 -delinearize  | FileCheck %s
   2 ; RUN: opt < %s -passes='print<delinearization>' -disable-output  2>&1 | FileCheck %s
   3
   4 ; void foo(long n, long m, long o, double A[n][m][o]) {
   5 ;
   6 ;   for (long i = 0; i < n; i++)
   7 ;     for (long j = 0; j < m; j++)
   8 ;       for (long k = 0; k < o; k++)
   9 ;         A[i+3][j-4][k+7] = 1.0;
  10 ; }
  11
  12 ; AddRec: {{{(56 + (8 * (-4 + (3 * %m)) * %o) + %A),+,(8 * %m * %o)}<%for.i>,+,(8 * %o)}<%for.j>,+,8}<%for.k>
  13 ; CHECK: Base offset: %A
  14 ; CHECK: ArrayDecl[UnknownSize][%m][%o] with elements of 8 bytes.
  15 ; CHECK: ArrayRef[{3,+,1}<nuw><%for.i>][{-4,+,1}<nw><%for.j>][{7,+,1}<nuw><nsw><%for.k>]
  16
  17 define void @foo(i64 %n, i64 %m, i64 %o, double* %A) {
  18 entry:
  19   br label %for.i
  20
  21 for.i:
  22   %i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
  23   br label %for.j
  24
  25 for.j:
  26   %j = phi i64 [ 0, %for.i ], [ %j.inc, %for.j.inc ]
  27   br label %for.k
  28
  29 for.k:
  30   %k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
  31   %offset0 = add nsw i64 %i, 3
  32   %subscript0 = mul i64 %offset0, %m
  33   %offset1 = add nsw i64 %j, -4
  34   %subscript1 = add i64 %offset1, %subscript0
  35   %subscript2 = mul i64 %subscript1, %o
  36   %offset2 = add nsw i64 %k, 7
  37   %subscript = add i64 %subscript2, %offset2
  38   %idx = getelementptr inbounds double, double* %A, i64 %subscript
  39   store double 1.0, double* %idx
  40   br label %for.k.inc
  41
  42 for.k.inc:
  43   %k.inc = add nsw i64 %k, 1
  44   %k.exitcond = icmp eq i64 %k.inc, %o
  45   br i1 %k.exitcond, label %for.j.inc, label %for.k
  46
  47 for.j.inc:
  48   %j.inc = add nsw i64 %j, 1
  49   %j.exitcond = icmp eq i64 %j.inc, %m
  50   br i1 %j.exitcond, label %for.i.inc, label %for.j
  51
  52 for.i.inc:
  53   %i.inc = add nsw i64 %i, 1
  54   %i.exitcond = icmp eq i64 %i.inc, %n
  55   br i1 %i.exitcond, label %end, label %for.i
  56
  57 end:
  58   ret void
  59 }