llvm/test/Transforms/GVN/PRE/rle-phi-translate.ll

   1 ; RUN: opt < %s -passes=gvn -S | FileCheck %s
   2
   3 target datalayout = "e-p:32:32:32-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:32:64-f32:32:32-f64:32:64-v64:64:64-v128:128:128-a0:0:64-f80:128:128"
   4 target triple = "i386-apple-darwin7"
   5
   6 define i32 @test1(ptr %b, ptr %c) nounwind {
   7 ; CHECK-LABEL: @test1(
   8 entry:
   9         %g = alloca i32
  10         %t1 = icmp eq ptr %b, null
  11         br i1 %t1, label %bb, label %bb1
  12
  13 bb:
  14         %t2 = load i32, ptr %c, align 4
  15         %t3 = add i32 %t2, 1
  16         store i32 %t3, ptr %g, align 4
  17         br label %bb2
  18
  19 bb1:            ; preds = %entry
  20         %t5 = load i32, ptr %b, align 4
  21         %t6 = add i32 %t5, 1
  22         store i32 %t6, ptr %g, align 4
  23         br label %bb2
  24
  25 bb2:            ; preds = %bb1, %bb
  26         %c_addr.0 = phi ptr [ %g, %bb1 ], [ %c, %bb ]
  27         %b_addr.0 = phi ptr [ %b, %bb1 ], [ %g, %bb ]
  28         %cv = load i32, ptr %c_addr.0, align 4
  29         %bv = load i32, ptr %b_addr.0, align 4
  30 ; CHECK: %bv = phi i32
  31 ; CHECK: %cv = phi i32
  32 ; CHECK-NOT: load
  33 ; CHECK: ret i32
  34         %ret = add i32 %cv, %bv
  35         ret i32 %ret
  36 }
  37
  38 define i8 @test2(i1 %cond, ptr %b, ptr %c) nounwind {
  39 ; CHECK-LABEL: @test2(
  40 entry:
  41   br i1 %cond, label %bb, label %bb1
  42
  43 bb:
  44   store i8 4, ptr %b
  45   br label %bb2
  46
  47 bb1:
  48   store i8 92, ptr %c
  49   br label %bb2
  50
  51 bb2:
  52   %d = phi ptr [ %c, %bb1 ], [ %b, %bb ]
  53   %dv = load i8, ptr %d
  54 ; CHECK: %dv = phi i8 [ 92, %bb1 ], [ 4, %bb ]
  55 ; CHECK-NOT: load
  56 ; CHECK: ret i8 %dv
  57   ret i8 %dv
  58 }
  59
  60 define i32 @test3(i1 %cond, ptr %b, ptr %c) nounwind {
  61 ; CHECK-LABEL: @test3(
  62 entry:
  63   br i1 %cond, label %bb, label %bb1
  64
  65 bb:
  66   %b1 = getelementptr i32, ptr %b, i32 17
  67   store i32 4, ptr %b1
  68   br label %bb2
  69
  70 bb1:
  71   %c1 = getelementptr i32, ptr %c, i32 7
  72   store i32 82, ptr %c1
  73   br label %bb2
  74
  75 bb2:
  76   %d = phi ptr [ %c, %bb1 ], [ %b, %bb ]
  77   %i = phi i32 [ 7, %bb1 ], [ 17, %bb ]
  78   %d1 = getelementptr i32, ptr %d, i32 %i
  79   %dv = load i32, ptr %d1
  80 ; CHECK: %dv = phi i32 [ 82, %bb1 ], [ 4, %bb ]
  81 ; CHECK-NOT: load
  82 ; CHECK: ret i32 %dv
  83   ret i32 %dv
  84 }
  85
  86 ; PR5313
  87 define i32 @test4(i1 %cond, ptr %b, ptr %c) nounwind {
  88 ; CHECK-LABEL: @test4(
  89 entry:
  90   br i1 %cond, label %bb, label %bb1
  91
  92 bb:
  93   store i32 4, ptr %b
  94   br label %bb2
  95
  96 bb1:
  97   %c1 = getelementptr i32, ptr %c, i32 7
  98   store i32 82, ptr %c1
  99   br label %bb2
 100
 101 bb2:
 102   %d = phi ptr [ %c, %bb1 ], [ %b, %bb ]
 103   %i = phi i32 [ 7, %bb1 ], [ 0, %bb ]
 104   %d1 = getelementptr i32, ptr %d, i32 %i
 105   %dv = load i32, ptr %d1
 106 ; CHECK: %dv = phi i32 [ 82, %bb1 ], [ 4, %bb ]
 107 ; CHECK-NOT: load
 108 ; CHECK: ret i32 %dv
 109   ret i32 %dv
 110 }
 111
 112
 113
 114 ; void test5(int N, ptr G) {
 115 ;   for (long j = 1; j < 1000; j++)
 116 ;     G[j] = G[j] + G[j-1];
 117 ; }
 118 ;
 119 ; Should compile into one load in the loop.
 120 define void @test5(i32 %N, ptr nocapture %G) nounwind ssp {
 121 ; CHECK-LABEL: @test5(
 122 bb.nph:
 123   br label %for.body
 124
 125 for.body:
 126   %indvar = phi i64 [ 0, %bb.nph ], [ %tmp, %for.body ]
 127   %arrayidx6 = getelementptr double, ptr %G, i64 %indvar
 128   %tmp = add i64 %indvar, 1
 129   %arrayidx = getelementptr double, ptr %G, i64 %tmp
 130   %tmp3 = load double, ptr %arrayidx
 131   %tmp7 = load double, ptr %arrayidx6
 132   %add = fadd double %tmp3, %tmp7
 133   store double %add, ptr %arrayidx
 134   %exitcond = icmp eq i64 %tmp, 999
 135   br i1 %exitcond, label %for.end, label %for.body
 136 ; CHECK: for.body:
 137 ; CHECK: phi double
 138 ; CHECK: load double
 139 ; CHECK-NOT: load double
 140 ; CHECK: br i1
 141 for.end:
 142   ret void
 143 }