clang/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.13.4)
   2
   3 if(NOT DEFINED LLVM_COMMON_CMAKE_UTILS)
   4   set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
   5 endif()
   6 include(${LLVM_COMMON_CMAKE_UTILS}/Modules/CMakePolicy.cmake
   7   NO_POLICY_SCOPE)
   8
   9 # If we are not building as a part of LLVM, build Clang as an
  10 # standalone project, using LLVM as an external library:
  11 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  12   project(Clang)
  13   set(CLANG_BUILT_STANDALONE TRUE)
  14   if ("${CMAKE_VERSION}" VERSION_LESS "3.20.0")
  15     message(WARNING
  16       "Your CMake version is ${CMAKE_VERSION}. Starting with LLVM 17.0.0, the "
  17       "minimum version of CMake required to build LLVM will become 3.20.0, and "
  18       "using an older CMake will become an error. Please upgrade your CMake to "
  19       "at least 3.20.0 now to avoid issues in the future!")
  20   endif()
  21 endif()
  22
  23 # Must go below project(..)
  24 include(GNUInstallDirs)
  25
  26 if(CLANG_BUILT_STANDALONE)
  27   set(CMAKE_CXX_STANDARD 17 CACHE STRING "C++ standard to conform to")
  28   set(CMAKE_CXX_STANDARD_REQUIRED YES)
  29   set(CMAKE_CXX_EXTENSIONS NO)
  30
  31   if(NOT MSVC_IDE)
  32     set(LLVM_ENABLE_ASSERTIONS ${ENABLE_ASSERTIONS}
  33       CACHE BOOL "Enable assertions")
  34     # Assertions should follow llvm-config's.
  35     mark_as_advanced(LLVM_ENABLE_ASSERTIONS)
  36   endif()
  37
  38   find_package(LLVM REQUIRED HINTS "${LLVM_CMAKE_DIR}")
  39   list(APPEND CMAKE_MODULE_PATH "${LLVM_DIR}")
  40
  41   # Turn into CACHE PATHs for overwritting
  42   set(LLVM_INCLUDE_DIRS ${LLVM_INCLUDE_DIRS} CACHE PATH "Path to llvm/include and any other header dirs needed")
  43   set(LLVM_BINARY_DIR "${LLVM_BINARY_DIR}" CACHE PATH "Path to LLVM build tree")
  44   set(LLVM_MAIN_SRC_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../llvm" CACHE PATH "Path to LLVM source tree")
  45   set(LLVM_TOOLS_BINARY_DIR "${LLVM_TOOLS_BINARY_DIR}" CACHE PATH "Path to llvm/bin")
  46   set(LLVM_LIBRARY_DIR "${LLVM_LIBRARY_DIR}" CACHE PATH "Path to llvm/lib")
  47
  48   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR}
  49     NO_DEFAULT_PATH)
  50
  51   # They are used as destination of target generators.
  52   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  53   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  54   if(WIN32 OR CYGWIN)
  55     # DLL platform -- put DLLs into bin.
  56     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  57   else()
  58     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
  59   endif()
  60
  61   option(LLVM_INSTALL_TOOLCHAIN_ONLY
  62     "Only include toolchain files in the 'install' target." OFF)
  63
  64   option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
  65     "Set to ON to force using an old, unsupported host toolchain." OFF)
  66   option(CLANG_ENABLE_BOOTSTRAP "Generate the clang bootstrap target" OFF)
  67   option(LLVM_ENABLE_LIBXML2 "Use libxml2 if available." ON)
  68
  69   include(AddLLVM)
  70   include(TableGen)
  71   include(HandleLLVMOptions)
  72   include(VersionFromVCS)
  73   include(CheckAtomic)
  74   include(GetErrcMessages)
  75   include(LLVMDistributionSupport)
  76
  77   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
  78   set(BUG_REPORT_URL "${LLVM_PACKAGE_BUGREPORT}" CACHE STRING
  79     "Default URL where bug reports are to be submitted.")
  80
  81   if (NOT DEFINED LLVM_INCLUDE_TESTS)
  82     set(LLVM_INCLUDE_TESTS ON)
  83   endif()
  84
  85   include_directories(${LLVM_INCLUDE_DIRS})
  86   link_directories("${LLVM_LIBRARY_DIR}")
  87
  88   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
  89   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
  90   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
  91
  92   if(LLVM_INCLUDE_TESTS)
  93     find_package(Python3 ${LLVM_MINIMUM_PYTHON_VERSION} REQUIRED
  94       COMPONENTS Interpreter)
  95
  96     # Check prebuilt llvm/utils.
  97     if(EXISTS ${LLVM_TOOLS_BINARY_DIR}/FileCheck${CMAKE_EXECUTABLE_SUFFIX}
  98         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/count${CMAKE_EXECUTABLE_SUFFIX}
  99         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/not${CMAKE_EXECUTABLE_SUFFIX})
 100       set(LLVM_UTILS_PROVIDED ON)
 101     endif()
 102
 103     # Seek installed Lit.
 104     find_program(LLVM_LIT
 105                  NAMES llvm-lit lit.py lit
 106                  PATHS "${LLVM_MAIN_SRC_DIR}/utils/lit"
 107                  DOC "Path to lit.py")
 108
 109     if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 110       # Note: path not really used, except for checking if lit was found
 111       if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 112         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit utils/llvm-lit)
 113       endif()
 114       if(NOT LLVM_UTILS_PROVIDED)
 115         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/FileCheck utils/FileCheck)
 116         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/count utils/count)
 117         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/not utils/not)
 118         set(LLVM_UTILS_PROVIDED ON)
 119         set(CLANG_TEST_DEPS FileCheck count not)
 120       endif()
 121     endif()
 122
 123     if (NOT TARGET llvm_gtest)
 124         message(FATAL_ERROR "llvm-gtest not found. Please install llvm-gtest or disable tests with -DLLVM_INCLUDE_TESTS=OFF")
 125     endif()
 126
 127     if(LLVM_LIT)
 128       # Define the default arguments to use with 'lit', and an option for the user
 129       # to override.
 130       set(LIT_ARGS_DEFAULT "-sv")
 131       if (MSVC OR XCODE)
 132         set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 133       endif()
 134       set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 135
 136       get_errc_messages(LLVM_LIT_ERRC_MESSAGES)
 137
 138       # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 139       if( WIN32 AND NOT CYGWIN )
 140         set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 141       endif()
 142     else()
 143       set(LLVM_INCLUDE_TESTS OFF)
 144     endif()
 145
 146     umbrella_lit_testsuite_begin(check-all)
 147   endif() # LLVM_INCLUDE_TESTS
 148 endif() # standalone
 149
 150 # Make sure that our source directory is on the current cmake module path so that
 151 # we can include cmake files from this directory.
 152 list(INSERT CMAKE_MODULE_PATH 0
 153   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 154   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
 155   )
 156
 157 # This allows disabling clang's XML dependency even if LLVM finds libxml2.
 158 # By default, clang depends on libxml2 if LLVM does.
 159 option(CLANG_ENABLE_LIBXML2 "Whether libclang may depend on libxml2"
 160        ${LLVM_ENABLE_LIBXML2})
 161
 162 if(CLANG_ENABLE_LIBXML2)
 163   # Don't look for libxml if we're using MSan, since uninstrumented third party
 164   # code may call MSan interceptors like strlen, leading to false positives.
 165   if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 166     set (LIBXML2_FOUND 0)
 167     find_package(LibXml2 2.5.3 QUIET)
 168     if (LIBXML2_FOUND)
 169       set(CLANG_HAVE_LIBXML 1)
 170     endif()
 171   endif()
 172 endif()
 173
 174 include(CheckIncludeFile)
 175 check_include_file(sys/resource.h CLANG_HAVE_RLIMITS)
 176
 177 set(CLANG_RESOURCE_DIR "" CACHE STRING
 178   "Relative directory from the Clang binary to its resource files.")
 179
 180 set(C_INCLUDE_DIRS "" CACHE STRING
 181   "Colon separated list of directories clang will search for headers.")
 182
 183 set(GCC_INSTALL_PREFIX "" CACHE PATH "Directory where gcc is installed." )
 184 set(DEFAULT_SYSROOT "" CACHE STRING
 185   "Default <path> to all compiler invocations for --sysroot=<path>." )
 186
 187 set(ENABLE_LINKER_BUILD_ID OFF CACHE BOOL "pass --build-id to ld")
 188
 189 set(ENABLE_X86_RELAX_RELOCATIONS ON CACHE BOOL
 190     "enable x86 relax relocations by default")
 191
 192 set(PPC_LINUX_DEFAULT_IEEELONGDOUBLE OFF CACHE BOOL
 193     "Enable IEEE binary128 as default long double format on PowerPC Linux.")
 194
 195 set(CLANG_SPAWN_CC1 OFF CACHE BOOL
 196     "Whether clang should use a new process for the CC1 invocation")
 197
 198 option(CLANG_DEFAULT_PIE_ON_LINUX "Default to -fPIE and -pie on linux-gnu" ON)
 199
 200 set(CLANG_DEFAULT_LINKER "" CACHE STRING
 201   "Default linker to use (linker name or absolute path, empty for platform default)")
 202
 203 set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 204   "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default")
 205 if (NOT(CLANG_DEFAULT_CXX_STDLIB STREQUAL "" OR
 206         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libstdc++" OR
 207         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libc++"))
 208   message(WARNING "Resetting default C++ stdlib to use platform default")
 209   set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 210     "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default" FORCE)
 211 endif()
 212
 213 set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 214   "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)")
 215 if (NOT(CLANG_DEFAULT_RTLIB STREQUAL "" OR
 216         CLANG_DEFAULT_RTLIB STREQUAL "libgcc" OR
 217         CLANG_DEFAULT_RTLIB STREQUAL "compiler-rt"))
 218   message(WARNING "Resetting default rtlib to use platform default")
 219   set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 220     "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)" FORCE)
 221 endif()
 222
 223 set(CLANG_DEFAULT_UNWINDLIB "" CACHE STRING
 224   "Default unwind library to use (\"none\" \"libgcc\" or \"libunwind\", empty to match runtime library.)")
 225 if (CLANG_DEFAULT_UNWINDLIB STREQUAL "")
 226   if (CLANG_DEFAULT_RTLIB STREQUAL "libgcc")
 227     set (CLANG_DEFAULT_UNWINDLIB "libgcc" CACHE STRING "" FORCE)
 228   endif()
 229 endif()
 230
 231 if (NOT(CLANG_DEFAULT_UNWINDLIB STREQUAL "" OR
 232         CLANG_DEFAULT_UNWINDLIB STREQUAL "none" OR
 233         CLANG_DEFAULT_UNWINDLIB STREQUAL "libgcc" OR
 234         CLANG_DEFAULT_UNWINDLIB STREQUAL "libunwind"))
 235   message(WARNING "Resetting default unwindlib to use platform default")
 236   set(CLANG_DEFAULT_UNWINDLIB "" CACHE STRING
 237     "Default unwind library to use (\"none\" \"libgcc\" or \"libunwind\", empty to match runtime library.)" FORCE)
 238 endif()
 239
 240 set(CLANG_DEFAULT_OBJCOPY "objcopy" CACHE STRING
 241   "Default objcopy executable to use.")
 242
 243 set(CLANG_DEFAULT_OPENMP_RUNTIME "libomp" CACHE STRING
 244   "Default OpenMP runtime used by -fopenmp.")
 245
 246 set(CLANG_SYSTEMZ_DEFAULT_ARCH "z10" CACHE STRING "SystemZ Default Arch")
 247
 248 set(CLANG_VENDOR ${PACKAGE_VENDOR} CACHE STRING
 249   "Vendor-specific text for showing with version information.")
 250
 251 set(CLANG_REPOSITORY_STRING "" CACHE STRING
 252   "Vendor-specific text for showing the repository the source is taken from.")
 253
 254 if(CLANG_REPOSITORY_STRING)
 255   add_definitions(-DCLANG_REPOSITORY_STRING="${CLANG_REPOSITORY_STRING}")
 256 endif()
 257
 258 set(CLANG_VENDOR_UTI "org.llvm.clang" CACHE STRING
 259   "Vendor-specific uti.")
 260
 261 set(CLANG_PYTHON_BINDINGS_VERSIONS "" CACHE STRING
 262     "Python versions to install libclang python bindings for")
 263
 264 set(CLANG_LINK_CLANG_DYLIB ${LLVM_LINK_LLVM_DYLIB} CACHE BOOL
 265     "Link tools against libclang-cpp.so")
 266
 267 if (NOT LLVM_LINK_LLVM_DYLIB AND CLANG_LINK_CLANG_DYLIB)
 268   message(FATAL_ERROR "Cannot set CLANG_LINK_CLANG_DYLIB=ON when "
 269                       "LLVM_LINK_LLVM_DYLIB=OFF")
 270 endif()
 271
 272 # The libdir suffix must exactly match whatever LLVM's configuration used.
 273 set(CLANG_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}")
 274
 275 set(CLANG_TOOLS_INSTALL_DIR "${CMAKE_INSTALL_BINDIR}" CACHE PATH
 276     "Path for binary subdirectory (defaults to '${CMAKE_INSTALL_BINDIR}')")
 277 mark_as_advanced(CLANG_TOOLS_INSTALL_DIR)
 278
 279 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 280 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 281
 282 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 283   message(FATAL_ERROR "In-source builds are not allowed. "
 284 "Please create a directory and run cmake "
 285 "from there, passing the path to this source directory as the last argument. "
 286 "This process created the file `CMakeCache.txt' and the directory "
 287 "`CMakeFiles'. Please delete them.")
 288 endif()
 289
 290 # If CLANG_VERSION_* is specified, use it, if not use LLVM_VERSION_*.
 291 if(NOT DEFINED CLANG_VERSION_MAJOR)
 292   set(CLANG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 293 endif()
 294 if(NOT DEFINED CLANG_VERSION_MINOR)
 295   set(CLANG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 296 endif()
 297 if(NOT DEFINED CLANG_VERSION_PATCHLEVEL)
 298   set(CLANG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 299 endif()
 300 # Unlike PACKAGE_VERSION, CLANG_VERSION does not include LLVM_VERSION_SUFFIX.
 301 set(CLANG_VERSION "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}.${CLANG_VERSION_PATCHLEVEL}")
 302 message(STATUS "Clang version: ${CLANG_VERSION}")
 303
 304 # Configure the Version.inc file.
 305 configure_file(
 306   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 307   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 308
 309 # Add appropriate flags for GCC
 310 if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 311   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual")
 312   if (NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 313     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
 314   endif ()
 315
 316   # Enable -pedantic for Clang even if it's not enabled for LLVM.
 317   if (NOT LLVM_ENABLE_PEDANTIC)
 318     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-long-long")
 319   endif ()
 320
 321   check_cxx_compiler_flag("-Werror -Wnested-anon-types" CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG)
 322   if( CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG )
 323     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 324   endif()
 325 endif ()
 326
 327 # Determine HOST_LINK_VERSION on Darwin.
 328 set(HOST_LINK_VERSION)
 329 if (APPLE AND NOT CMAKE_LINKER MATCHES ".*lld.*")
 330   set(LD_V_OUTPUT)
 331   execute_process(
 332     COMMAND sh -c "${CMAKE_LINKER} -v 2>&1 | head -1"
 333     RESULT_VARIABLE HAD_ERROR
 334     OUTPUT_VARIABLE LD_V_OUTPUT
 335   )
 336   if (HAD_ERROR)
 337     message(FATAL_ERROR "${CMAKE_LINKER} failed with status ${HAD_ERROR}")
 338   endif()
 339   if ("${LD_V_OUTPUT}" MATCHES ".*ld64-([0-9.]+).*")
 340     string(REGEX REPLACE ".*ld64-([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 341   elseif ("${LD_V_OUTPUT}" MATCHES "[^0-9]*([0-9.]+).*")
 342     string(REGEX REPLACE "[^0-9]*([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 343   endif()
 344   message(STATUS "Host linker version: ${HOST_LINK_VERSION}")
 345 endif()
 346
 347 include(CMakeParseArguments)
 348 include(AddClang)
 349
 350 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 351
 352 include_directories(BEFORE
 353   ${CMAKE_CURRENT_BINARY_DIR}/include
 354   ${CMAKE_CURRENT_SOURCE_DIR}/include
 355   )
 356
 357 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 358   install(DIRECTORY include/clang include/clang-c
 359     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 360     COMPONENT clang-headers
 361     FILES_MATCHING
 362     PATTERN "*.def"
 363     PATTERN "*.h"
 364     PATTERN "config.h" EXCLUDE
 365     )
 366
 367   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/clang
 368     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 369     COMPONENT clang-headers
 370     FILES_MATCHING
 371     PATTERN "CMakeFiles" EXCLUDE
 372     PATTERN "*.inc"
 373     PATTERN "*.h"
 374     )
 375
 376   # Installing the headers needs to depend on generating any public
 377   # tablegen'd headers.
 378   add_custom_target(clang-headers DEPENDS clang-tablegen-targets)
 379   set_target_properties(clang-headers PROPERTIES FOLDER "Misc")
 380   if(NOT LLVM_ENABLE_IDE)
 381     add_llvm_install_targets(install-clang-headers
 382                              DEPENDS clang-headers
 383                              COMPONENT clang-headers)
 384   endif()
 385
 386   add_custom_target(bash-autocomplete DEPENDS utils/bash-autocomplete.sh)
 387   install(FILES utils/bash-autocomplete.sh
 388           DESTINATION "${CMAKE_INSTALL_DATADIR}/clang"
 389           COMPONENT bash-autocomplete)
 390   if(NOT LLVM_ENABLE_IDE)
 391     add_llvm_install_targets(install-bash-autocomplete
 392                              DEPENDS bash-autocomplete
 393                              COMPONENT bash-autocomplete)
 394   endif()
 395 endif()
 396
 397 option(CLANG_BUILD_TOOLS
 398   "Build the Clang tools. If OFF, just generate build targets." ON)
 399
 400 if(LLVM_ENABLE_PLUGINS OR LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 401   set(HAVE_CLANG_PLUGIN_SUPPORT ON)
 402 else()
 403   set(HAVE_CLANG_PLUGIN_SUPPORT OFF)
 404 endif()
 405 CMAKE_DEPENDENT_OPTION(CLANG_PLUGIN_SUPPORT
 406   "Build clang with plugin support" ON
 407   "HAVE_CLANG_PLUGIN_SUPPORT" OFF)
 408
 409 # If libstdc++ is statically linked, clang-repl needs to statically link libstdc++
 410 # itself, which is not possible in many platforms because of current limitations in
 411 # JIT stack. (more platforms need to be supported by JITLink)
 412 if(NOT LLVM_STATIC_LINK_CXX_STDLIB)
 413   set(HAVE_CLANG_REPL_SUPPORT ON)
 414 endif()
 415
 416 option(CLANG_ENABLE_ARCMT "Build ARCMT." ON)
 417 option(CLANG_ENABLE_STATIC_ANALYZER
 418   "Include static analyzer in clang binary." ON)
 419
 420 option(CLANG_ENABLE_PROTO_FUZZER "Build Clang protobuf fuzzer." OFF)
 421
 422 if(NOT CLANG_ENABLE_STATIC_ANALYZER AND CLANG_ENABLE_ARCMT)
 423   message(FATAL_ERROR "Cannot disable static analyzer while enabling ARCMT or Z3")
 424 endif()
 425
 426 if(CLANG_ENABLE_ARCMT)
 427   set(CLANG_ENABLE_OBJC_REWRITER ON)
 428 endif()
 429
 430 # This option is a stop-gap, we should commit to removing this as
 431 # soon as possible. See discussion:
 432 # https://discourse.llvm.org/t/rationale-for-removing-versioned-libclang-middle-ground-to-keep-it-behind-option/
 433 option(CLANG_FORCE_MATCHING_LIBCLANG_SOVERSION
 434   "Force the SOVERSION of libclang to be equal to CLANG_MAJOR" ON)
 435
 436 # Clang version information
 437 set(CLANG_EXECUTABLE_VERSION
 438     "${CLANG_VERSION_MAJOR}" CACHE STRING
 439     "Major version number that will be appended to the clang executable name")
 440 set(LIBCLANG_LIBRARY_VERSION
 441     "${CLANG_VERSION_MAJOR}" CACHE STRING
 442     "Major version number that will be appended to the libclang library")
 443 mark_as_advanced(CLANG_EXECUTABLE_VERSION LIBCLANG_LIBRARY_VERSION)
 444
 445 option(CLANG_INCLUDE_TESTS
 446        "Generate build targets for the Clang unit tests."
 447        ${LLVM_INCLUDE_TESTS})
 448
 449 option(CLANG_ENABLE_HLSL "Include HLSL build products" Off)
 450 # While HLSL support is experimental this should stay hidden.
 451 mark_as_advanced(CLANG_ENABLE_HLSL)
 452
 453 add_subdirectory(utils/TableGen)
 454
 455 # Export CLANG_TABLEGEN_EXE for use by flang docs.
 456 set(CLANG_TABLEGEN_EXE "${CLANG_TABLEGEN_EXE}" CACHE INTERNAL "")
 457
 458 add_subdirectory(include)
 459
 460 # All targets below may depend on all tablegen'd files.
 461 get_property(CLANG_TABLEGEN_TARGETS GLOBAL PROPERTY CLANG_TABLEGEN_TARGETS)
 462 add_custom_target(clang-tablegen-targets
 463   DEPENDS
 464   omp_gen
 465   ${CLANG_TABLEGEN_TARGETS})
 466 set_target_properties(clang-tablegen-targets PROPERTIES FOLDER "Misc")
 467 list(APPEND LLVM_COMMON_DEPENDS clang-tablegen-targets)
 468
 469 # Force target to be built as soon as possible. Clang modules builds depend
 470 # header-wise on it as they ship all headers from the umbrella folders. Building
 471 # an entire module might include header, which depends on intrinsics_gen.
 472 if(LLVM_ENABLE_MODULES)
 473   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 474 endif()
 475
 476 add_subdirectory(lib)
 477 add_subdirectory(tools)
 478 add_subdirectory(runtime)
 479
 480 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs by default." OFF)
 481 add_subdirectory(examples)
 482
 483 if(APPLE)
 484   # this line is needed as a cleanup to ensure that any CMakeCaches with the old
 485   # default value get updated to the new default.
 486   if(CLANG_ORDER_FILE STREQUAL "")
 487     unset(CLANG_ORDER_FILE CACHE)
 488     unset(CLANG_ORDER_FILE)
 489   endif()
 490
 491
 492   set(CLANG_ORDER_FILE ${CMAKE_CURRENT_BINARY_DIR}/clang.order CACHE FILEPATH
 493     "Order file to use when compiling clang in order to improve startup time (Darwin Only - requires ld64).")
 494
 495   if(NOT EXISTS ${CLANG_ORDER_FILE})
 496     string(FIND "${CLANG_ORDER_FILE}" "${CMAKE_CURRENT_BINARY_DIR}" PATH_START)
 497     if(PATH_START EQUAL 0)
 498       file(WRITE ${CLANG_ORDER_FILE} "\n")
 499     else()
 500       message(FATAL_ERROR "Specified order file '${CLANG_ORDER_FILE}' does not exist.")
 501     endif()
 502   endif()
 503 endif()
 504
 505
 506 if( CLANG_INCLUDE_TESTS )
 507   add_subdirectory(unittests)
 508   list(APPEND CLANG_TEST_DEPS ClangUnitTests)
 509   list(APPEND CLANG_TEST_PARAMS
 510     clang_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/test/Unit/lit.site.cfg
 511   )
 512   add_subdirectory(test)
 513   add_subdirectory(bindings/python/tests)
 514
 515   if(CLANG_BUILT_STANDALONE)
 516     umbrella_lit_testsuite_end(check-all)
 517   endif()
 518   add_subdirectory(utils/perf-training)
 519 endif()
 520
 521 option(CLANG_INCLUDE_DOCS "Generate build targets for the Clang docs."
 522   ${LLVM_INCLUDE_DOCS})
 523 if( CLANG_INCLUDE_DOCS )
 524   add_subdirectory(docs)
 525 endif()
 526
 527 # Custom target to install all clang libraries.
 528 add_custom_target(clang-libraries)
 529 set_target_properties(clang-libraries PROPERTIES FOLDER "Misc")
 530
 531 if(NOT LLVM_ENABLE_IDE)
 532   add_llvm_install_targets(install-clang-libraries
 533                            DEPENDS clang-libraries
 534                            COMPONENT clang-libraries)
 535 endif()
 536
 537 get_property(CLANG_LIBS GLOBAL PROPERTY CLANG_LIBS)
 538 if(CLANG_LIBS)
 539   list(REMOVE_DUPLICATES CLANG_LIBS)
 540   foreach(lib ${CLANG_LIBS})
 541     add_dependencies(clang-libraries ${lib})
 542     if(NOT LLVM_ENABLE_IDE)
 543       add_dependencies(install-clang-libraries install-${lib})
 544       add_dependencies(install-clang-libraries-stripped install-${lib}-stripped)
 545     endif()
 546   endforeach()
 547 endif()
 548
 549 add_subdirectory(cmake/modules)
 550
 551 if(CLANG_STAGE)
 552   message(STATUS "Setting current clang stage to: ${CLANG_STAGE}")
 553 endif()
 554
 555 if (CLANG_ENABLE_BOOTSTRAP)
 556   include(ExternalProject)
 557
 558   add_custom_target(clang-bootstrap-deps DEPENDS clang)
 559
 560   if(NOT CLANG_STAGE)
 561     set(CLANG_STAGE stage1)
 562   endif()
 563
 564   string(REGEX MATCH "stage([0-9]*)" MATCHED_STAGE "${CLANG_STAGE}")
 565   if(MATCHED_STAGE)
 566     if(NOT LLVM_BUILD_INSTRUMENTED)
 567       math(EXPR STAGE_NUM "${CMAKE_MATCH_1} + 1")
 568       set(NEXT_CLANG_STAGE stage${STAGE_NUM})
 569     else()
 570       set(NEXT_CLANG_STAGE stage${CMAKE_MATCH_1})
 571     endif()
 572   else()
 573     set(NEXT_CLANG_STAGE bootstrap)
 574   endif()
 575
 576   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 577     set(NEXT_CLANG_STAGE ${NEXT_CLANG_STAGE}-instrumented)
 578   endif()
 579   message(STATUS "Setting next clang stage to: ${NEXT_CLANG_STAGE}")
 580
 581
 582   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-stamps/)
 583   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-bins/)
 584
 585   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 586     # adding lld to clang-bootstrap-deps without having it enabled in
 587     # LLVM_ENABLE_PROJECTS just generates a cryptic error message.
 588     if (NOT "lld" IN_LIST LLVM_ENABLE_PROJECTS)
 589       message(FATAL_ERROR "LLD is enabled in the bootstrap build, but lld is not in LLVM_ENABLE_PROJECTS")
 590     endif()
 591     add_dependencies(clang-bootstrap-deps lld)
 592   endif()
 593
 594   if (WIN32)
 595     # Build llvm-rc and llvm-mt which are needed by the Windows build.
 596     add_dependencies(clang-bootstrap-deps llvm-rc)
 597     if(LLVM_ENABLE_LIBXML2)
 598       add_dependencies(clang-bootstrap-deps llvm-mt)
 599     endif()
 600   endif()
 601
 602   # If the next stage is LTO we need to depend on LTO and possibly lld or LLVMgold
 603   if(BOOTSTRAP_LLVM_ENABLE_LTO OR LLVM_ENABLE_LTO AND NOT LLVM_BUILD_INSTRUMENTED)
 604     if(APPLE)
 605       add_dependencies(clang-bootstrap-deps LTO)
 606       # on Darwin we need to set DARWIN_LTO_LIBRARY so that -flto will work
 607       # using the just-built compiler, and we need to override DYLD_LIBRARY_PATH
 608       # so that the host object file tools will use the just-built libLTO.
 609       # However if System Integrity Protection is enabled the DYLD variables
 610       # will be scrubbed from the environment of any base system commands. This
 611       # includes /bin/sh, which ninja uses when executing build commands. To
 612       # work around the envar being filtered away we pass it in as a CMake
 613       # variable, and have LLVM's CMake append the envar to the archiver calls.
 614       set(LTO_LIBRARY -DDARWIN_LTO_LIBRARY=${LLVM_SHLIB_OUTPUT_INTDIR}/libLTO.dylib
 615         -DDYLD_LIBRARY_PATH=${LLVM_LIBRARY_OUTPUT_INTDIR})
 616     elseif(MSVC)
 617       add_dependencies(clang-bootstrap-deps llvm-lib)
 618       set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-lib)
 619     elseif(NOT WIN32)
 620       add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 621       if(NOT BOOTSTRAP_LLVM_ENABLE_LLD AND LLVM_BINUTILS_INCDIR)
 622         add_dependencies(clang-bootstrap-deps LLVMgold)
 623       endif()
 624       set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 625       set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 626     endif()
 627   endif()
 628
 629   if(CLANG_BOOTSTRAP_EXTRA_DEPS)
 630     add_dependencies(clang-bootstrap-deps ${CLANG_BOOTSTRAP_EXTRA_DEPS})
 631   endif()
 632
 633   add_custom_target(${NEXT_CLANG_STAGE}-clear
 634     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 635     )
 636   add_custom_command(
 637     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 638     DEPENDS clang-bootstrap-deps
 639     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
 640     COMMAND ${CMAKE_COMMAND} -E make_directory ${BINARY_DIR}
 641     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
 642     COMMAND ${CMAKE_COMMAND} -E make_directory ${STAMP_DIR}
 643     COMMENT "Clobberring ${NEXT_CLANG_STAGE} build and stamp directories"
 644     )
 645
 646   if(CMAKE_VERBOSE_MAKEFILE)
 647     set(verbose -DCMAKE_VERBOSE_MAKEFILE=On)
 648   endif()
 649
 650   set(_BOOTSTRAP_DEFAULT_PASSTHROUGH
 651     PACKAGE_VERSION
 652     PACKAGE_VENDOR
 653     LLVM_VERSION_MAJOR
 654     LLVM_VERSION_MINOR
 655     LLVM_VERSION_PATCH
 656     CLANG_VERSION_MAJOR
 657     CLANG_VERSION_MINOR
 658     CLANG_VERSION_PATCHLEVEL
 659     CLANG_VENDOR
 660     LLVM_VERSION_SUFFIX
 661     LLVM_BINUTILS_INCDIR
 662     CLANG_REPOSITORY_STRING
 663     CMAKE_MAKE_PROGRAM
 664     CMAKE_OSX_ARCHITECTURES
 665     CMAKE_BUILD_TYPE
 666     LLVM_ENABLE_PROJECTS
 667     LLVM_ENABLE_RUNTIMES)
 668
 669   # We don't need to depend on compiler-rt/libcxx if we're building instrumented
 670   # because the next stage will use the same compiler used to build this stage.
 671   if(NOT LLVM_BUILD_INSTRUMENTED)
 672     if(TARGET compiler-rt)
 673       add_dependencies(clang-bootstrap-deps compiler-rt)
 674     endif()
 675     if(TARGET cxx-headers)
 676       add_dependencies(clang-bootstrap-deps cxx-headers)
 677     endif()
 678   endif()
 679
 680   set(C_COMPILER "clang")
 681   set(CXX_COMPILER "clang++")
 682   if(WIN32)
 683     set(C_COMPILER "clang-cl.exe")
 684     set(CXX_COMPILER "clang-cl.exe")
 685   endif()
 686
 687   set(COMPILER_OPTIONS
 688     -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${CXX_COMPILER}
 689     -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 690     -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 691     -DCMAKE_ASM_COMPILER_ID=Clang)
 692
 693   # cmake requires CMAKE_LINKER to be specified if the compiler is MSVC-like,
 694   # otherwise it defaults the linker to be link.exe.
 695   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 696     if((WIN32 AND NOT BOOTSTRAP_CMAKE_SYSTEM_NAME) OR BOOTSTRAP_CMAKE_SYSTEM_NAME STREQUAL "Windows")
 697       set(${CLANG_STAGE}_LINKER -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/lld-link${CMAKE_EXECUTABLE_SUFFIX})
 698     endif()
 699   endif()
 700
 701   if(BOOTSTRAP_CMAKE_SYSTEM_NAME)
 702     set(${CLANG_STAGE}_TABLEGEN
 703       -DLLVM_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-tblgen
 704       -DCLANG_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-tblgen)
 705     if(BOOTSTRAP_CMAKE_SYSTEM_NAME STREQUAL "Linux")
 706       if(BOOTSTRAP_LLVM_ENABLE_LLD)
 707         set(${CLANG_STAGE}_LINKER -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/ld.lld)
 708       endif()
 709       if(NOT BOOTSTRAP_LLVM_ENABLE_LTO)
 710         add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 711         set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 712         set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 713       endif()
 714       add_dependencies(clang-bootstrap-deps llvm-objcopy llvm-strip)
 715       set(${CLANG_STAGE}_OBJCOPY -DCMAKE_OBJCOPY=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-objcopy)
 716       set(${CLANG_STAGE}_STRIP -DCMAKE_STRIP=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-strip)
 717       set(${CLANG_STAGE}_READELF -DCMAKE_READELF=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-readelf)
 718     endif()
 719   endif()
 720
 721   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 722     add_dependencies(clang-bootstrap-deps llvm-profdata)
 723     set(PGO_OPT -DLLVM_PROFDATA=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-profdata)
 724   endif()
 725
 726   if(LLVM_BUILD_INSTRUMENTED)
 727     add_dependencies(clang-bootstrap-deps generate-profdata)
 728     set(PGO_OPT -DLLVM_PROFDATA_FILE=${CMAKE_CURRENT_BINARY_DIR}/utils/perf-training/clang.profdata)
 729     # Use the current tools for LTO instead of the instrumented ones
 730     list(APPEND _BOOTSTRAP_DEFAULT_PASSTHROUGH
 731       CMAKE_CXX_COMPILER
 732       CMAKE_C_COMPILER
 733       CMAKE_ASM_COMPILER
 734       CMAKE_AR
 735       CMAKE_RANLIB
 736       DARWIN_LTO_LIBRARY
 737       DYLD_LIBRARY_PATH)
 738
 739     set(COMPILER_OPTIONS)
 740     set(LTO_LIBRARY)
 741     set(LTO_AR)
 742     set(LTO_RANLIB)
 743   endif()
 744
 745   # Populate the passthrough variables
 746   foreach(variableName ${CLANG_BOOTSTRAP_PASSTHROUGH} ${_BOOTSTRAP_DEFAULT_PASSTHROUGH})
 747     if(DEFINED ${variableName})
 748       if("${${variableName}}" STREQUAL "")
 749         set(value "")
 750       else()
 751         string(REPLACE ";" "|" value "${${variableName}}")
 752       endif()
 753       list(APPEND PASSTHROUGH_VARIABLES
 754         -D${variableName}=${value})
 755     endif()
 756   endforeach()
 757
 758   # Find all variables that start with BOOTSTRAP_ and populate a variable with
 759   # them.
 760   get_cmake_property(variableNames VARIABLES)
 761   foreach(variableName ${variableNames})
 762     if(variableName MATCHES "^BOOTSTRAP_")
 763       string(SUBSTRING ${variableName} 10 -1 varName)
 764       string(REPLACE ";" "|" value "${${variableName}}")
 765       list(APPEND PASSTHROUGH_VARIABLES
 766         -D${varName}=${value})
 767     endif()
 768     if(${variableName} AND variableName MATCHES "LLVM_EXTERNAL_.*_SOURCE_DIR")
 769       list(APPEND PASSTHROUGH_VARIABLES
 770         -D${variableName}=${${variableName}})
 771     endif()
 772   endforeach()
 773
 774   # Build arguments for native tool used in CMake.
 775   set(build_configuration "$<CONFIG>")
 776   set(build_tool_args "${LLVM_EXTERNAL_PROJECT_BUILD_TOOL_ARGS}")
 777   if(NOT build_tool_args STREQUAL "")
 778     string(PREPEND build_tool_args "-- ")
 779     separate_arguments(build_tool_args UNIX_COMMAND "${build_tool_args}")
 780   endif()
 781
 782   ExternalProject_Add(${NEXT_CLANG_STAGE}
 783     DEPENDS clang-bootstrap-deps
 784     PREFIX ${NEXT_CLANG_STAGE}
 785     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 786     STAMP_DIR ${STAMP_DIR}
 787     BINARY_DIR ${BINARY_DIR}
 788     EXCLUDE_FROM_ALL 1
 789     CMAKE_ARGS
 790                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 791                 # seem to work, so instead I'm passing this through
 792                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 793                 ${PASSTHROUGH_VARIABLES}
 794                 ${CLANG_BOOTSTRAP_CMAKE_ARGS}
 795                  -DCLANG_STAGE=${NEXT_CLANG_STAGE}
 796                 ${COMPILER_OPTIONS}
 797                 ${${CLANG_STAGE}_TABLEGEN}
 798                 ${LTO_LIBRARY} ${verbose} ${PGO_OPT}
 799                 ${${CLANG_STAGE}_LINKER}
 800                 ${${CLANG_STAGE}_AR}
 801                 ${${CLANG_STAGE}_RANLIB}
 802                 ${${CLANG_STAGE}_OBJCOPY}
 803                 ${${CLANG_STAGE}_STRIP}
 804     BUILD_COMMAND ${CMAKE_COMMAND} --build ${BINARY_DIR}
 805                                    --config ${build_configuration}
 806                                    ${build_tool_args}
 807     INSTALL_COMMAND ""
 808     STEP_TARGETS configure build
 809     USES_TERMINAL_CONFIGURE 1
 810     USES_TERMINAL_BUILD 1
 811     USES_TERMINAL_INSTALL 1
 812     LIST_SEPARATOR |
 813     )
 814
 815   # exclude really-install from main target
 816   set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_really-install_EXCLUDE_FROM_MAIN On)
 817   ExternalProject_Add_Step(${NEXT_CLANG_STAGE} really-install
 818     COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target install
 819     COMMENT "Performing install step for '${NEXT_CLANG_STAGE}'"
 820     DEPENDEES build
 821     USES_TERMINAL 1
 822   )
 823   ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} really-install)
 824   add_custom_target(${NEXT_CLANG_STAGE}-install DEPENDS ${NEXT_CLANG_STAGE}-really-install)
 825
 826   if(NOT CLANG_BOOTSTRAP_TARGETS)
 827     set(CLANG_BOOTSTRAP_TARGETS check-llvm check-clang check-all)
 828   endif()
 829   foreach(target ${CLANG_BOOTSTRAP_TARGETS})
 830     # Install targets have side effects, so we always want to execute them.
 831     # "install" is reserved by CMake and can't be used as a step name for
 832     # ExternalProject_Add_Step, so we can match against "^install-" instead of
 833     # "^install" to get a tighter match. CMake's installation scripts already
 834     # skip up-to-date files, so there's no behavior change if you install to the
 835     # same destination multiple times.
 836     if(target MATCHES "^install-")
 837       set(step_always ON)
 838     else()
 839       set(step_always OFF)
 840     endif()
 841
 842     ExternalProject_Add_Step(${NEXT_CLANG_STAGE} ${target}
 843       COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target ${target}
 844       COMMENT "Performing ${target} for '${NEXT_CLANG_STAGE}'"
 845       DEPENDEES configure
 846       ALWAYS ${step_always}
 847       EXCLUDE_FROM_MAIN ON
 848       USES_TERMINAL 1
 849     )
 850
 851     if(target MATCHES "^stage[0-9]*")
 852       add_custom_target(${target} DEPENDS ${NEXT_CLANG_STAGE}-${target})
 853     endif()
 854
 855     ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} ${target})
 856   endforeach()
 857 endif()
 858
 859 if (CLANG_BOLT_INSTRUMENT AND NOT LLVM_BUILD_INSTRUMENTED)
 860   set(CLANG_PATH ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
 861   set(CLANGXX_PATH ${CLANG_PATH}++)
 862   set(CLANG_INSTRUMENTED ${CLANG_PATH}-bolt.inst)
 863   set(CLANGXX_INSTRUMENTED ${CLANGXX_PATH}-bolt.inst)
 864
 865   # Instrument clang with BOLT
 866   add_custom_target(clang-instrumented
 867     DEPENDS ${CLANG_INSTRUMENTED}
 868   )
 869   add_custom_command(OUTPUT ${CLANG_INSTRUMENTED}
 870     DEPENDS clang llvm-bolt
 871     COMMAND llvm-bolt ${CLANG_PATH} -o ${CLANG_INSTRUMENTED}
 872       -instrument --instrumentation-file-append-pid
 873       --instrumentation-file=${CMAKE_CURRENT_BINARY_DIR}/prof.fdata
 874     COMMENT "Instrumenting clang binary with BOLT"
 875     VERBATIM
 876   )
 877
 878   # Make a symlink from clang-bolt.inst to clang++-bolt.inst
 879   add_custom_target(clang++-instrumented
 880     DEPENDS ${CLANGXX_INSTRUMENTED}
 881   )
 882   add_custom_command(OUTPUT ${CLANGXX_INSTRUMENTED}
 883     DEPENDS clang-instrumented
 884     COMMAND ${CMAKE_COMMAND} -E create_symlink
 885       ${CLANG_INSTRUMENTED}
 886       ${CLANGXX_INSTRUMENTED}
 887     COMMENT "Creating symlink from BOLT instrumented clang to clang++"
 888     VERBATIM
 889   )
 890
 891   # Build specified targets with instrumented Clang to collect the profile
 892   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/bolt-instrumented-clang-stamps/)
 893   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/bolt-instrumented-clang-bins/)
 894   set(build_configuration "$<CONFIG>")
 895   include(ExternalProject)
 896   ExternalProject_Add(bolt-instrumentation-profile
 897     DEPENDS clang++-instrumented
 898     PREFIX bolt-instrumentation-profile
 899     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 900     STAMP_DIR ${STAMP_DIR}
 901     BINARY_DIR ${BINARY_DIR}
 902     EXCLUDE_FROM_ALL 1
 903     CMAKE_ARGS
 904                 ${CLANG_BOLT_INSTRUMENT_EXTRA_CMAKE_FLAGS}
 905                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 906                 # seem to work, so instead I'm passing this through
 907                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 908                 -DCMAKE_C_COMPILER=${CLANG_INSTRUMENTED}
 909                 -DCMAKE_CXX_COMPILER=${CLANGXX_INSTRUMENTED}
 910                 -DCMAKE_ASM_COMPILER=${CLANG_INSTRUMENTED}
 911                 -DCMAKE_ASM_COMPILER_ID=Clang
 912                 -DCMAKE_BUILD_TYPE=Release
 913                 -DLLVM_ENABLE_PROJECTS=${CLANG_BOLT_INSTRUMENT_PROJECTS}
 914                 -DLLVM_TARGETS_TO_BUILD=${LLVM_TARGETS_TO_BUILD}
 915     BUILD_COMMAND ${CMAKE_COMMAND} --build ${BINARY_DIR}
 916                                    --config ${build_configuration}
 917                                    --target ${CLANG_BOLT_INSTRUMENT_TARGETS}
 918     INSTALL_COMMAND ""
 919     STEP_TARGETS configure build
 920     USES_TERMINAL_CONFIGURE 1
 921     USES_TERMINAL_BUILD 1
 922     USES_TERMINAL_INSTALL 1
 923   )
 924
 925   # Merge profiles into one using merge-fdata
 926   add_custom_target(clang-bolt-profile
 927     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/prof.fdata
 928   )
 929   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/prof.fdata
 930     DEPENDS merge-fdata bolt-instrumentation-profile-build
 931     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 932     COMMAND ${Python3_EXECUTABLE}
 933       ${CMAKE_CURRENT_SOURCE_DIR}/utils/perf-training/perf-helper.py merge-fdata
 934       $<TARGET_FILE:merge-fdata> ${CMAKE_CURRENT_BINARY_DIR}/prof.fdata
 935       ${CMAKE_CURRENT_BINARY_DIR}
 936     COMMENT "Preparing BOLT profile"
 937     VERBATIM
 938   )
 939
 940   # Optimize original (pre-bolt) Clang using the collected profile
 941   set(CLANG_OPTIMIZED ${CMAKE_CURRENT_BINARY_DIR}/clang.bolt)
 942   add_custom_target(clang-bolt
 943     DEPENDS ${CLANG_OPTIMIZED}
 944   )
 945   add_custom_command(OUTPUT ${CLANG_OPTIMIZED}
 946     DEPENDS clang-bolt-profile
 947     COMMAND llvm-bolt ${CLANG_PATH}
 948       -o ${CLANG_OPTIMIZED}
 949       -data ${CMAKE_CURRENT_BINARY_DIR}/prof.fdata
 950       -reorder-blocks=ext-tsp -reorder-functions=hfsort+ -split-functions
 951       -split-all-cold -split-eh -dyno-stats -icf=1 -use-gnu-stack
 952     COMMAND ${CMAKE_COMMAND} -E rename ${CLANG_OPTIMIZED} $<TARGET_FILE:clang>
 953     COMMENT "Optimizing Clang with BOLT"
 954     VERBATIM
 955   )
 956 endif()
 957
 958 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 959   add_subdirectory(utils/ClangVisualizers)
 960 endif()
 961 add_subdirectory(utils/hmaptool)
 962
 963 if(CLANG_BUILT_STANDALONE)
 964   llvm_distribution_add_targets()
 965   process_llvm_pass_plugins()
 966 endif()
 967
 968 set(CLANG_INSTALL_LIBDIR_BASENAME "lib${CLANG_LIBDIR_SUFFIX}")
 969
 970 configure_file(
 971   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 972   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)