llvm/test/Transforms/GlobalDCE/virtual-functions-novfe.ll

   1 ; Tests that VFE is not performed when the Virtual Function Elim metadata set
   2 ; to 0. This is the same as virtual-functions.ll otherwise.
   3 ; RUN: opt < %s -globaldce -S | FileCheck %s
   4
   5 target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
   6
   7 declare dso_local noalias nonnull i8* @_Znwm(i64)
   8 declare { i8*, i1 } @llvm.type.checked.load(i8*, i32, metadata)
   9
  10 ; %struct.A is a C++ struct with two virtual functions, A::foo and A::bar. The
  11 ; !vcall_visibility metadata is set on the vtable, so we know that all virtual
  12 ; calls through this vtable are visible and use the @llvm.type.checked.load
  13 ; intrinsic. Function test_A makes a call to A::foo, but there is no call to
  14 ; A::bar anywhere, so A::bar can be deleted, and its vtable slot replaced with
  15 ; null.
  16 ; However, with the metadata set to 0 we should not perform this VFE.
  17
  18 %struct.A = type { i32 (...)** }
  19
  20 ; We should retain @_ZN1A3barEv in the vtable.
  21 ; CHECK: @_ZTV1A = internal unnamed_addr constant { [4 x i8*] } { [4 x i8*] [i8* null, i8* null, i8* bitcast (i32 (%struct.A*)* @_ZN1A3fooEv to i8*), i8* bitcast (i32 (%struct.A*)* @_ZN1A3barEv to i8*)] }
  22 @_ZTV1A = internal unnamed_addr constant { [4 x i8*] } { [4 x i8*] [i8* null, i8* null, i8* bitcast (i32 (%struct.A*)* @_ZN1A3fooEv to i8*), i8* bitcast (i32 (%struct.A*)* @_ZN1A3barEv to i8*)] }, align 8, !type !0, !type !1, !type !2, !vcall_visibility !3
  23
  24 ; A::foo is called, so must be retained.
  25 ; CHECK: define internal i32 @_ZN1A3fooEv(
  26 define internal i32 @_ZN1A3fooEv(%struct.A* nocapture readnone %this) {
  27 entry:
  28   ret i32 42
  29 }
  30
  31 ; A::bar is not used, so can be deleted with VFE, however, we should not be
  32 ; performing that elimination here.
  33 ; CHECK: define internal i32 @_ZN1A3barEv(
  34 define internal i32 @_ZN1A3barEv(%struct.A* nocapture readnone %this) {
  35 entry:
  36   ret i32 1337
  37 }
  38
  39 define dso_local i32 @test_A() {
  40 entry:
  41   %call = tail call i8* @_Znwm(i64 8)
  42   %0 = bitcast i8* %call to %struct.A*
  43   %1 = bitcast i8* %call to i32 (...)***
  44   store i32 (...)** bitcast (i8** getelementptr inbounds ({ [4 x i8*] }, { [4 x i8*] }* @_ZTV1A, i64 0, inrange i32 0, i64 2) to i32 (...)**), i32 (...)*** %1, align 8
  45   %2 = tail call { i8*, i1 } @llvm.type.checked.load(i8* bitcast (i8** getelementptr inbounds ({ [4 x i8*] }, { [4 x i8*] }* @_ZTV1A, i64 0, inrange i32 0, i64 2) to i8*), i32 0, metadata !"_ZTS1A"), !nosanitize !9
  46   %3 = extractvalue { i8*, i1 } %2, 0, !nosanitize !9
  47   %4 = bitcast i8* %3 to i32 (%struct.A*)*, !nosanitize !9
  48   %call1 = tail call i32 %4(%struct.A* nonnull %0)
  49   ret i32 %call1
  50 }
  51
  52 !llvm.module.flags = !{!4}
  53
  54 !0 = !{i64 16, !"_ZTS1A"}
  55 !1 = !{i64 16, !"_ZTSM1AFivE.virtual"}
  56 !2 = !{i64 24, !"_ZTSM1AFivE.virtual"}
  57 !3 = !{i64 2}
  58 !4 = !{i32 1, !"Virtual Function Elim", i32 0}
  59 !9 = !{}