llvm/test/Analysis/LoopAccessAnalysis/print-order.ll

   1 ; REQUIRES: asserts
   2 ; RUN: opt -passes='print<access-info>' -debug-only=loop-accesses -disable-output < %s 2>&1 | FileCheck %s
   3
   4 ; void negative_step(int *A) {
   5 ;  for (int i = 1022; i >= 0; i--)
   6 ;    A[i+1] = A[i] + 1;
   7 ; }
   8
   9 ; CHECK-LABEL: 'negative_step'
  10 ; CHECK: LAA: Found an analyzable loop: loop
  11 ; CHECK: LAA: Checking memory dependencies
  12 ; CHECK-NEXT: LAA: Src Scev: {(4092 + %A),+,-4}<nw><%loop>Sink Scev: {(4088 + %A)<nuw>,+,-4}<nw><%loop>
  13 ; CHECK-NEXT: LAA: Distance for   store i32 %add, ptr %gep.A.plus.1, align 4 to   %l = load i32, ptr %gep.A, align 4: -4
  14 ; CHECK-NEXT: LAA: Src induction step: -1 Sink induction step: -1
  15 ; CHECK-NEXT: LAA: Dependence is negative
  16
  17 define void @negative_step(ptr nocapture %A) {
  18 entry:
  19   %A.plus.1 = getelementptr i32, ptr %A, i64 1
  20   br label %loop
  21
  22 loop:
  23   %iv = phi i64 [ 1022, %entry ], [ %iv.next, %loop ]
  24   %gep.A = getelementptr inbounds i32, ptr %A, i64 %iv
  25   %l = load i32, ptr %gep.A, align 4
  26   %add = add nsw i32 %l, 1
  27   %gep.A.plus.1 = getelementptr i32, ptr %A.plus.1, i64 %iv
  28   store i32 %add, ptr %gep.A.plus.1, align 4
  29   %iv.next = add nsw i64 %iv, -1
  30   %cmp.not = icmp eq i64 %iv, 0
  31   br i1 %cmp.not, label %exit, label %loop
  32
  33 exit:
  34   ret void
  35 }
  36
  37 ; void positive_step(int *A) {
  38 ;  for (int i = 1; i < 1024; i++)
  39 ;    A[i-1] = A[i] + 1;
  40 ; }
  41
  42 ; CHECK-LABEL: 'positive_step'
  43 ; CHECK: LAA: Found an analyzable loop: loop
  44 ; CHECK: LAA: Checking memory dependencies
  45 ; CHECK-NEXT: LAA: Src Scev: {(4 + %A)<nuw>,+,4}<nuw><%loop>Sink Scev: {%A,+,4}<nw><%loop>
  46 ; CHECK-NEXT: LAA: Distance for   %l = load i32, ptr %gep.A, align 4 to   store i32 %add, ptr %gep.A.minus.1, align 4: -4
  47 ; CHECK-NEXT: LAA: Src induction step: 1 Sink induction step: 1
  48 ; CHECK-NEXT: LAA: Dependence is negative
  49
  50 define void @positive_step(ptr nocapture %A) {
  51 entry:
  52   %A.minus.1 = getelementptr i32, ptr %A, i64 -1
  53   br label %loop
  54
  55 loop:
  56   %iv = phi i64 [ 1, %entry ], [ %iv.next, %loop ]
  57   %gep.A = getelementptr inbounds i32, ptr %A, i64 %iv
  58   %l = load i32, ptr %gep.A, align 4
  59   %add = add nsw i32 %l, 1
  60   %gep.A.minus.1 = getelementptr i32, ptr %A.minus.1, i64 %iv
  61   store i32 %add, ptr %gep.A.minus.1, align 4
  62   %iv.next = add nsw i64 %iv, 1
  63   %cmp.not = icmp eq i64 %iv, 1024
  64   br i1 %cmp.not, label %exit, label %loop
  65
  66 exit:
  67   ret void
  68 }
  69