llvm/test/ThinLTO/X86/import_callee_declaration.ll

   1 ; "-debug-only" requires asserts.
   2 ; REQUIRES: asserts
   3 ; RUN: rm -rf %t && split-file %s %t && cd %t
   4
   5 ; Generate per-module summaries.
   6 ; RUN: opt -module-summary main.ll -o main.bc
   7 ; RUN: opt -module-summary lib.ll -o lib.bc
   8
   9 ; Generate the combined summary and distributed indices.
  10
  11 ; - For function import, set 'import-instr-limit' to 7 and fall back to import
  12 ;   function declarations.
  13 ; - In main.ll, function 'main' calls 'small_func' and 'large_func'. Both callees
  14 ;   are defined in lib.ll. 'small_func' has two indirect callees, one is smaller
  15 ;   and the other one is larger. Both callees of 'small_func' are defined in lib.ll.
  16 ; - Given the import limit, in main's combined summary, the import type of 'small_func'
  17 ;   and 'small_indirect_callee' will be 'definition', and the import type of
  18 ;   large* functions and their aliasees will be 'declaration'.
  19 ;
  20 ; The test will disassemble combined summaries and check the import type is
  21 ; correct. Right now postlink optimizer pipeline doesn't do anything (e.g.,
  22 ; import the declaration or de-serialize summary attributes yet) so there is
  23 ; nothing to test more than the summary content.
  24 ;
  25 ; TODO: Extend this test case to test IR once postlink optimizer makes use of
  26 ; the import type for declarations.
  27 ;
  28 ; RUN: llvm-lto2 run \
  29 ; RUN:   -debug-only=function-import \
  30 ; RUN:   -import-instr-limit=7 \
  31 ; RUN:   -import-instr-evolution-factor=1.0 \
  32 ; RUN:   -import-declaration \
  33 ; RUN:   -thinlto-distributed-indexes \
  34 ; RUN:   -r=main.bc,main,px \
  35 ; RUN:   -r=main.bc,small_func, \
  36 ; RUN:   -r=main.bc,large_func, \
  37 ; RUN:   -r=lib.bc,callee,pl \
  38 ; RUN:   -r=lib.bc,large_indirect_callee,px \
  39 ; RUN:   -r=lib.bc,large_indirect_bar,px \
  40 ; RUN:   -r=lib.bc,small_func,px \
  41 ; RUN:   -r=lib.bc,large_func,px \
  42 ; RUN:   -r=lib.bc,large_indirect_callee_alias,px \
  43 ; RUN:   -r=lib.bc,large_indirect_bar_alias,px \
  44 ; RUN:   -r=lib.bc,calleeAddrs,px -r=lib.bc,calleeAddrs2,px -o summary main.bc lib.bc 2>&1 | FileCheck %s --check-prefix=DUMP
  45 ;
  46 ; RUN: llvm-lto -thinlto-action=thinlink -import-declaration -import-instr-limit=7 -import-instr-evolution-factor=1.0 -o combined.index.bc main.bc lib.bc
  47 ; RUN: llvm-lto -thinlto-action=distributedindexes -debug-only=function-import -import-declaration -import-instr-limit=7 -import-instr-evolution-factor=1.0 -thinlto-index combined.index.bc main.bc lib.bc 2>&1 | FileCheck %s --check-prefix=DUMP
  48
  49 ; DUMP: - 2 function definitions and 4 function declarations imported from lib.bc
  50
  51 ; First disassemble per-module summary and find out the GUID for {large_func, large_indirect_callee}.
  52 ;
  53 ; RUN: llvm-dis lib.bc -o - | FileCheck %s --check-prefix=LIB-DIS
  54 ; LIB-DIS: module: (path: "lib.bc", hash: (0, 0, 0, 0, 0))
  55 ; LIB-DIS: gv: (name: "large_func", summaries: {{.*}}) ; guid = 2418497564662708935
  56 ; LIB-DIS: gv: (name: "large_indirect_bar_alias", summaries: {{.*}}, aliasee: [[LARGEINDIRECT_BAR:\^[0-9]+]]{{.*}}guid = 13590951773474913315
  57 ; LIB-DIS: [[LARGEINDIRECT_BAR]] = gv: (name: "large_indirect_bar", summaries: {{.*}}) ; guid = 13770917885399536773
  58 ; LIB-DIS: [[LARGEINDIRECT:\^[0-9]+]] = gv: (name: "large_indirect_callee", summaries: {{.*}}) ; guid = 14343440786664691134
  59 ; LIB-DIS: gv: (name: "large_indirect_callee_alias", summaries: {{.*}}, aliasee: [[LARGEINDIRECT]]{{.*}}guid = 16730173943625350469
  60 ;
  61 ; Secondly disassemble main's combined summary and verify the import type of
  62 ; these two GUIDs are declaration.
  63 ;
  64 ; RUN: llvm-dis main.bc.thinlto.bc -o - | FileCheck %s --check-prefix=MAIN-DIS
  65 ;
  66 ; MAIN-DIS: [[LIBMOD:\^[0-9]+]] = module: (path: "lib.bc", hash: (0, 0, 0, 0, 0))
  67 ; MAIN-DIS: gv: (guid: 2418497564662708935, summaries: (function: (module: [[LIBMOD]], flags: ({{.*}} importType: declaration), insts: 8, {{.*}})))
  68 ; When alias is imported as a copy of the aliasee, but the aliasee is not being
  69 ; imported by itself, the aliasee should be null.
  70 ; MAIN-DIS: gv: (guid: 13590951773474913315, summaries: (alias: (module: [[LIBMOD]], flags: ({{.*}} importType: declaration), aliasee: null)))
  71 ; MAIN-DIS: [[LARGEINDIRECT:\^[0-9]+]] = gv: (guid: 14343440786664691134, summaries: (function: (module: [[LIBMOD]], flags: ({{.*}} importType: declaration), insts: 8, {{.*}})))
  72 ; MAIN-DIS: gv: (guid: 16730173943625350469, summaries: (alias: (module: [[LIBMOD]], flags: ({{.*}} importType: declaration), aliasee: [[LARGEINDIRECT]])))
  73
  74 ; Run in-process ThinLTO and tests that
  75 ; 1. `callee` remains internalized even if the symbols of its callers
  76 ; (large_func, large_indirect_callee, large_indirect_bar) are exported as
  77 ; declarations and visible to main module.
  78 ; 2. the debugging logs from `function-import` pass are expected.
  79
  80 ; RUN: llvm-lto2 run \
  81 ; RUN:   -debug-only=function-import \
  82 ; RUN:   -save-temps \
  83 ; RUN:   -thinlto-threads=1 \
  84 ; RUN:   -import-instr-limit=7 \
  85 ; RUN:   -import-instr-evolution-factor=1.0 \
  86 ; RUN:   -import-declaration \
  87 ; RUN:   -r=main.bc,main,px \
  88 ; RUN:   -r=main.bc,small_func, \
  89 ; RUN:   -r=main.bc,large_func, \
  90 ; RUN:   -r=lib.bc,callee,pl \
  91 ; RUN:   -r=lib.bc,large_indirect_callee,px \
  92 ; RUN:   -r=lib.bc,large_indirect_bar,px \
  93 ; RUN:   -r=lib.bc,small_func,px \
  94 ; RUN:   -r=lib.bc,large_func,px \
  95 ; RUN:   -r=lib.bc,large_indirect_callee_alias,px \
  96 ; RUN:   -r=lib.bc,large_indirect_bar_alias,px \
  97 ; RUN:   -r=lib.bc,calleeAddrs,px -r=lib.bc,calleeAddrs2,px -o in-process main.bc lib.bc 2>&1 | FileCheck %s --check-prefix=IMPORTDUMP
  98
  99 ; TODO: Extend this test case to test IR once postlink optimizer makes use of
 100 ; the import type for declarations.
 101 ; IMPORTDUMP-DAG: Not importing function 11825436545918268459 callee from lib.cc
 102 ; IMPORTDUMP-DAG: Is importing function declaration 14343440786664691134 large_indirect_callee from lib.cc
 103 ; IMPORTDUMP-DAG: Is importing function definition 13568239288960714650 small_indirect_callee from lib.cc
 104 ; IMPORTDUMP-DAG: Is importing function definition 6976996067367342685 small_func from lib.cc
 105 ; IMPORTDUMP-DAG: Is importing function declaration 2418497564662708935 large_func from lib.cc
 106 ; IMPORTDUMP-DAG: Not importing global 7680325410415171624 calleeAddrs from lib.cc
 107 ; IMPORTDUMP-DAG: Is importing alias declaration 16730173943625350469 large_indirect_callee_alias from lib.cc
 108 ; IMPORTDUMP-DAG: Is importing alias declaration 13590951773474913315 large_indirect_bar_alias from lib.cc
 109 ; IMPORTDUMP-DAG: Not importing function 13770917885399536773 large_indirect_bar
 110
 111 ; RUN: llvm-dis in-process.1.3.import.bc -o - | FileCheck %s --check-prefix=IMPORT
 112
 113 ; RUN: llvm-dis in-process.2.2.internalize.bc -o - | FileCheck %s --check-prefix=INTERNALIZE
 114
 115 ; IMPORT-DAG: define available_externally void @small_func
 116 ; IMPORT-DAG: define available_externally hidden void @small_indirect_callee
 117 ; IMPORT-DAG: declare void @large_func
 118 ; IMPORT-NOT: large_indirect_callee
 119 ; IMPORT-NOT: large_indirect_callee_alias
 120 ; IMPORT-NOT: large_indirect_bar
 121 ; IMPORT-NOT: large_indirect_bar_alias
 122
 123 ; INTERNALIZE: define internal void @callee()
 124
 125 ;--- main.ll
 126 target datalayout = "e-m:e-p270:32:32-p271:32:32-p272:64:64-i64:64-i128:128-f80:128-n8:16:32:64-S128"
 127 target triple = "x86_64-unknown-linux-gnu"
 128
 129 define i32 @main() {
 130   call void @small_func()
 131   call void @large_func()
 132   ret i32 0
 133 }
 134
 135 declare void @small_func()
 136
 137 ; large_func without attributes
 138 declare void @large_func()
 139
 140 ;--- lib.ll
 141 source_filename = "lib.cc"
 142 target datalayout = "e-m:e-p270:32:32-p271:32:32-p272:64:64-i64:64-i128:128-f80:128-n8:16:32:64-S128"
 143 target triple = "x86_64-unknown-linux-gnu"
 144
 145 ; Both large_indirect_callee and large_indirect_callee_alias are referenced
 146 ; and visible to main.ll.
 147 @calleeAddrs = global [3 x ptr] [ptr @large_indirect_callee, ptr @small_indirect_callee, ptr @large_indirect_callee_alias]
 148
 149 ; large_indirect_bar_alias is visible to main.ll but its aliasee isn't.
 150 @calleeAddrs2 = global [1 x ptr] [ptr @large_indirect_bar_alias]
 151
 152 define void @callee() #1 {
 153   ret void
 154 }
 155
 156 define void @large_indirect_callee()#2 {
 157   call void @callee()
 158   call void @callee()
 159   call void @callee()
 160   call void @callee()
 161   call void @callee()
 162   call void @callee()
 163   call void @callee()
 164   ret void
 165 }
 166
 167 define void @large_indirect_bar()#2 {
 168   call void @callee()
 169   call void @callee()
 170   call void @callee()
 171   call void @callee()
 172   call void @callee()
 173   call void @callee()
 174   call void @callee()
 175   ret void
 176 }
 177
 178 define internal void @small_indirect_callee() #0 {
 179 entry:
 180   %0 = load ptr, ptr @calleeAddrs2
 181   call void %0(), !prof !3
 182   ret void
 183 }
 184
 185 @large_indirect_callee_alias = alias void(), ptr @large_indirect_callee
 186
 187 @large_indirect_bar_alias = alias void(), ptr @large_indirect_bar
 188
 189 define void @small_func() {
 190 entry:
 191   %0 = load ptr, ptr @calleeAddrs
 192   call void %0(), !prof !0
 193   %1 = load ptr, ptr getelementptr inbounds ([3 x ptr], ptr @calleeAddrs, i64 0, i64 1)
 194   call void %1(), !prof !1
 195   %2 = load ptr, ptr getelementptr inbounds ([3 x ptr], ptr @calleeAddrs, i64 0, i64 2)
 196   call void %2(), !prof !2
 197   ret void
 198 }
 199
 200 define void @large_func() #0 {
 201 entry:
 202   call void @callee()
 203   call void @callee()
 204   call void @callee()
 205   call void @callee()
 206   call void @callee()
 207   call void @callee()
 208   call void @callee()
 209   ret void
 210 }
 211
 212 attributes #0 = { nounwind norecurse }
 213
 214 attributes #1 = { noinline }
 215
 216 attributes #2 = { norecurse }
 217
 218 !0 = !{!"VP", i32 0, i64 1, i64 14343440786664691134, i64 1}
 219 !1 = !{!"VP", i32 0, i64 1, i64 13568239288960714650, i64 1}
 220 !2 = !{!"VP", i32 0, i64 1, i64 16730173943625350469, i64 1}
 221 !3 = !{!"VP", i32 0, i64 1, i64 13590951773474913315, i64 1}