flang/test/Transforms/omp-map-info-finalization-implicit-field.fir

   1 // Tests that we implicitly map alloctable fields of a record when referenced in
   2 // a target region.
   3
   4 // RUN: fir-opt --split-input-file --omp-map-info-finalization %s | FileCheck %s
   5
   6 !record_t = !fir.type<_QFTrecord_t{
   7   not_to_implicitly_map:
   8     !fir.box<!fir.heap<!fir.array<?xf32>>>,
   9   to_implicitly_map:
  10     !fir.box<!fir.heap<!fir.array<?xf32>>>
  11 }>
  12
  13 fir.global internal @_QFEdst_record : !record_t {
  14   %0 = fir.undefined !record_t
  15   fir.has_value %0 : !record_t
  16 }
  17
  18 func.func @_QQmain() {
  19   %6 = fir.address_of(@_QFEdst_record) : !fir.ref<!record_t>
  20   %7:2 = hlfir.declare %6 {uniq_name = "_QFEdst_record"} : (!fir.ref<!record_t>) -> (!fir.ref<!record_t>, !fir.ref<!record_t>)
  21   %16 = omp.map.info var_ptr(%7#1 : !fir.ref<!record_t>, !record_t) map_clauses(implicit, tofrom) capture(ByRef) -> !fir.ref<!record_t> {name = "dst_record"}
  22   omp.target map_entries(%16 -> %arg0 : !fir.ref<!record_t>) {
  23     %20:2 = hlfir.declare %arg0 {uniq_name = "_QFEdst_record"} : (!fir.ref<!record_t>) -> (!fir.ref<!record_t>, !fir.ref<!record_t>)
  24     %23 = hlfir.designate %20#0{"to_implicitly_map"}   {fortran_attrs = #fir.var_attrs<allocatable>} : (!fir.ref<!record_t>) -> !fir.ref<!fir.box<!fir.heap<!fir.array<?xf32>>>>
  25     omp.terminator
  26   }
  27   return
  28 }
  29
  30 // CHECK: %[[RECORD_DECL:.*]]:2 = hlfir.declare %0 {uniq_name = "_QFEdst_record"}
  31 // CHECK: %[[FIELD_COORD:.*]] = fir.coordinate_of %[[RECORD_DECL]]#1, %{{c1.*}}
  32
  33 // CHECK: %[[UPPER_BOUND:.*]] = arith.subi %{{.*}}#1, %{{c1.*}} : index
  34
  35 // CHECK: %[[BOUNDS:.*]] = omp.map.bounds
  36 // CHECK-SAME: lower_bound(%{{c0.*}} : index) upper_bound(%[[UPPER_BOUND]] : index)
  37 // CHECK-SAME: extent(%{{.*}}#1 : index) stride(%{{.*}}#2 : index)
  38 // CHECK-SAME: start_idx(%{{.*}}#0 : index) {stride_in_bytes = true}
  39
  40 // CHECK: %[[BASE_ADDR:.*]] = fir.box_offset %[[FIELD_COORD]] base_addr
  41 // CHECK: %[[FIELD_BASE_ADDR_MAP:.*]] = omp.map.info var_ptr(
  42 // CHECK-SAME: %[[FIELD_COORD]] : {{.*}}) var_ptr_ptr(
  43 // CHECK-SAME: %[[BASE_ADDR]] : {{.*}}) map_clauses(
  44 // CHECK-SAME: implicit, tofrom) capture(ByRef) bounds(
  45 // CHECK-SAME: %[[BOUNDS]])
  46
  47 // CHECK: %[[FIELD_MAP:.*]] = omp.map.info var_ptr(
  48 // CHECK-SAME: %[[FIELD_COORD]] : {{.*}}) map_clauses(
  49 // CHECK-SAME: implicit, to) capture(ByRef) ->
  50 // CHECK-SAME: {{.*}} {name = "dst_record.to_implicitly_map.implicit_map"}
  51
  52 // CHECK: %[[RECORD_MAP:.*]] = omp.map.info var_ptr(
  53 // CHECK-SAME: %[[RECORD_DECL]]#1 : {{.*}}) map_clauses(
  54 // CHECK-SAME: implicit, tofrom) capture(ByRef) members(
  55 // CHECK-SAME: %[[FIELD_MAP]], %[[FIELD_BASE_ADDR_MAP]] :
  56 // CHECK-SAME: [1], [1, 0] : {{.*}}) -> {{.*}}> {name =
  57 // CHECK-SAME: "dst_record", partial_map = true}
  58
  59 // CHECK: omp.target map_entries(
  60 // CHECK-SAME: %[[RECORD_MAP]] -> %{{[^[:space:]]+}},
  61 // CHECK-SAME: %[[FIELD_MAP]] -> %{{[^[:space:]]+}},
  62 // CHECK-SAME: %[[FIELD_BASE_ADDR_MAP]] -> %{{[^[:space:]]+}}
  63 // CHECK-SAME: : {{.*}})