llvm/utils/gn/secondary/lld/Common/BUILD.gn

   1 import("//llvm/utils/gn/build/write_vcsrevision.gni")
   2
   3 config("write_vcsrevision_config") {
   4   # To pick up the generated inc file.
   5   include_dirs = [ target_gen_dir ]
   6   visibility = [ ":write_vcsrevision" ]
   7 }
   8
   9 write_vcsrevision("write_vcsversion") {
  10   visibility = [ ":Common" ]
  11   header = "$target_gen_dir/VCSVersion.inc"
  12   names = [ "LLD" ]
  13   public_configs = [ ":write_vcsrevision_config" ]
  14 }
  15
  16 static_library("Common") {
  17   output_name = "lldCommon"
  18   configs += [ "//llvm/utils/gn/build:lld_code" ]
  19   public_deps = [
  20     # public_dep because public header Version.h includes generated Version.inc.
  21     "//lld/include/lld/Common:version",
  22   ]
  23   deps = [
  24     ":write_vcsversion",
  25     "//llvm/lib/CodeGen",
  26     "//llvm/lib/Demangle",
  27     "//llvm/lib/IR",
  28     "//llvm/lib/MC",
  29     "//llvm/lib/Option",
  30     "//llvm/lib/Support",
  31     "//llvm/lib/Target",
  32   ]
  33   sources = [
  34     "Args.cpp",
  35     "DWARF.cpp",
  36     "ErrorHandler.cpp",
  37     "Filesystem.cpp",
  38     "Memory.cpp",
  39     "Reproduce.cpp",
  40     "Strings.cpp",
  41     "TargetOptionsCommandFlags.cpp",
  42     "Timer.cpp",
  43     "Version.cpp",
  44   ]
  45 }