compiler-rt/test/asan/CMakeLists.txt

   1 set(ASAN_LIT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   2
   3 set(ASAN_TESTSUITES)
   4 set(ASAN_DYNAMIC_TESTSUITES)
   5
   6 # Before Windows 8 (CMAKE_SYSTEM_VERSION 6.2), reserving large regions of shadow
   7 # memory allocated physical memory for page tables, which made it very
   8 # unreliable. Remove the asan tests from check-all in this configuration.
   9 set(SHADOW_MAPPING_UNRELIABLE FALSE)
  10 if(OS_NAME MATCHES "Windows" AND CMAKE_SIZEOF_VOID_P EQUAL 8 AND
  11     ${CMAKE_SYSTEM_VERSION} LESS 6.2)
  12   set(SHADOW_MAPPING_UNRELIABLE TRUE)
  13   message(WARNING "Disabling ASan tests because they are unreliable on Windows 7 and earlier")
  14 endif()
  15
  16 if (SHADOW_MAPPING_UNRELIABLE)
  17   set(EXCLUDE_FROM_ALL TRUE)
  18 endif()
  19
  20 macro(get_bits_for_arch arch bits)
  21   if (${arch} MATCHES "i386|arm|mips|mipsel")
  22     set(${bits} 32)
  23   elseif (${arch} MATCHES "x86_64|powerpc64|powerpc64le|aarch64|mips64|mips64el|s390x")
  24     set(${bits} 64)
  25   else()
  26     message(FATAL_ERROR "Unknown target architecture: ${arch}")
  27   endif()
  28 endmacro()
  29
  30 set(ASAN_TEST_DEPS ${SANITIZER_COMMON_LIT_TEST_DEPS})
  31 if(NOT COMPILER_RT_STANDALONE_BUILD)
  32   list(APPEND ASAN_TEST_DEPS asan)
  33   if(NOT APPLE AND COMPILER_RT_HAS_LLD)
  34     list(APPEND ASAN_TEST_DEPS
  35       lld
  36     )
  37   endif()
  38 endif()
  39 set(ASAN_DYNAMIC_TEST_DEPS ${ASAN_TEST_DEPS})
  40
  41 set(ASAN_TEST_ARCH ${ASAN_SUPPORTED_ARCH})
  42 if(APPLE)
  43   darwin_filter_host_archs(ASAN_SUPPORTED_ARCH ASAN_TEST_ARCH)
  44 endif()
  45
  46 foreach(arch ${ASAN_TEST_ARCH})
  47   if(ANDROID)
  48     set(ASAN_TEST_TARGET_ARCH ${arch}-android)
  49   else()
  50     set(ASAN_TEST_TARGET_ARCH ${arch})
  51   endif()
  52
  53   set(ASAN_TEST_IOS "0")
  54   pythonize_bool(ASAN_TEST_IOS)
  55   set(ASAN_TEST_IOSSIM "0")
  56   pythonize_bool(ASAN_TEST_IOSSIM)
  57
  58   string(TOLOWER "-${arch}-${OS_NAME}" ASAN_TEST_CONFIG_SUFFIX)
  59   get_bits_for_arch(${arch} ASAN_TEST_BITS)
  60   get_test_cc_for_arch(${arch} ASAN_TEST_TARGET_CC ASAN_TEST_TARGET_CFLAGS)
  61   if(ANDROID)
  62     set(ASAN_TEST_DYNAMIC True)
  63   else()
  64     set(ASAN_TEST_DYNAMIC False)
  65   endif()
  66   string(TOUPPER ${arch} ARCH_UPPER_CASE)
  67   set(CONFIG_NAME ${ARCH_UPPER_CASE}${OS_NAME}Config)
  68   configure_lit_site_cfg(
  69     ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
  70     ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME}/lit.site.cfg
  71     )
  72   list(APPEND ASAN_TESTSUITES ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME})
  73
  74   if(COMPILER_RT_ASAN_HAS_STATIC_RUNTIME)
  75     string(TOLOWER "-${arch}-${OS_NAME}-dynamic" ASAN_TEST_CONFIG_SUFFIX)
  76     set(ASAN_TEST_DYNAMIC True)
  77     set(CONFIG_NAME ${ARCH_UPPER_CASE}${OS_NAME}DynamicConfig)
  78     configure_lit_site_cfg(
  79       ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
  80       ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME}/lit.site.cfg)
  81     list(APPEND ASAN_DYNAMIC_TESTSUITES
  82       ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME})
  83   endif()
  84 endforeach()
  85
  86 # iOS and iOS simulator test suites
  87 # These are not added into "check-all", in order to run these tests, use
  88 # "check-asan-iossim-x86_64" and similar. They also require that an extra env
  89 # variable to select which iOS device or simulator to use, e.g.:
  90 # SANITIZER_IOSSIM_TEST_DEVICE_IDENTIFIER="iPhone 6"
  91 if(APPLE)
  92   set(EXCLUDE_FROM_ALL ON)
  93
  94   set(ASAN_TEST_TARGET_CC ${COMPILER_RT_TEST_COMPILER})
  95   set(ASAN_TEST_IOS "1")
  96   pythonize_bool(ASAN_TEST_IOS)
  97   set(ASAN_TEST_DYNAMIC True)
  98
  99   foreach(arch ${DARWIN_iossim_ARCHS})
 100     set(ASAN_TEST_IOSSIM "1")
 101     pythonize_bool(ASAN_TEST_IOSSIM)
 102     set(ASAN_TEST_TARGET_ARCH ${arch})
 103     set(ASAN_TEST_TARGET_CFLAGS "-arch ${arch} -isysroot ${DARWIN_iossim_SYSROOT} ${COMPILER_RT_TEST_COMPILER_CFLAGS}")
 104     set(ASAN_TEST_CONFIG_SUFFIX "-${arch}-iossim")
 105     get_bits_for_arch(${arch} ASAN_TEST_BITS)
 106     string(TOUPPER ${arch} ARCH_UPPER_CASE)
 107     set(CONFIG_NAME "IOSSim${ARCH_UPPER_CASE}Config")
 108     configure_lit_site_cfg(
 109       ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
 110       ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME}/lit.site.cfg
 111       )
 112     add_lit_testsuite(check-asan-iossim-${arch} "AddressSanitizer iOS Simulator ${arch} tests"
 113       ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME}/
 114       DEPENDS ${ASAN_TEST_DEPS})
 115   endforeach()
 116
 117   foreach (arch ${DARWIN_ios_ARCHS})
 118     set(ASAN_TEST_IOSSIM "0")
 119     pythonize_bool(ASAN_TEST_IOSSIM)
 120     set(ASAN_TEST_TARGET_ARCH ${arch})
 121     set(ASAN_TEST_TARGET_CFLAGS "-arch ${arch} -isysroot ${DARWIN_ios_SYSROOT} ${COMPILER_RT_TEST_COMPILER_CFLAGS}")
 122     set(ASAN_TEST_CONFIG_SUFFIX "-${arch}-ios")
 123     get_bits_for_arch(${arch} ASAN_TEST_BITS)
 124     string(TOUPPER ${arch} ARCH_UPPER_CASE)
 125     set(CONFIG_NAME "IOS${ARCH_UPPER_CASE}Config")
 126     configure_lit_site_cfg(
 127       ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
 128       ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME}/lit.site.cfg
 129       )
 130     add_lit_testsuite(check-asan-ios-${arch} "AddressSanitizer iOS ${arch} tests"
 131       ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME}/
 132       DEPENDS ${ASAN_TEST_DEPS})
 133   endforeach()
 134
 135   set(EXCLUDE_FROM_ALL OFF)
 136 endif()
 137
 138 # Add unit tests.
 139 if(COMPILER_RT_INCLUDE_TESTS)
 140   set(ASAN_TEST_DYNAMIC False)
 141   configure_lit_site_cfg(
 142     ${CMAKE_CURRENT_SOURCE_DIR}/Unit/lit.site.cfg.in
 143     ${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg)
 144   if(COMPILER_RT_ASAN_HAS_STATIC_RUNTIME)
 145     set(ASAN_TEST_DYNAMIC True)
 146     configure_lit_site_cfg(
 147       ${CMAKE_CURRENT_SOURCE_DIR}/Unit/lit.site.cfg.in
 148       ${CMAKE_CURRENT_BINARY_DIR}/Unit/dynamic/lit.site.cfg)
 149   endif()
 150   # FIXME: support unit test in the android test runner
 151   if (NOT ANDROID)
 152     list(APPEND ASAN_TEST_DEPS AsanUnitTests)
 153     list(APPEND ASAN_TESTSUITES ${CMAKE_CURRENT_BINARY_DIR}/Unit)
 154     if(COMPILER_RT_ASAN_HAS_STATIC_RUNTIME)
 155       list(APPEND ASAN_DYNAMIC_TEST_DEPS AsanDynamicUnitTests)
 156       list(APPEND ASAN_DYNAMIC_TESTSUITES ${CMAKE_CURRENT_BINARY_DIR}/Unit/dynamic)
 157     endif()
 158   endif()
 159 endif()
 160
 161 add_lit_testsuite(check-asan "Running the AddressSanitizer tests"
 162   ${ASAN_TESTSUITES}
 163   DEPENDS ${ASAN_TEST_DEPS})
 164 set_target_properties(check-asan PROPERTIES FOLDER "Compiler-RT Misc")
 165
 166 if(COMPILER_RT_ASAN_HAS_STATIC_RUNTIME)
 167   # Add check-dynamic-asan target. It is a part of check-all only on Windows,
 168   # where we want to always test both dynamic and static runtime.
 169
 170   if(NOT OS_NAME MATCHES "Windows")
 171     set(EXCLUDE_FROM_ALL TRUE)
 172   endif()
 173   add_lit_testsuite(check-asan-dynamic
 174                     "Running the AddressSanitizer tests with dynamic runtime"
 175                     ${ASAN_DYNAMIC_TESTSUITES}
 176                     DEPENDS ${ASAN_DYNAMIC_TEST_DEPS})
 177   set_target_properties(check-asan-dynamic
 178                         PROPERTIES FOLDER "Compiler-RT Misc")
 179   if(NOT OS_NAME MATCHES "Windows")
 180     set(EXCLUDE_FROM_ALL FALSE)
 181   endif()
 182 endif()
 183
 184 # Reset EXCLUDE_FROM_ALL to its initial value.
 185 if (SHADOW_MAPPING_UNRELIABLE)
 186   set(EXCLUDE_FROM_ALL FALSE)
 187 endif()