llvm/test/Analysis/ScalarEvolution/min-max-exprs.ll

   1 ; RUN: opt -scalar-evolution -analyze -enable-new-pm=0 < %s | FileCheck %s
   2 ; RUN: opt "-passes=print<scalar-evolution>" -disable-output < %s 2>&1 | FileCheck %s
   3 ;
   4 ; This checks if the min and max expressions are properly recognized by
   5 ; ScalarEvolution even though they the ICmpInst and SelectInst have different
   6 ; types.
   7 ;
   8 ;    #define max(a, b) (a > b ? a : b)
   9 ;    #define min(a, b) (a < b ? a : b)
  10 ;
  11 ;    void f(int *A, int N) {
  12 ;      for (int i = 0; i < N; i++) {
  13 ;        A[max(0, i - 3)] = A[min(N, i + 3)] * 2;
  14 ;      }
  15 ;    }
  16 ;
  17 target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
  18
  19 define void @f(i32* %A, i32 %N) {
  20 bb:
  21   br label %bb1
  22
  23 bb1:                                              ; preds = %bb2, %bb
  24   %i.0 = phi i32 [ 0, %bb ], [ %tmp23, %bb2 ]
  25   %i.0.1 = sext i32 %i.0 to i64
  26   %tmp = icmp slt i32 %i.0, %N
  27   br i1 %tmp, label %bb2, label %bb24
  28
  29 bb2:                                              ; preds = %bb1
  30   %tmp3 = add nuw nsw i32 %i.0, 3
  31   %tmp4 = icmp slt i32 %tmp3, %N
  32   %tmp5 = sext i32 %tmp3 to i64
  33   %tmp6 = sext i32 %N to i64
  34   %tmp9 = select i1 %tmp4, i64 %tmp5, i64 %tmp6
  35 ;                  min(N, i+3)
  36 ; CHECK:           select i1 %tmp4, i64 %tmp5, i64 %tmp6
  37 ; CHECK-NEXT:  --> ((sext i32 {3,+,1}<nuw><%bb1> to i64) smin (sext i32 %N to i64))
  38   %tmp11 = getelementptr inbounds i32, i32* %A, i64 %tmp9
  39   %tmp12 = load i32, i32* %tmp11, align 4
  40   %tmp13 = shl nsw i32 %tmp12, 1
  41   %tmp14 = icmp sge i32 3, %i.0
  42   %tmp17 = add nsw i64 %i.0.1, -3
  43   %tmp19 = select i1 %tmp14, i64 0, i64 %tmp17
  44 ;                  max(0, i - 3)
  45 ; CHECK:           select i1 %tmp14, i64 0, i64 %tmp17
  46 ; CHECK-NEXT: -->  (-3 + (3 smax {0,+,1}<nuw><nsw><%bb1>))
  47   %tmp21 = getelementptr inbounds i32, i32* %A, i64 %tmp19
  48   store i32 %tmp13, i32* %tmp21, align 4
  49   %tmp23 = add nuw nsw i32 %i.0, 1
  50   br label %bb1
  51
  52 bb24:                                             ; preds = %bb1
  53   ret void
  54 }