llvm/test/Analysis/CostModel/X86/vectorized-loop.ll

   1 ; RUN: opt < %s  -passes="print<cost-model>" 2>&1 -disable-output -mtriple=x86_64-apple-macosx10.8.0 -mcpu=corei7-avx | FileCheck %s
   2
   3 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   4 target triple = "x86_64-apple-macosx10.8.0"
   5
   6 define i32 @foo(ptr noalias nocapture %A, ptr noalias nocapture %B, i32 %start, i32 %end) nounwind uwtable ssp {
   7 entry:
   8   ;CHECK: cost of 1 {{.*}} icmp
   9   %cmp7 = icmp slt i32 %start, %end
  10   br i1 %cmp7, label %for.body.lr.ph, label %for.end
  11
  12 for.body.lr.ph:                                   ; preds = %entry
  13   ;CHECK: cost of 1 {{.*}} sext
  14   %0 = sext i32 %start to i64
  15   %1 = sub i32 %end, %start
  16   %2 = zext i32 %1 to i64
  17   %end.idx = add i64 %2, %0
  18   ;CHECK: cost of 1 {{.*}} add
  19   %n.vec = and i64 %2, 4294967288
  20   %end.idx.rnd.down = add i64 %n.vec, %0
  21   ;CHECK: cost of 1 {{.*}} icmp
  22   %cmp.zero = icmp eq i64 %n.vec, 0
  23   br i1 %cmp.zero, label %middle.block, label %vector.body
  24
  25 vector.body:                                      ; preds = %for.body.lr.ph, %vector.body
  26   %index = phi i64 [ %index.next, %vector.body ], [ %0, %for.body.lr.ph ]
  27   %3 = add i64 %index, 2
  28   %4 = getelementptr inbounds i32, ptr %B, i64 %3
  29   ;CHECK: cost of 2 {{.*}} load
  30   %5 = load <8 x i32>, ptr %4, align 4
  31   ;CHECK: cost of 5 {{.*}} mul
  32   %6 = mul nsw <8 x i32> %5, <i32 5, i32 5, i32 5, i32 5, i32 5, i32 5, i32 5, i32 5>
  33   %7 = getelementptr inbounds i32, ptr %A, i64 %index
  34   ;CHECK: cost of 2 {{.*}} load
  35   %8 = load <8 x i32>, ptr %7, align 4
  36   ;CHECK: cost of 4 {{.*}} add
  37   %9 = add nsw <8 x i32> %8, %6
  38   ;CHECK: cost of 2 {{.*}} store
  39   store <8 x i32> %9, ptr %7, align 4
  40   %index.next = add i64 %index, 8
  41   %10 = icmp eq i64 %index.next, %end.idx.rnd.down
  42   ;CHECK: cost of 0 {{.*}} br
  43   br i1 %10, label %middle.block, label %vector.body
  44
  45 middle.block:                                     ; preds = %vector.body, %for.body.lr.ph
  46   %cmp.n = icmp eq i64 %end.idx, %end.idx.rnd.down
  47   br i1 %cmp.n, label %for.end, label %for.body
  48
  49 for.body:                                         ; preds = %middle.block, %for.body
  50   %indvars.iv = phi i64 [ %indvars.iv.next, %for.body ], [ %end.idx.rnd.down, %middle.block ]
  51   %11 = add nsw i64 %indvars.iv, 2
  52   %arrayidx = getelementptr inbounds i32, ptr %B, i64 %11
  53   ;CHECK: cost of 1 {{.*}} load
  54   %12 = load i32, ptr %arrayidx, align 4
  55   ;CHECK: cost of 1 {{.*}} mul
  56   %mul = mul nsw i32 %12, 5
  57   %arrayidx2 = getelementptr inbounds i32, ptr %A, i64 %indvars.iv
  58   ;CHECK: cost of 1 {{.*}} load
  59   %13 = load i32, ptr %arrayidx2, align 4
  60   %add3 = add nsw i32 %13, %mul
  61   store i32 %add3, ptr %arrayidx2, align 4
  62   %indvars.iv.next = add i64 %indvars.iv, 1
  63   ;CHECK: cost of 0 {{.*}} trunc
  64   %14 = trunc i64 %indvars.iv.next to i32
  65   %cmp = icmp slt i32 %14, %end
  66   ;CHECK: cost of 0 {{.*}} br
  67   br i1 %cmp, label %for.body, label %for.end
  68
  69 for.end:                                          ; preds = %middle.block, %for.body, %entry
  70   ;CHECK: cost of 0 {{.*}} ret
  71   ret i32 undef
  72 }