compiler-rt/cmake/Modules/CompilerRTCompile.cmake

   1 # On Windows, CMAKE_*_FLAGS are built for MSVC but we use the GCC clang.exe,
   2 # which uses completely different flags. Translate some common flag types, and
   3 # drop the rest.
   4 function(translate_msvc_cflags out_flags msvc_flags)
   5   # Insert an empty string in the list to simplify processing.
   6   set(msvc_flags ";${msvc_flags}")
   7
   8   # Canonicalize /flag to -flag.
   9   string(REPLACE ";/" ";-" msvc_flags "${msvc_flags}")
  10
  11   # Make space separated -D and -U flags into joined flags.
  12   string(REGEX REPLACE ";-\([DU]\);" ";-\\1" msvc_flags "${msvc_flags}")
  13
  14   set(clang_flags "")
  15   foreach(flag ${msvc_flags})
  16     if ("${flag}" MATCHES "^-[DU]")
  17       # Pass through basic command line macro definitions (-DNDEBUG).
  18       list(APPEND clang_flags "${flag}")
  19     elseif ("${flag}" MATCHES "^-O[2x]")
  20       # Canonicalize normal optimization flags to -O2.
  21       list(APPEND clang_flags "-O2")
  22     endif()
  23   endforeach()
  24   set(${out_flags} "${clang_flags}" PARENT_SCOPE)
  25 endfunction()
  26
  27 # Compile a sanitizer test with a freshly built clang
  28 # for a given architecture, adding the result to the object list.
  29 #  - obj_list: output list of objects, populated by path
  30 #              of a generated object file.
  31 #  - source:   source file of a test.
  32 #  - arch:     architecture to compile for.
  33 # sanitizer_test_compile(<obj_list> <source> <arch>
  34 #                        KIND <custom namespace>
  35 #                        COMPILE_DEPS <list of compile-time dependencies>
  36 #                        DEPS <list of dependencies>
  37 #                        CFLAGS <list of flags>
  38 # )
  39 function(sanitizer_test_compile obj_list source arch)
  40   cmake_parse_arguments(TEST
  41       "" "" "KIND;COMPILE_DEPS;DEPS;CFLAGS" ${ARGN})
  42   get_filename_component(basename ${source} NAME)
  43   set(output_obj
  44     "${CMAKE_CFG_RESOLVED_INTDIR}${obj_list}.${basename}.${arch}${TEST_KIND}.o")
  45
  46   # Write out architecture-specific flags into TARGET_CFLAGS variable.
  47   get_target_flags_for_arch(${arch} TARGET_CFLAGS)
  48   set(COMPILE_DEPS ${TEST_COMPILE_DEPS})
  49   if(NOT COMPILER_RT_STANDALONE_BUILD)
  50     list(APPEND COMPILE_DEPS ${TEST_DEPS})
  51   endif()
  52   clang_compile(${output_obj} ${source}
  53                 CFLAGS ${TEST_CFLAGS} ${TARGET_CFLAGS}
  54                 DEPS ${COMPILE_DEPS})
  55   list(APPEND ${obj_list} ${output_obj})
  56   set("${obj_list}" "${${obj_list}}" PARENT_SCOPE)
  57 endfunction()
  58
  59 # Compile a source into an object file with COMPILER_RT_TEST_COMPILER using
  60 # a provided compile flags and dependenices.
  61 # clang_compile(<object> <source>
  62 #               CFLAGS <list of compile flags>
  63 #               DEPS <list of dependencies>)
  64 function(clang_compile object_file source)
  65   cmake_parse_arguments(SOURCE "" "" "CFLAGS;DEPS" ${ARGN})
  66   get_filename_component(source_rpath ${source} REALPATH)
  67   if(NOT COMPILER_RT_STANDALONE_BUILD)
  68     list(APPEND SOURCE_DEPS clang compiler-rt-headers)
  69   endif()
  70   if (TARGET CompilerRTUnitTestCheckCxx)
  71     list(APPEND SOURCE_DEPS CompilerRTUnitTestCheckCxx)
  72   endif()
  73   if(COMPILER_RT_STANDALONE_BUILD)
  74     # Only add global flags in standalone build.
  75     string(REGEX MATCH "[.](cc|cpp)$" is_cxx ${source_rpath})
  76     if(is_cxx)
  77       string(REPLACE " " ";" global_flags "${CMAKE_CXX_FLAGS}")
  78     else()
  79       string(REPLACE " " ";" global_flags "${CMAKE_C_FLAGS}")
  80     endif()
  81
  82     if (MSVC)
  83       translate_msvc_cflags(global_flags "${global_flags}")
  84     endif()
  85
  86     if (APPLE)
  87       set(global_flags ${OSX_SYSROOT_FLAG} ${global_flags})
  88     endif()
  89
  90     # Ignore unknown warnings. CMAKE_CXX_FLAGS may contain GCC-specific options
  91     # which are not supported by Clang.
  92     list(APPEND global_flags -Wno-unknown-warning-option)
  93     set(compile_flags ${global_flags} ${SOURCE_CFLAGS})
  94   else()
  95     set(compile_flags ${SOURCE_CFLAGS})
  96   endif()
  97
  98   string(REGEX MATCH "[.](m|mm)$" is_objc ${source_rpath})
  99   if (is_objc)
 100     list(APPEND compile_flags "-ObjC")
 101   endif()
 102
 103   add_custom_command(
 104     OUTPUT ${object_file}
 105     COMMAND ${COMPILER_RT_TEST_COMPILER} ${compile_flags} -c
 106             -o "${object_file}"
 107             ${source_rpath}
 108     MAIN_DEPENDENCY ${source}
 109     DEPENDS ${SOURCE_DEPS}
 110     COMMAND_EXPAND_LISTS)
 111 endfunction()
 112
 113 # On Darwin, there are no system-wide C++ headers and the just-built clang is
 114 # therefore not able to compile C++ files unless they are copied/symlinked into
 115 # ${LLVM_BINARY_DIR}/include/c++
 116 # The just-built clang is used to build compiler-rt unit tests. Let's detect
 117 # this before we try to build the tests and print out a suggestion how to fix
 118 # it.
 119 # On other platforms, this is currently not an issue.
 120 macro(clang_compiler_add_cxx_check)
 121   if (APPLE)
 122     set(CMD
 123       "echo '#include <iostream>' | ${COMPILER_RT_TEST_COMPILER} ${OSX_SYSROOT_FLAG} -E -x c++ - > /dev/null"
 124       "if [ $? != 0 ] "
 125       "  then echo"
 126       "  echo 'Your just-built clang cannot find C++ headers, which are needed to build and run compiler-rt tests.'"
 127       "  echo 'You should copy or symlink your system C++ headers into ${LLVM_BINARY_DIR}/include/c++'"
 128       "  if [ -d $(dirname $(dirname $(xcrun -f clang)))/include/c++ ]"
 129       "    then echo 'e.g. with:'"
 130       "    echo '  cp -r' $(dirname $(dirname $(xcrun -f clang)))/include/c++ '${LLVM_BINARY_DIR}/include/'"
 131       "  elif [ -d $(dirname $(dirname $(xcrun -f clang)))/lib/c++ ]"
 132       "    then echo 'e.g. with:'"
 133       "    echo '  cp -r' $(dirname $(dirname $(xcrun -f clang)))/lib/c++ '${LLVM_BINARY_DIR}/include/'"
 134       "  fi"
 135       "  echo 'This can also be fixed by checking out the libcxx project from llvm.org and installing the headers'"
 136       "  echo 'into your build directory:'"
 137       "  echo '  cd ${LLVM_MAIN_SRC_DIR}/projects && svn co http://llvm.org/svn/llvm-project/libcxx/trunk libcxx'"
 138       "  echo '  cd ${LLVM_BINARY_DIR} && make -C ${LLVM_MAIN_SRC_DIR}/projects/libcxx installheaders HEADER_DIR=${LLVM_BINARY_DIR}/include'"
 139       "  echo"
 140       "  false"
 141       "fi"
 142       )
 143     add_custom_target(CompilerRTUnitTestCheckCxx
 144       COMMAND bash -c "${CMD}"
 145       COMMENT "Checking that just-built clang can find C++ headers..."
 146       VERBATIM)
 147     if (NOT COMPILER_RT_STANDALONE_BUILD AND NOT LLVM_RUNTIMES_BUILD)
 148       ADD_DEPENDENCIES(CompilerRTUnitTestCheckCxx clang)
 149     endif()
 150   endif()
 151 endmacro()