llvm/test/Transforms/SCCP/ip-add-range-to-call.ll

   1 ; RUN: opt -ipsccp -S %s | FileCheck %s
   2
   3 ; Test 1.
   4 ; Both arguments and return value of @callee can be tracked. The inferred range
   5 ; can be added to call sites.
   6 define internal noundef i32 @callee(i32 %x) {
   7 ; CHECK-LABEL: @callee(
   8 ; CHECK-NEXT:    ret i32 [[X:%.*]]
   9 ;
  10   ret i32 %x
  11 }
  12
  13 define i32 @caller1() {
  14 ; CHECK-LABEL: @caller1(
  15 ; CHECK-NEXT:    [[C1:%.*]] = call i32 @callee(i32 10), !range [[RANGE_10_21:![0-9]+]]
  16 ; CHECK-NEXT:    [[C2:%.*]] = call i32 @callee(i32 20), !range [[RANGE_10_21]]
  17 ; CHECK-NEXT:    [[A:%.*]] = add i32 [[C1]], [[C2]]
  18 ; CHECK-NEXT:    ret i32 [[A]]
  19 ;
  20   %c1 = call i32 @callee(i32 10)
  21   %c2 = call i32 @callee(i32 20)
  22   %a = add i32 %c1, %c2
  23   ret i32 %a
  24 }
  25
  26 define i32 @caller2(i32 %x) {
  27 ; CHECK-LABEL: @caller2(
  28 ; CHECK-NEXT:    [[X_15:%.*]] = and i32 [[X:%.*]], 15
  29 ; CHECK-NEXT:    [[C:%.*]] = call i32 @callee(i32 [[X_15]]), !range [[RANGE_10_21]]
  30 ; CHECK-NEXT:    ret i32 [[C]]
  31 ;
  32   %x.15 = and i32 %x, 15
  33   %c = call i32 @callee(i32 %x.15)
  34   ret i32 %c
  35 }
  36
  37 ; Test 2.
  38 ; The return value of @callee2 can be tracked, but arguments cannot, because
  39 ; it is passed to @use_cb1. We cannot infer a range for the return value, no
  40 ; metadata should be added.
  41
  42 declare void @use_cb1(i32 (i32)*)
  43
  44 define internal noundef i32 @callee2(i32 %x) {
  45 ; CHECK-LABEL: @callee2(
  46 ; CHECK-NEXT:    ret i32 [[X:%.*]]
  47 ;
  48   ret i32 %x
  49 }
  50
  51 define void @caller_cb1() {
  52 ; CHECK-LABEL: @caller_cb1(
  53 ; CHECK-NEXT:    [[C1:%.*]] = call i32 @callee2(i32 9)
  54 ; CHECK-NOT:   !range
  55 ; CHECK-NEXT:    [[C2:%.*]] = call i32 @callee2(i32 10)
  56 ; CHECK-NOT:   !range
  57 ; CHECK-NEXT:    call void @use_cb1(i32 (i32)* @callee2)
  58 ; CHECK-NEXT:    ret void
  59 ;
  60   %c1 = call i32 @callee2(i32 9)
  61   %c2 = call i32 @callee2(i32 10)
  62   call void @use_cb1(i32 (i32)* @callee2)
  63   ret void
  64 }
  65
  66 ; Test 3.
  67 ; The return value can be tracked and it the result range ([500, 601) does not
  68 ; depend on the arguments, which cannot be tracked because @callee3 is passed
  69 ; to @use_cb2. The result range can be added to the call sites of @callee.
  70
  71 declare void @use_cb2(i32 (i32)*)
  72
  73 define internal noundef i32 @callee3(i32 %x) {
  74 ; CHECK-LABEL: @callee3(
  75 ; CHECK-NEXT:    [[C:%.*]] = icmp eq i32 [[X:%.*]], 10
  76 ; CHECK-NEXT:    [[S:%.*]] = select i1 [[C]], i32 500, i32 600
  77 ; CHECK-NEXT:    ret i32 [[S]]
  78 ;
  79   %c = icmp eq i32 %x, 10
  80   %s = select i1 %c, i32 500, i32 600
  81   ret i32 %s
  82 }
  83
  84 define void @caller_cb2() {
  85 ; CHECK-LABEL: @caller_cb2(
  86 ; CHECK-NEXT:    [[C1:%.*]] = call i32 @callee3(i32 9), !range [[RANGE_500_601:![0-9]+]]
  87 ; CHECK-NEXT:    [[C2:%.*]] = call i32 @callee3(i32 10), !range [[RANGE_500_601]]
  88 ; CHECK-NEXT:    call void @use_cb2(i32 (i32)* @callee3)
  89 ; CHECK-NEXT:    ret void
  90 ;
  91   %c1 = call i32 @callee3(i32 9)
  92   %c2 = call i32 @callee3(i32 10)
  93   call void @use_cb2(i32 (i32)* @callee3)
  94   ret void
  95 }
  96
  97 ; Test 4.
  98 ; The return value of @callee4 can be tracked, but depends on an argument which
  99 ; cannot be tracked. No result range can be inferred.
 100
 101 declare void @use_cb3(i32 (i32, i32)*)
 102
 103 define internal noundef i32 @callee4(i32 %x, i32 %y) {
 104 ; CHECK-LABEL: @callee4(
 105 ; CHECK-NEXT:    [[C:%.*]] = icmp eq i32 [[X:%.*]], 10
 106 ; CHECK-NEXT:    [[S:%.*]] = select i1 [[C]], i32 500, i32 [[Y:%.*]]
 107 ; CHECK-NEXT:    ret i32 [[S]]
 108 ;
 109   %c = icmp eq i32 %x, 10
 110   %s = select i1 %c, i32 500, i32 %y
 111   ret i32 %s
 112 }
 113
 114 define void @caller_cb3() {
 115 ; CHECK-LABEL: @caller_cb3(
 116 ; CHECK-NEXT:    [[C1:%.*]] = call i32 @callee4(i32 11, i32 30)
 117 ; CHECK-NOT:   !range
 118 ; CHECK-NEXT:    [[C2:%.*]] = call i32 @callee4(i32 12, i32 40)
 119 ; CHECK-NOT:   !range
 120 ; CHECK-NEXT:    call void @use_cb3(i32 (i32, i32)* @callee4)
 121 ; CHECK-NEXT:    ret void
 122 ;
 123   %c1 = call i32 @callee4(i32 11, i32 30)
 124   %c2 = call i32 @callee4(i32 12, i32 40)
 125   call void @use_cb3(i32 (i32, i32)* @callee4)
 126   ret void
 127 }
 128
 129 ; Test 5.
 130 ; Range for the return value of callee5 includes undef. No range metadata
 131 ; should be added at call sites.
 132 define internal noundef i32 @callee5(i32 %x, i32 %y) {
 133 ; CHECK-LABEL: @callee5(
 134 ; CHECK-NEXT:    [[C:%.*]] = icmp slt i32 [[X:%.*]], 15
 135 ; CHECK-NEXT:    br i1 [[C]], label [[BB1:%.*]], label [[BB2:%.*]]
 136 ; CHECK:       bb1:
 137 ; CHECK-NEXT:    br label [[EXIT:%.*]]
 138 ; CHECK:       bb2:
 139 ; CHECK-NEXT:    br label [[EXIT]]
 140 ; CHECK:       exit:
 141 ; CHECK-NEXT:    [[RES:%.*]] = phi i32 [ [[Y:%.*]], [[BB1]] ], [ undef, [[BB2]] ]
 142 ; CHECK-NEXT:    ret i32 [[RES]]
 143 ;
 144   %c = icmp slt i32 %x, 15
 145   br i1 %c, label %bb1, label %bb2
 146
 147 bb1:
 148   br label %exit
 149
 150 bb2:
 151   br label %exit
 152
 153 exit:
 154   %res = phi i32 [ %y, %bb1 ], [ undef, %bb2]
 155   ret i32 %res
 156 }
 157
 158 define i32 @caller5() {
 159 ; CHECK-LABEL: @caller5(
 160 ; CHECK-NEXT:    [[C1:%.*]] = call i32 @callee5(i32 10, i32 100)
 161 ; CHECK-NOT:   !range
 162 ; CHECK-NEXT:    [[C2:%.*]] = call i32 @callee5(i32 20, i32 200)
 163 ; CHECK-NOT:   !range
 164 ; CHECK-NEXT:    [[A:%.*]] = add i32 [[C1]], [[C2]]
 165 ; CHECK-NEXT:    ret i32 [[A]]
 166 ;
 167   %c1 = call i32 @callee5(i32 10, i32 100)
 168   %c2 = call i32 @callee5(i32 20, i32 200)
 169   %a = add i32 %c1, %c2
 170   ret i32 %a
 171 }
 172
 173 ; CHECK: [[RANGE_10_21]] = !{i32 0, i32 21}
 174 ; CHECK: [[RANGE_500_601]] = !{i32 500, i32 601}