llvm/test/Analysis/ScalarEvolution/trip-count13.ll

   1 ; RUN: opt -S -analyze -enable-new-pm=0 -scalar-evolution < %s | FileCheck %s
   2 ; RUN: opt -S -disable-output "-passes=print<scalar-evolution>" < %s 2>&1 | FileCheck %s
   3
   4 define void @u_0(i8 %rhs) {
   5 ; E.g.: %rhs = 255, %start = 99, backedge taken 156 times
   6 entry:
   7   %start = add i8 %rhs, 100
   8   br label %loop
   9
  10 loop:
  11   %iv = phi i8 [ %start, %entry ], [ %iv.inc, %loop ]
  12   %iv.inc = add nuw i8 %iv, 1  ;; Note: this never unsigned-wraps
  13   %iv.cmp = icmp ult i8 %iv, %rhs
  14   br i1 %iv.cmp, label %loop, label %leave
  15
  16 ; CHECK-LABEL: Determining loop execution counts for: @u_0
  17 ; CHECK-NEXT: Loop %loop: backedge-taken count is (-100 + (-1 * %rhs) + ((100 + %rhs) umax %rhs))
  18 ; CHECK-NEXT: Loop %loop: max backedge-taken count is -100, actual taken count either this or zero.
  19
  20 leave:
  21   ret void
  22 }
  23
  24 define void @u_1(i8 %start) {
  25 entry:
  26 ; E.g.: %start = 99, %rhs = 255, backedge taken 156 times
  27   %rhs = add i8 %start, -100
  28   br label %loop
  29
  30 loop:
  31   %iv = phi i8 [ %start, %entry ], [ %iv.inc, %loop ]
  32   %iv.inc = add nuw i8 %iv, 1  ;; Note: this never unsigned-wraps
  33   %iv.cmp = icmp ult i8 %iv, %rhs
  34   br i1 %iv.cmp, label %loop, label %leave
  35
  36 ; CHECK-LABEL: Determining loop execution counts for: @u_1
  37 ; CHECK-NEXT: Loop %loop: backedge-taken count is ((-1 * %start) + ((-100 + %start) umax %start))
  38 ; CHECK-NEXT: Loop %loop: max backedge-taken count is -100, actual taken count either this or zero.
  39
  40 leave:
  41   ret void
  42 }
  43
  44 define void @s_0(i8 %rhs) {
  45 entry:
  46 ; E.g.: %rhs = 127, %start = -29, backedge taken 156 times
  47   %start = add i8 %rhs, 100
  48   br label %loop
  49
  50 loop:
  51   %iv = phi i8 [ %start, %entry ], [ %iv.inc, %loop ]
  52   %iv.inc = add nsw i8 %iv, 1  ;; Note: this never signed-wraps
  53   %iv.cmp = icmp slt i8 %iv, %rhs
  54   br i1 %iv.cmp, label %loop, label %leave
  55
  56 ; CHECK-LABEL: Determining loop execution counts for: @s_0
  57 ; CHECK-NEXT: Loop %loop: backedge-taken count is (-100 + (-1 * %rhs) + ((100 + %rhs) smax %rhs))
  58 ; CHECK-NEXT: Loop %loop: max backedge-taken count is -100, actual taken count either this or zero.
  59
  60 leave:
  61   ret void
  62 }
  63
  64 define void @s_1(i8 %start) {
  65 entry:
  66 ; E.g.: start = -29, %rhs = 127, %backedge taken 156 times
  67   %rhs = add i8 %start, -100
  68   br label %loop
  69
  70 loop:
  71   %iv = phi i8 [ %start, %entry ], [ %iv.inc, %loop ]
  72   %iv.inc = add nsw i8 %iv, 1
  73   %iv.cmp = icmp slt i8 %iv, %rhs
  74   br i1 %iv.cmp, label %loop, label %leave
  75
  76 ; CHECK-LABEL: Determining loop execution counts for: @s_1
  77 ; CHECK-NEXT: Loop %loop: backedge-taken count is ((-1 * %start) + ((-100 + %start) smax %start))
  78 ; CHECK-NEXT: Loop %loop: max backedge-taken count is -100, actual taken count either this or zero.
  79
  80 leave:
  81   ret void
  82 }
  83
  84 define void @s_2(i8 %start) {
  85 entry:
  86   %rhs = add i8 %start, -100
  87   br label %loop
  88
  89 loop:
  90   %iv = phi i8 [ %start, %entry ], [ %iv.inc, %loop ]
  91   %iv.inc = add nsw i8 %iv, -1
  92   %iv.cmp = icmp sgt i8 %iv, %rhs
  93   br i1 %iv.cmp, label %loop, label %leave
  94
  95 ; CHECK-LABEL: Determining loop execution counts for: @s_2
  96 ; CHECK-NEXT: Loop %loop: backedge-taken count is ((-1 * ((-100 + %start) smin %start)) + %start)
  97 ; CHECK-NEXT: Loop %loop: max backedge-taken count is -1
  98
  99 leave:
 100   ret void
 101 }