llvm/test/Analysis/DependenceAnalysis/Invariant.ll

   1 ; RUN: opt < %s -disable-output "-passes=print<da>" -aa-pipeline=basic-aa 2>&1 \
   2 ; RUN: | FileCheck %s
   3 ; RUN: opt < %s -analyze -enable-new-pm=0 -basic-aa -da | FileCheck %s
   4
   5 ; Test for a bug, which caused an assert when an invalid
   6 ; SCEVAddRecExpr is created in addToCoefficient.
   7
   8 ; float foo (float g, float* rr[40]) {
   9 ;   float res= 0.0f;
  10 ;   for (int i = 0; i < 40; i += 5) {
  11 ;     for (int j = 0; j < 40; j += 5) {
  12 ;       float add = rr[j][j] + rr[i][j];
  13 ;       res = add > g? add : res;
  14 ;     }
  15 ;   }
  16 ;   return res;
  17 ; }
  18
  19 ; CHECK-LABEL: foo
  20 ; CHECK: da analyze - consistent input [S 0]!
  21 ; CHECK: da analyze - input [* 0|<]!
  22 ; CHECK: da analyze - none!
  23
  24 define float @foo(float %g, [40 x float]* %rr) nounwind {
  25 entry:
  26   br label %for.cond1.preheader
  27
  28 for.cond1.preheader:
  29   %i.04 = phi i32 [ 0, %entry ], [ %add10, %for.inc9 ]
  30   %res.03 = phi float [ 0.000000e+00, %entry ], [ %add.res.1, %for.inc9 ]
  31   br label %for.body3
  32
  33 for.body3:
  34   %j.02 = phi i32 [ 0, %for.cond1.preheader ], [ %add8, %for.body3 ]
  35   %res.11 = phi float [ %res.03, %for.cond1.preheader ], [ %add.res.1, %for.body3 ]
  36   %arrayidx4 = getelementptr inbounds [40 x float], [40 x float]* %rr, i32 %j.02, i32 %j.02
  37   %0 = load float, float* %arrayidx4, align 4
  38   %arrayidx6 = getelementptr inbounds [40 x float], [40 x float]* %rr, i32 %i.04, i32 %j.02
  39   %1 = load float, float* %arrayidx6, align 4
  40   %add = fadd float %0, %1
  41   %cmp7 = fcmp ogt float %add, %g
  42   %add.res.1 = select i1 %cmp7, float %add, float %res.11
  43   %add8 = add nsw i32 %j.02, 5
  44   %cmp2 = icmp slt i32 %add8, 40
  45   br i1 %cmp2, label %for.body3, label %for.inc9
  46
  47 for.inc9:
  48   %add10 = add nsw i32 %i.04, 5
  49   %cmp = icmp slt i32 %add10, 40
  50   br i1 %cmp, label %for.cond1.preheader, label %for.end11
  51
  52 for.end11:
  53   ret float %add.res.1
  54 }