llvm/test/Analysis/LoopCacheAnalysis/PowerPC/stencil.ll

   1 ; RUN: opt < %s -passes='print<loop-cache-cost>' -disable-output 2>&1 | FileCheck %s
   2
   3 target datalayout = "e-m:e-i64:64-n32:64"
   4 target triple = "powerpc64le-unknown-linux-gnu"
   5
   6 ; void foo(long n, long m, long o, int A[n][m], int B[n][m], int C[n]) {
   7 ;   for (long i = 0; i < n; i++)
   8 ;     for (long j = 0; j < m; j++) {
   9 ;         A[i][j] = A[i][j+1] + B[i-1][j] + B[i+1][j+1] + C[i];
  10 ;         A[i][j] += B[i][i];
  11 ;     }
  12 ; }
  13
  14 ; CHECK-DAG: Loop 'for.i' has cost = 20600
  15 ; CHECK-DAG: Loop 'for.j' has cost = 800
  16
  17 define void @foo(i64 %n, i64 %m, i32* %A, i32* %B, i32* %C) {
  18 entry:
  19   %cmp32 = icmp sgt i64 %n, 0
  20   %cmp230 = icmp sgt i64 %m, 0
  21   br i1 %cmp32, label %for.cond1.preheader.lr.ph, label %for.end
  22
  23 for.cond1.preheader.lr.ph:                        ; preds = %entry
  24   br i1 %cmp230, label %for.i.preheader, label %for.end
  25
  26 for.i.preheader:                                  ; preds = %for.cond1.preheader.lr.ph
  27   br label %for.i
  28
  29 for.i:                                            ; preds = %for.inci, %for.i.preheader.split
  30   %i = phi i64 [ %inci, %for.inci ], [ 0, %for.i.preheader ]
  31   %subione = sub i64 %i, 1
  32   %addione = add i64 %i, 1
  33   %muli = mul i64 %i, %m
  34   %muliminusone = mul i64 %subione, %m
  35   %muliplusone = mul i64 %addione, %m
  36   br label %for.j
  37
  38 for.j:                                            ; preds = %for.incj, %for.i
  39   %j = phi i64 [ %incj, %for.incj ], [ 0, %for.i ]
  40   %addj = add i64 %muli, %j
  41
  42   ; B[i-1][j]
  43   %arrayidx1 = add i64 %j, %muliminusone
  44   %arrayidx2 = getelementptr inbounds i32, i32* %B, i64 %arrayidx1
  45   %elem_B1 = load i32, i32* %arrayidx2, align 4
  46
  47   ; B[i-1][j+1]
  48   %addjone = add i64 %j, 1
  49   %arrayidx3 = add i64 %addjone, %muliminusone
  50   %arrayidx4 = getelementptr inbounds i32, i32* %B, i64 %arrayidx3
  51   %elem_B2 = load i32, i32* %arrayidx4, align 4
  52
  53   ; C[i]
  54   %arrayidx6 = getelementptr inbounds i32, i32* %C, i64 %i
  55   %elem_C = load i32, i32* %arrayidx6, align 4
  56
  57   ; A[i][j+1]
  58   %arrayidx7 = add i64 %addjone, %muli
  59   %arrayidx8 = getelementptr inbounds i32, i32* %A, i64 %arrayidx7
  60   %elem_A = load i32, i32* %arrayidx8, align 4
  61
  62   ; A[i][j] = A[i][j+1] + B[i-1][j] + B[i-1][j+1] + C[i]
  63   %addB = add i32 %elem_B1, %elem_B2
  64   %addC = add i32 %addB, %elem_C
  65   %addA = add i32 %elem_A, %elem_C
  66   %arrayidx9 = add i64 %j, %muli
  67   %arrayidx10 = getelementptr inbounds i32, i32* %A, i64 %arrayidx9
  68   store i32 %addA, i32* %arrayidx10, align 4
  69
  70   ; A[i][j] += B[i][i];
  71   %arrayidx11 = add i64 %j, %muli
  72   %arrayidx12 = getelementptr inbounds i32, i32* %A, i64 %arrayidx11
  73   %elem_A1 = load i32, i32* %arrayidx12, align 4
  74   %arrayidx13 = add i64 %i, %muli
  75   %arrayidx14 = getelementptr inbounds i32, i32* %B, i64 %arrayidx13
  76   %elem_B3 = load i32, i32* %arrayidx14, align 4
  77   %addA1 = add i32 %elem_A1, %elem_B3
  78   store i32 %addA1, i32* %arrayidx12, align 4
  79
  80   br label %for.incj
  81
  82 for.incj:                                         ; preds = %for.j
  83   %incj = add nsw i64 %j, 1
  84   %exitcond54.us = icmp eq i64 %incj, %m
  85   br i1 %exitcond54.us, label %for.inci, label %for.j
  86
  87 for.inci:                                         ; preds = %for.incj
  88   %inci = add nsw i64 %i, 1
  89   %exitcond55.us = icmp eq i64 %inci, %n
  90   br i1 %exitcond55.us, label %for.end.loopexit, label %for.i
  91
  92 for.end.loopexit:                                 ; preds = %for.inci
  93   br label %for.end
  94
  95 for.end:                                          ; preds = %for.end.loopexit, %for.cond1.preheader.lr.ph, %entry
  96   ret void
  97 }
  98