compiler-rt/lib/builtins/i386/lshrdi3.S

   1 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   2 // See https://llvm.org/LICENSE.txt for license information.
   3 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   4
   5 #include "../assembly.h"
   6
   7 // di_int __lshrdi3(di_int input, int count);
   8
   9 // This routine has some extra memory traffic, loading the 64-bit input via two
  10 // 32-bit loads, then immediately storing it back to the stack via a single 64-bit
  11 // store.  This is to avoid a write-small, read-large stall.
  12 // However, if callers of this routine can be safely assumed to store the argument
  13 // via a 64-bt store, this is unnecessary memory traffic, and should be avoided.
  14 // It can be turned off by defining the TRUST_CALLERS_USE_64_BIT_STORES macro.
  15
  16 #ifdef __i386__
  17 #ifdef __SSE2__
  18
  19 .text
  20 .balign 4
  21 DEFINE_COMPILERRT_FUNCTION(__lshrdi3)
  22         movd      12(%esp),             %xmm2   // Load count
  23 #ifndef TRUST_CALLERS_USE_64_BIT_STORES
  24         movd       4(%esp),             %xmm0
  25         movd       8(%esp),             %xmm1
  26         punpckldq       %xmm1,          %xmm0   // Load input
  27 #else
  28         movq       4(%esp),             %xmm0   // Load input
  29 #endif
  30         psrlq           %xmm2,          %xmm0   // shift input by count
  31         movd            %xmm0,          %eax
  32         psrlq           $32,            %xmm0
  33         movd            %xmm0,          %edx
  34         ret
  35 END_COMPILERRT_FUNCTION(__lshrdi3)
  36
  37 #else // Use GPRs instead of SSE2 instructions, if they aren't available.
  38
  39 .text
  40 .balign 4
  41 DEFINE_COMPILERRT_FUNCTION(__lshrdi3)
  42         movl      12(%esp),             %ecx    // Load count
  43         movl       8(%esp),             %edx    // Load high
  44         movl       4(%esp),             %eax    // Load low
  45
  46         testl           $0x20,          %ecx    // If count >= 32
  47         jnz                     1f                                      //    goto 1
  48
  49         shrdl           %cl, %edx,      %eax    // right shift low by count
  50         shrl            %cl,            %edx    // right shift high by count
  51         ret
  52
  53 1:      movl            %edx,           %eax    // Move high to low
  54         xorl            %edx,           %edx    // clear high
  55         shrl            %cl,            %eax    // shift low by count - 32
  56         ret
  57 END_COMPILERRT_FUNCTION(__lshrdi3)
  58
  59 #endif // __SSE2__
  60 #endif // __i386__
  61
  62 NO_EXEC_STACK_DIRECTIVE
  63