llvm/test/Transforms/FunctionAttrs/readattrs.ll

   1 ; RUN: opt < %s -function-attrs -S | FileCheck %s
   2 ; RUN: opt < %s -aa-pipeline=basic-aa -passes='cgscc(function-attrs)' -S | FileCheck %s
   3
   4 @x = global i32 0
   5
   6 declare void @test1_1(i8* %x1_1, i8* readonly %y1_1, ...)
   7
   8 ; NOTE: readonly for %y1_2 would be OK here but not for the similar situation in test13.
   9 ;
  10 ; CHECK: define void @test1_2(i8* %x1_2, i8* readonly %y1_2, i8* %z1_2)
  11 define void @test1_2(i8* %x1_2, i8* %y1_2, i8* %z1_2) {
  12   call void (i8*, i8*, ...) @test1_1(i8* %x1_2, i8* %y1_2, i8* %z1_2)
  13   store i32 0, i32* @x
  14   ret void
  15 }
  16
  17 ; CHECK: define i8* @test2(i8* readnone returned %p)
  18 define i8* @test2(i8* %p) {
  19   store i32 0, i32* @x
  20   ret i8* %p
  21 }
  22
  23 ; CHECK: define i1 @test3(i8* readnone %p, i8* readnone %q)
  24 define i1 @test3(i8* %p, i8* %q) {
  25   %A = icmp ult i8* %p, %q
  26   ret i1 %A
  27 }
  28
  29 declare void @test4_1(i8* nocapture) readonly
  30
  31 ; CHECK: define void @test4_2(i8* nocapture readonly %p)
  32 define void @test4_2(i8* %p) {
  33   call void @test4_1(i8* %p)
  34   ret void
  35 }
  36
  37 ; CHECK: define void @test5(i8** nocapture %p, i8* %q)
  38 ; Missed optz'n: we could make %q readnone, but don't break test6!
  39 define void @test5(i8** %p, i8* %q) {
  40   store i8* %q, i8** %p
  41   ret void
  42 }
  43
  44 declare void @test6_1()
  45 ; CHECK: define void @test6_2(i8** nocapture %p, i8* %q)
  46 ; This is not a missed optz'n.
  47 define void @test6_2(i8** %p, i8* %q) {
  48   store i8* %q, i8** %p
  49   call void @test6_1()
  50   ret void
  51 }
  52
  53 ; CHECK: define void @test7_1(i32* nocapture inalloca(i32) %a)
  54 ; inalloca parameters are always considered written
  55 define void @test7_1(i32* inalloca(i32) %a) {
  56   ret void
  57 }
  58
  59 ; CHECK: define void @test7_2(i32* nocapture preallocated(i32) %a)
  60 ; preallocated parameters are always considered written
  61 define void @test7_2(i32* preallocated(i32) %a) {
  62   ret void
  63 }
  64
  65 ; CHECK: define i32* @test8_1(i32* readnone returned %p)
  66 define i32* @test8_1(i32* %p) {
  67 entry:
  68   ret i32* %p
  69 }
  70
  71 ; CHECK: define void @test8_2(i32* %p)
  72 define void @test8_2(i32* %p) {
  73 entry:
  74   %call = call i32* @test8_1(i32* %p)
  75   store i32 10, i32* %call, align 4
  76   ret void
  77 }
  78
  79 ; CHECK: declare void @llvm.masked.scatter
  80 declare void @llvm.masked.scatter.v4i32.v4p0i32(<4 x i32>%val, <4 x i32*>, i32, <4 x i1>)
  81
  82 ; CHECK-NOT: readnone
  83 ; CHECK-NOT: readonly
  84 ; CHECK: define void @test9
  85 define void @test9(<4 x i32*> %ptrs, <4 x i32>%val) {
  86   call void @llvm.masked.scatter.v4i32.v4p0i32(<4 x i32>%val, <4 x i32*> %ptrs, i32 4, <4 x i1><i1 true, i1 false, i1 true, i1 false>)
  87   ret void
  88 }
  89
  90 ; CHECK: declare <4 x i32> @llvm.masked.gather
  91 declare <4 x i32> @llvm.masked.gather.v4i32.v4p0i32(<4 x i32*>, i32, <4 x i1>, <4 x i32>)
  92 ; CHECK: readonly
  93 ; CHECK: define <4 x i32> @test10
  94 define <4 x i32> @test10(<4 x i32*> %ptrs) {
  95   %res = call <4 x i32> @llvm.masked.gather.v4i32.v4p0i32(<4 x i32*> %ptrs, i32 4, <4 x i1><i1 true, i1 false, i1 true, i1 false>, <4 x i32>undef)
  96   ret <4 x i32> %res
  97 }
  98
  99 ; CHECK: declare <4 x i32> @test11_1
 100 declare <4 x i32> @test11_1(<4 x i32*>) argmemonly nounwind readonly
 101 ; CHECK: readonly
 102 ; CHECK-NOT: readnone
 103 ; CHECK: define <4 x i32> @test11_2
 104 define <4 x i32> @test11_2(<4 x i32*> %ptrs) {
 105   %res = call <4 x i32> @test11_1(<4 x i32*> %ptrs)
 106   ret <4 x i32> %res
 107 }
 108
 109 declare <4 x i32> @test12_1(<4 x i32*>) argmemonly nounwind
 110 ; CHECK-NOT: readnone
 111 ; CHECK: define <4 x i32> @test12_2
 112 define <4 x i32> @test12_2(<4 x i32*> %ptrs) {
 113   %res = call <4 x i32> @test12_1(<4 x i32*> %ptrs)
 114   ret <4 x i32> %res
 115 }
 116
 117 ; CHECK: define i32 @volatile_load(
 118 ; CHECK-NOT: readonly
 119 ; CHECK: ret
 120 define i32 @volatile_load(i32* %p) {
 121   %load = load volatile i32, i32* %p
 122   ret i32 %load
 123 }
 124
 125 declare void @escape_readnone_ptr(i8** %addr, i8* readnone %ptr)
 126 declare void @escape_readonly_ptr(i8** %addr, i8* readonly %ptr)
 127
 128 ; The argument pointer %escaped_then_written cannot be marked readnone/only even
 129 ; though the only direct use, in @escape_readnone_ptr/@escape_readonly_ptr,
 130 ; is marked as readnone/only. However, the functions can write the pointer into
 131 ; %addr, causing the store to write to %escaped_then_written.
 132 ;
 133 ; FIXME: This test currently exposes a bug in function-attrs!
 134 ;
 135 ; CHECK: define void @unsound_readnone(i8* nocapture readnone %ignored, i8* readnone %escaped_then_written)
 136 ; CHECK: define void @unsound_readonly(i8* nocapture readnone %ignored, i8* readonly %escaped_then_written)
 137 ;
 138 define void @unsound_readnone(i8* %ignored, i8* %escaped_then_written) {
 139   %addr = alloca i8*
 140   call void @escape_readnone_ptr(i8** %addr, i8* %escaped_then_written)
 141   %addr.ld = load i8*, i8** %addr
 142   store i8 0, i8* %addr.ld
 143   ret void
 144 }
 145
 146 define void @unsound_readonly(i8* %ignored, i8* %escaped_then_written) {
 147   %addr = alloca i8*
 148   call void @escape_readonly_ptr(i8** %addr, i8* %escaped_then_written)
 149   %addr.ld = load i8*, i8** %addr
 150   store i8 0, i8* %addr.ld
 151   ret void
 152 }