llvm/test/ThinLTO/X86/devirt_pure_virtual_base.ll

   1 ;; Test that pure virtual base is handled correctly.
   2
   3 ;; Index based WPD
   4 ;; Generate unsplit module with summary for ThinLTO index-based WPD.
   5 ; RUN: opt --thinlto-bc -o %t1a.o %s
   6 ; RUN: llvm-lto2 run %t1a.o -save-temps -pass-remarks=. \
   7 ; RUN:   -whole-program-visibility \
   8 ; RUN:   -o %t3a \
   9 ; RUN:   -r=%t1a.o,_start,plx \
  10 ; RUN:   -r=%t1a.o,_ZTV1A,p \
  11 ; RUN:   -r=%t1a.o,_ZTV1B,p \
  12 ; RUN:   -r=%t1a.o,_ZN1A1fEi,p \
  13 ; RUN:   -r=%t1a.o,_ZN1A1nEi,p \
  14 ; RUN:   -r=%t1a.o,_ZN1B1fEi,p \
  15 ; RUN:   -r=%t1a.o,__cxa_pure_virtual, \
  16 ; RUN:   2>&1 | FileCheck %s --check-prefix=REMARK
  17 ; RUN: llvm-dis %t3a.1.4.opt.bc -o - | FileCheck %s --check-prefix=CHECK-IR
  18
  19 ;; Hybrid WPD
  20 ;; Generate split module with summary for hybrid Thin/Regular LTO WPD.
  21 ; RUN: opt --thinlto-bc --thinlto-split-lto-unit -o %t1b.o %s
  22 ; RUN: llvm-lto2 run %t1b.o -save-temps -pass-remarks=. \
  23 ; RUN:   -whole-program-visibility \
  24 ; RUN:   -o %t3b \
  25 ; RUN:   -r=%t1b.o,_start,plx \
  26 ; RUN:   -r=%t1b.o,_ZTV1A, \
  27 ; RUN:   -r=%t1b.o,_ZTV1B, \
  28 ; RUN:   -r=%t1b.o,__cxa_pure_virtual, \
  29 ; RUN:   -r=%t1b.o,_ZN1A1fEi,p \
  30 ; RUN:   -r=%t1b.o,_ZN1A1nEi,p \
  31 ; RUN:   -r=%t1b.o,_ZN1B1fEi,p \
  32 ; RUN:   -r=%t1b.o,_ZTV1A,p \
  33 ; RUN:   -r=%t1b.o,_ZTV1B,p \
  34 ; RUN:   -r=%t1b.o,_ZN1A1nEi, \
  35 ; RUN:   -r=%t1b.o,_ZN1B1fEi, \
  36 ; RUN:   -r=%t1b.o,__cxa_pure_virtual, \
  37 ; RUN:   2>&1 | FileCheck %s --check-prefix=REMARK
  38 ; RUN: llvm-dis %t3b.1.4.opt.bc -o - | FileCheck %s --check-prefix=CHECK-IR
  39
  40 ;; Regular LTO WPD
  41 ; RUN: opt -o %t1c.o %s
  42 ; RUN: llvm-lto2 run %t1c.o -save-temps -pass-remarks=. \
  43 ; RUN:   -whole-program-visibility \
  44 ; RUN:   -o %t3c \
  45 ; RUN:   -r=%t1c.o,_start,plx \
  46 ; RUN:   -r=%t1c.o,_ZTV1A,p \
  47 ; RUN:   -r=%t1c.o,_ZTV1B,p \
  48 ; RUN:   -r=%t1c.o,_ZN1A1fEi,p \
  49 ; RUN:   -r=%t1c.o,_ZN1A1nEi,p \
  50 ; RUN:   -r=%t1c.o,_ZN1B1fEi,p \
  51 ; RUN:   -r=%t1c.o,__cxa_pure_virtual, \
  52 ; RUN:   2>&1 | FileCheck %s --check-prefix=REMARK
  53 ; RUN: llvm-dis %t3c.0.4.opt.bc -o - | FileCheck %s --check-prefix=CHECK-IR
  54
  55 ; REMARK-DAG: single-impl: devirtualized a call to _ZN1A1nEi
  56
  57 target datalayout = "e-m:e-p270:32:32-p271:32:32-p272:64:64-i64:64-f80:128-n8:16:32:64-S128"
  58 target triple = "x86_64-grtev4-linux-gnu"
  59
  60 %struct.A = type { ptr }
  61 %struct.B = type { %struct.A }
  62
  63 @_ZTV1A = linkonce_odr unnamed_addr constant { [4 x ptr] } { [4 x ptr] [ptr null, ptr undef, ptr @__cxa_pure_virtual, ptr @__cxa_pure_virtual] }, !type !0, !vcall_visibility !2
  64 @_ZTV1B = linkonce_odr unnamed_addr constant { [4 x ptr] } { [4 x ptr] [ptr null, ptr undef, ptr @_ZN1B1fEi, ptr @_ZN1A1nEi] }, !type !0, !type !1, !vcall_visibility !2
  65
  66 ;; Prevent the vtables from being dead code eliminated.
  67 @llvm.used = appending global [2 x ptr] [ ptr @_ZTV1A, ptr @_ZTV1B]
  68
  69 ; CHECK-IR-LABEL: define dso_local {{(noundef )?}}i32 @_start
  70 define i32 @_start(ptr %obj, i32 %a) {
  71 entry:
  72   %vtable = load ptr, ptr %obj
  73   %p = call i1 @llvm.type.test(ptr %vtable, metadata !"_ZTS1A")
  74   call void @llvm.assume(i1 %p)
  75   %fptrptr = getelementptr ptr, ptr %vtable, i32 1
  76   %fptr1 = load ptr, ptr %fptrptr, align 8
  77
  78   ;; Check that the call was devirtualized.
  79   ; CHECK-IR: %call = tail call i32 @_ZN1A1nEi
  80   ; CHECK-NODEVIRT-IR: %call = tail call i32 %fptr1
  81   %call = tail call i32 %fptr1(ptr nonnull %obj, i32 %a)
  82
  83   ret i32 %call
  84 }
  85 ; CHECK-IR-LABEL: ret i32
  86 ; CHECK-IR-NEXT: }
  87
  88 declare i1 @llvm.type.test(ptr, metadata)
  89 declare void @llvm.assume(i1)
  90 declare void @__cxa_pure_virtual() unnamed_addr
  91
  92 define linkonce_odr i32 @_ZN1A1fEi(ptr %this, i32 %a) #0 {
  93    ret i32 0
  94 }
  95
  96 define linkonce_odr i32 @_ZN1A1nEi(ptr %this, i32 %a) #0 {
  97    ret i32 0
  98 }
  99
 100 define linkonce_odr i32 @_ZN1B1fEi(ptr %this, i32 %a) #0 {
 101    ret i32 0
 102 }
 103
 104 ;; Make sure we don't inline or otherwise optimize out the direct calls.
 105 attributes #0 = { noinline optnone }
 106
 107 !0 = !{i64 16, !"_ZTS1A"}
 108 !1 = !{i64 16, !"_ZTS1B"}
 109 !2 = !{i64 0}