compiler-rt/lib/builtins/arm/divmodsi4.S

   1 //===-- divmodsi4.S - 32-bit signed integer divide and modulus ------------===//
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6 //
   7 //===----------------------------------------------------------------------===//
   8 //
   9 // This file implements the __divmodsi4 (32-bit signed integer divide and
  10 // modulus) function for the ARM architecture.  A naive digit-by-digit
  11 // computation is employed for simplicity.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 #include "../assembly.h"
  16
  17 #define ESTABLISH_FRAME    \
  18     push   {r4-r7, lr}   ;\
  19     add     r7,     sp, #12
  20 #define CLEAR_FRAME_AND_RETURN \
  21     pop    {r4-r7, pc}
  22
  23         .syntax unified
  24         .text
  25   DEFINE_CODE_STATE
  26
  27 @ int __divmodsi4(int divident, int divisor, int *remainder)
  28 @   Calculate the quotient and remainder of the (signed) division.  The return
  29 @   value is the quotient, the remainder is placed in the variable.
  30
  31         .p2align 3
  32 DEFINE_COMPILERRT_FUNCTION(__divmodsi4)
  33 #if __ARM_ARCH_EXT_IDIV__
  34         tst     r1, r1
  35         beq     LOCAL_LABEL(divzero)
  36         mov     r3, r0
  37         sdiv    r0, r3, r1
  38         mls     r1, r0, r1, r3
  39         str     r1, [r2]
  40         bx      lr
  41 LOCAL_LABEL(divzero):
  42         mov     r0, #0
  43         bx      lr
  44 #else
  45     ESTABLISH_FRAME
  46 //  Set aside the sign of the quotient and modulus, and the address for the
  47 //  modulus.
  48     eor     r4,     r0, r1
  49     mov     r5,     r0
  50     mov     r6,     r2
  51 //  Take the absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
  52     eor     ip,     r0, r0, asr #31
  53     eor     lr,     r1, r1, asr #31
  54     sub     r0,     ip, r0, asr #31
  55     sub     r1,     lr, r1, asr #31
  56 //  Unsigned divmod:
  57     bl      SYMBOL_NAME(__udivmodsi4)
  58 //  Apply the sign of quotient and modulus
  59     ldr     r1,    [r6]
  60     eor     r0,     r0, r4, asr #31
  61     eor     r1,     r1, r5, asr #31
  62     sub     r0,     r0, r4, asr #31
  63     sub     r1,     r1, r5, asr #31
  64     str     r1,    [r6]
  65     CLEAR_FRAME_AND_RETURN
  66 #endif
  67 END_COMPILERRT_FUNCTION(__divmodsi4)
  68
  69 NO_EXEC_STACK_DIRECTIVE
  70