llvm/test/Transforms/LoopVectorize/if-conversion.ll

   1 ; RUN: opt < %s -passes=loop-vectorize,dce,instcombine -force-vector-interleave=1 -force-vector-width=4 -enable-if-conversion -S | FileCheck %s
   2
   3 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   4
   5 ; This is the loop in this example:
   6 ;
   7 ;int function0(int *a, int *b, int start, int end) {
   8 ;
   9 ;  for (int i=start; i<end; ++i) {
  10 ;    unsigned k = a[i];
  11 ;
  12 ;    if (a[i] > b[i])   <------ notice the IF inside the loop.
  13 ;      k = k * 5 + 3;
  14 ;
  15 ;    a[i] = k;  <---- K is a phi node that becomes vector-select.
  16 ;  }
  17 ;}
  18
  19 ;CHECK-LABEL: @function0(
  20 ;CHECK: load <4 x i32>
  21 ;CHECK: icmp sgt <4 x i32>
  22 ;CHECK: mul <4 x i32>
  23 ;CHECK: add <4 x i32>
  24 ;CHECK: select <4 x i1>
  25 ;CHECK: ret i32
  26 define i32 @function0(ptr nocapture %a, ptr nocapture %b, i32 %start, i32 %end) nounwind uwtable ssp {
  27 entry:
  28   %cmp16 = icmp slt i32 %start, %end
  29   br i1 %cmp16, label %for.body.lr.ph, label %for.end
  30
  31 for.body.lr.ph:
  32   %0 = sext i32 %start to i64
  33   br label %for.body
  34
  35 for.body:
  36   %indvars.iv = phi i64 [ %0, %for.body.lr.ph ], [ %indvars.iv.next, %if.end ]
  37   %arrayidx = getelementptr inbounds i32, ptr %a, i64 %indvars.iv
  38   %1 = load i32, ptr %arrayidx, align 4
  39   %arrayidx4 = getelementptr inbounds i32, ptr %b, i64 %indvars.iv
  40   %2 = load i32, ptr %arrayidx4, align 4
  41   %cmp5 = icmp sgt i32 %1, %2
  42   br i1 %cmp5, label %if.then, label %if.end
  43
  44 if.then:
  45   %mul = mul i32 %1, 5
  46   %add = add i32 %mul, 3
  47   br label %if.end
  48
  49 if.end:
  50   %k.0 = phi i32 [ %add, %if.then ], [ %1, %for.body ]
  51   store i32 %k.0, ptr %arrayidx, align 4
  52   %indvars.iv.next = add i64 %indvars.iv, 1
  53   %3 = trunc i64 %indvars.iv.next to i32
  54   %cmp = icmp slt i32 %3, %end
  55   br i1 %cmp, label %for.body, label %for.end
  56
  57 for.end:
  58   ret i32 undef
  59 }
  60
  61
  62
  63 ; int func(int *A, int n) {
  64 ;   unsigned sum = 0;
  65 ;   for (int i = 0; i < n; ++i)
  66 ;     if (A[i] > 30)
  67 ;       sum += A[i] + 2;
  68 ;
  69 ;   return sum;
  70 ; }
  71
  72 ;CHECK-LABEL: @reduction_func(
  73 ;CHECK: load <4 x i32>
  74 ;CHECK: icmp slt <4 x i32>
  75 ;CHECK: add <4 x i32>
  76 ;CHECK: select <4 x i1>
  77 ;CHECK: ret i32
  78 define i32 @reduction_func(ptr nocapture %A, i32 %n) nounwind uwtable readonly ssp {
  79 entry:
  80   %cmp10 = icmp sgt i32 %n, 0
  81   br i1 %cmp10, label %for.body, label %for.end
  82
  83 for.body:                                         ; preds = %entry, %for.inc
  84   %indvars.iv = phi i64 [ %indvars.iv.next, %for.inc ], [ 0, %entry ]
  85   %sum.011 = phi i32 [ %sum.1, %for.inc ], [ 0, %entry ]
  86   %arrayidx = getelementptr inbounds i32, ptr %A, i64 %indvars.iv
  87   %0 = load i32, ptr %arrayidx, align 4
  88   %cmp1 = icmp sgt i32 %0, 30
  89   br i1 %cmp1, label %if.then, label %for.inc
  90
  91 if.then:                                          ; preds = %for.body
  92   %add = add i32 %sum.011, 2
  93   %add4 = add i32 %add, %0
  94   br label %for.inc
  95
  96 for.inc:                                          ; preds = %for.body, %if.then
  97   %sum.1 = phi i32 [ %add4, %if.then ], [ %sum.011, %for.body ]
  98   %indvars.iv.next = add i64 %indvars.iv, 1
  99   %lftr.wideiv = trunc i64 %indvars.iv.next to i32
 100   %exitcond = icmp eq i32 %lftr.wideiv, %n
 101   br i1 %exitcond, label %for.end, label %for.body
 102
 103 for.end:                                          ; preds = %for.inc, %entry
 104   %sum.0.lcssa = phi i32 [ 0, %entry ], [ %sum.1, %for.inc ]
 105   ret i32 %sum.0.lcssa
 106 }
 107
 108 @a = common global [1 x ptr] zeroinitializer, align 8
 109 @c = common global ptr null, align 8
 110
 111 ; We use to if convert this loop. This is not safe because there is a trapping
 112 ; constant expression.
 113 ; PR16729
 114
 115 ; Handle PHI with single incoming value having a full mask.
 116 ; PR34523
 117
 118 ; CHECK-LABEL: PR34523
 119 ; CHECK: vector.body
 120
 121 define void @PR34523() {
 122 bb1:
 123   br label %bb2
 124
 125 bb2:                                             ; preds = %bb4, %bb1
 126   %i = phi i16 [ undef, %bb1 ], [ %_tmp2, %bb4 ]
 127   br label %bb3
 128
 129 bb3:                                             ; preds = %bb2
 130   %_tmp1 = phi ptr [ undef, %bb2 ]
 131   br label %bb4
 132
 133 bb4:                                             ; preds = %bb3
 134   %_tmp2 = add i16 %i, 1
 135   %_tmp3 = icmp slt i16 %_tmp2, 2
 136   br i1 %_tmp3, label %bb2, label %bb5
 137
 138 bb5:                                             ; preds = %bb4
 139   unreachable
 140 }