libcxxabi/src/CMakeLists.txt

   1 # Get sources
   2 set(LIBCXXABI_SOURCES
   3   # C++ABI files
   4   cxa_aux_runtime.cpp
   5   cxa_default_handlers.cpp
   6   cxa_demangle.cpp
   7   cxa_exception_storage.cpp
   8   cxa_guard.cpp
   9   cxa_handlers.cpp
  10   cxa_vector.cpp
  11   cxa_virtual.cpp
  12   # C++ STL files
  13   stdlib_exception.cpp
  14   stdlib_stdexcept.cpp
  15   stdlib_typeinfo.cpp
  16   # Internal files
  17   abort_message.cpp
  18   fallback_malloc.cpp
  19   private_typeinfo.cpp
  20 )
  21
  22 if (LIBCXXABI_ENABLE_NEW_DELETE_DEFINITIONS)
  23   list(APPEND LIBCXXABI_SOURCES
  24     stdlib_new_delete.cpp
  25   )
  26 endif()
  27
  28 if (LIBCXXABI_ENABLE_EXCEPTIONS)
  29   list(APPEND LIBCXXABI_SOURCES
  30     cxa_exception.cpp
  31     cxa_personality.cpp
  32   )
  33 else()
  34   list(APPEND LIBCXXABI_SOURCES
  35     cxa_noexception.cpp
  36   )
  37 endif()
  38
  39 if (LIBCXXABI_ENABLE_THREADS AND (UNIX OR FUCHSIA) AND NOT (APPLE OR CYGWIN)
  40     AND NOT (${CMAKE_SYSTEM_NAME} MATCHES "AIX"))
  41   list(APPEND LIBCXXABI_SOURCES
  42     cxa_thread_atexit.cpp
  43   )
  44 endif()
  45
  46 set(LIBCXXABI_HEADERS
  47   ../include/cxxabi.h
  48 )
  49
  50 # Add all the headers to the project for IDEs.
  51 if (MSVC_IDE OR XCODE)
  52   # Force them all into the headers dir on MSVC, otherwise they end up at
  53   # project scope because they don't have extensions.
  54   if (MSVC_IDE)
  55     source_group("Header Files" FILES ${LIBCXXABI_HEADERS})
  56   endif()
  57 endif()
  58
  59 # Some files depend on libc++ internals.
  60 include_directories("${LIBCXXABI_LIBCXX_PATH}/src")
  61
  62 if (LIBCXXABI_HAS_CXA_THREAD_ATEXIT_IMPL)
  63   add_definitions(-DHAVE___CXA_THREAD_ATEXIT_IMPL)
  64 endif()
  65
  66 if (LIBCXXABI_ENABLE_FORGIVING_DYNAMIC_CAST)
  67   add_definitions(-D_LIBCXXABI_FORGIVING_DYNAMIC_CAST)
  68 endif()
  69
  70 if (NOT APPLE) # On Apple platforms, we always use -nostdlib++ so we don't need to re-add other libraries
  71   if (LIBCXXABI_ENABLE_THREADS)
  72     add_library_flags_if(LIBCXXABI_HAS_PTHREAD_LIB pthread)
  73   endif()
  74
  75   add_library_flags_if(LIBCXXABI_HAS_C_LIB c)
  76 endif()
  77
  78 if (NOT LIBCXXABI_USE_COMPILER_RT)
  79   add_library_flags_if(LIBCXXABI_HAS_GCC_LIB gcc)
  80 endif()
  81 if (NOT LIBCXXABI_USE_LLVM_UNWINDER)
  82   add_library_flags_if(LIBCXXABI_HAS_GCC_S_LIB gcc_s)
  83 endif()
  84
  85 if (MINGW)
  86   # MINGW_LIBRARIES is defined in config-ix.cmake
  87   list(APPEND LIBCXXABI_LIBRARIES ${MINGW_LIBRARIES})
  88 endif()
  89 if (ANDROID AND ANDROID_PLATFORM_LEVEL LESS 21)
  90   list(APPEND LIBCXXABI_LIBRARIES android_support)
  91 endif()
  92
  93 # Setup flags.
  94 if (CXX_SUPPORTS_NOSTDLIBXX_FLAG)
  95   add_link_flags_if_supported(-nostdlib++)
  96 else()
  97   add_link_flags_if_supported(-nodefaultlibs)
  98 endif()
  99
 100 if (CXX_SUPPORTS_UNWINDLIB_EQ_NONE_FLAG AND LIBCXXABI_USE_LLVM_UNWINDER)
 101   # If we're linking directly against the libunwind that we're building
 102   # in the same invocation, don't try to link in the toolchain's
 103   # default libunwind (which may be missing still).
 104   add_link_flags_if_supported(--unwindlib=none)
 105 endif()
 106
 107 if ( APPLE )
 108   if (LLVM_USE_SANITIZER)
 109     if (("${LLVM_USE_SANITIZER}" STREQUAL "Address") OR
 110         ("${LLVM_USE_SANITIZER}" STREQUAL "Address;Undefined") OR
 111         ("${LLVM_USE_SANITIZER}" STREQUAL "Undefined;Address"))
 112       set(LIBFILE "libclang_rt.asan_osx_dynamic.dylib")
 113     elseif("${LLVM_USE_SANITIZER}" STREQUAL "Undefined")
 114       set(LIBFILE "libclang_rt.ubsan_osx_dynamic.dylib")
 115     elseif("${LLVM_USE_SANITIZER}" STREQUAL "Thread")
 116       set(LIBFILE "libclang_rt.tsan_osx_dynamic.dylib")
 117     else()
 118       message(WARNING "LLVM_USE_SANITIZER=${LLVM_USE_SANITIZER} is not supported on OS X")
 119     endif()
 120     if (LIBFILE)
 121       find_compiler_rt_library(builtins LIBCXXABI_BUILTINS_LIBRARY)
 122       get_filename_component(LIBDIR "${LIBCXXABI_BUILTINS_LIBRARY}" DIRECTORY)
 123       if (NOT IS_DIRECTORY "${LIBDIR}")
 124         message(FATAL_ERROR "Cannot find compiler-rt directory on OS X required for LLVM_USE_SANITIZER")
 125       endif()
 126       set(LIBCXXABI_SANITIZER_LIBRARY "${LIBDIR}/${LIBFILE}")
 127       set(LIBCXXABI_SANITIZER_LIBRARY "${LIBCXXABI_SANITIZER_LIBRARY}" PARENT_SCOPE)
 128       message(STATUS "Manually linking compiler-rt library: ${LIBCXXABI_SANITIZER_LIBRARY}")
 129       add_library_flags("${LIBCXXABI_SANITIZER_LIBRARY}")
 130       add_link_flags("-Wl,-rpath,${LIBDIR}")
 131     endif()
 132   endif()
 133
 134   # Make sure we link in CrashReporterClient if we find it -- it's used by
 135   # abort() on Apple platforms when building the system dylib.
 136   find_library(CrashReporterClient NAMES libCrashReporterClient.a
 137                                    PATHS "${CMAKE_OSX_SYSROOT}/usr/local/lib")
 138   if (CrashReporterClient)
 139     message(STATUS "Linking with CrashReporterClient at ${CrashReporterClient}")
 140     add_library_flags("${CrashReporterClient}")
 141   else()
 142     message(STATUS "Could not find CrashReporterClient, not linking against it")
 143   endif()
 144 endif()
 145
 146 split_list(LIBCXXABI_COMPILE_FLAGS)
 147 split_list(LIBCXXABI_LINK_FLAGS)
 148
 149 # FIXME: libc++abi.so will not link when modules are enabled because it depends
 150 # on symbols defined in libc++.so which has not yet been built.
 151 if (LLVM_ENABLE_MODULES)
 152   string(REPLACE "-Wl,-z,defs" "" CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS}")
 153 endif()
 154
 155 include(WarningFlags)
 156
 157 # Build the shared library.
 158 add_library(cxxabi_shared_objects OBJECT EXCLUDE_FROM_ALL ${LIBCXXABI_SOURCES} ${LIBCXXABI_HEADERS})
 159 cxx_add_warning_flags(cxxabi_shared_objects ${LIBCXXABI_ENABLE_WERROR} ${LIBCXXABI_ENABLE_PEDANTIC})
 160 if (LIBCXXABI_USE_LLVM_UNWINDER)
 161   if (LIBCXXABI_STATICALLY_LINK_UNWINDER_IN_SHARED_LIBRARY OR
 162       (DEFINED LIBUNWIND_ENABLE_SHARED AND NOT LIBUNWIND_ENABLE_SHARED))
 163     target_link_libraries(cxxabi_shared_objects PUBLIC unwind_shared_objects) # propagate usage requirements
 164     target_sources(cxxabi_shared_objects PUBLIC $<TARGET_OBJECTS:unwind_shared_objects>)
 165   else()
 166     target_link_libraries(cxxabi_shared_objects PUBLIC unwind_shared)
 167   endif()
 168 endif()
 169 target_link_libraries(cxxabi_shared_objects PRIVATE cxx-headers ${LIBCXXABI_BUILTINS_LIBRARY} ${LIBCXXABI_LIBRARIES})
 170 target_link_libraries(cxxabi_shared_objects PUBLIC cxxabi-headers)
 171 set_target_properties(cxxabi_shared_objects
 172   PROPERTIES
 173     CXX_EXTENSIONS OFF
 174     CXX_STANDARD 20
 175     CXX_STANDARD_REQUIRED OFF
 176     COMPILE_FLAGS "${LIBCXXABI_COMPILE_FLAGS}"
 177     DEFINE_SYMBOL ""
 178 )
 179 if (CMAKE_POSITION_INDEPENDENT_CODE OR NOT DEFINED CMAKE_POSITION_INDEPENDENT_CODE)
 180   set_target_properties(cxxabi_shared_objects PROPERTIES POSITION_INDEPENDENT_CODE ON) # must set manually because it's an object library
 181 endif()
 182
 183 if (LIBCXXABI_ENABLE_SHARED)
 184   add_library(cxxabi_shared SHARED)
 185   set_target_properties(cxxabi_shared
 186     PROPERTIES
 187       LINK_FLAGS "${LIBCXXABI_LINK_FLAGS}"
 188       OUTPUT_NAME "${LIBCXXABI_SHARED_OUTPUT_NAME}"
 189       SOVERSION "1"
 190       VERSION "${LIBCXXABI_LIBRARY_VERSION}"
 191   )
 192
 193   if (ZOS)
 194     add_custom_command(TARGET cxxabi_shared POST_BUILD
 195       COMMAND
 196         ${LIBCXXABI_LIBCXX_PATH}/utils/zos_rename_dll_side_deck.sh
 197         $<TARGET_LINKER_FILE_NAME:cxxabi_shared> $<TARGET_FILE_NAME:cxxabi_shared> "${LIBCXXABI_DLL_NAME}"
 198       COMMENT "Rename dll name inside the side deck file"
 199       WORKING_DIRECTORY $<TARGET_FILE_DIR:cxxabi_shared>
 200     )
 201   endif ()
 202
 203   target_link_libraries(cxxabi_shared
 204     PUBLIC cxxabi_shared_objects
 205     PRIVATE ${LIBCXXABI_LIBRARIES})
 206
 207   list(APPEND LIBCXXABI_BUILD_TARGETS "cxxabi_shared")
 208   if (LIBCXXABI_INSTALL_SHARED_LIBRARY)
 209     list(APPEND LIBCXXABI_INSTALL_TARGETS "cxxabi_shared")
 210   endif()
 211
 212   add_library(cxxabi-reexports INTERFACE)
 213
 214   # -exported_symbols_list is only available on Apple platforms
 215   if (APPLE)
 216     function(export_symbols file)
 217       target_link_libraries(cxxabi_shared PRIVATE "-Wl,-exported_symbols_list,${file}")
 218     endfunction()
 219     function(reexport_symbols file)
 220       export_symbols("${file}")
 221       target_link_libraries(cxxabi-reexports INTERFACE "-Wl,-reexported_symbols_list,${file}")
 222     endfunction()
 223
 224     export_symbols("${CMAKE_CURRENT_SOURCE_DIR}/../lib/itanium-base.exp")
 225
 226     if (LIBCXXABI_ENABLE_NEW_DELETE_DEFINITIONS)
 227       reexport_symbols("${CMAKE_CURRENT_SOURCE_DIR}/../lib/new-delete.exp")
 228     endif()
 229
 230     if (LIBCXXABI_ENABLE_EXCEPTIONS)
 231       reexport_symbols("${CMAKE_CURRENT_SOURCE_DIR}/../lib/exceptions.exp")
 232
 233       if ("${CMAKE_OSX_ARCHITECTURES}" MATCHES "^(armv6|armv7|armv7s)$")
 234         reexport_symbols("${CMAKE_CURRENT_SOURCE_DIR}/../lib/personality-sjlj.exp")
 235       else()
 236         reexport_symbols("${CMAKE_CURRENT_SOURCE_DIR}/../lib/personality-v0.exp")
 237       endif()
 238     endif()
 239   endif()
 240 endif()
 241
 242 # Build the static library.
 243 add_library(cxxabi_static_objects OBJECT EXCLUDE_FROM_ALL ${LIBCXXABI_SOURCES} ${LIBCXXABI_HEADERS})
 244 cxx_add_warning_flags(cxxabi_static_objects ${LIBCXXABI_ENABLE_WERROR} ${LIBCXXABI_ENABLE_PEDANTIC})
 245 if (LIBCXXABI_USE_LLVM_UNWINDER AND LIBCXXABI_STATICALLY_LINK_UNWINDER_IN_STATIC_LIBRARY)
 246   target_link_libraries(cxxabi_static_objects PUBLIC unwind_static_objects) # propagate usage requirements
 247   target_sources(cxxabi_static_objects PUBLIC $<TARGET_OBJECTS:unwind_static_objects>)
 248 endif()
 249 target_link_libraries(cxxabi_static_objects PRIVATE cxx-headers ${LIBCXXABI_STATIC_LIBRARIES} ${LIBCXXABI_LIBRARIES})
 250 target_link_libraries(cxxabi_static_objects PUBLIC cxxabi-headers)
 251 set_target_properties(cxxabi_static_objects
 252   PROPERTIES
 253     CXX_EXTENSIONS OFF
 254     CXX_STANDARD 20
 255     CXX_STANDARD_REQUIRED OFF
 256     COMPILE_FLAGS "${LIBCXXABI_COMPILE_FLAGS}"
 257 )
 258
 259 if(LIBCXXABI_HERMETIC_STATIC_LIBRARY)
 260   target_add_compile_flags_if_supported(cxxabi_static_objects PRIVATE -fvisibility=hidden)
 261   # If the hermetic library doesn't define the operator new/delete functions
 262   # then its code shouldn't declare them with hidden visibility.  They might
 263   # actually be provided by a shared library at link time.
 264   if (LIBCXXABI_ENABLE_NEW_DELETE_DEFINITIONS)
 265     target_add_compile_flags_if_supported(cxxabi_static_objects PRIVATE -fvisibility-global-new-delete-hidden)
 266   endif()
 267   # _LIBCPP_DISABLE_VISIBILITY_ANNOTATIONS can be defined in libcxx's
 268   # __config_site too. Define it in the same way here, to avoid redefinition
 269   # conflicts.
 270   target_compile_definitions(cxxabi_static_objects
 271     PRIVATE
 272       _LIBCXXABI_DISABLE_VISIBILITY_ANNOTATIONS
 273       _LIBCPP_DISABLE_VISIBILITY_ANNOTATIONS=)
 274 endif()
 275
 276 if (LIBCXXABI_ENABLE_STATIC)
 277   add_library(cxxabi_static STATIC)
 278   if (LIBCXXABI_USE_LLVM_UNWINDER AND NOT LIBCXXABI_STATICALLY_LINK_UNWINDER_IN_STATIC_LIBRARY)
 279     target_link_libraries(cxxabi_static PUBLIC unwind_static)
 280   endif()
 281   set_target_properties(cxxabi_static
 282     PROPERTIES
 283       LINK_FLAGS "${LIBCXXABI_LINK_FLAGS}"
 284       OUTPUT_NAME "${LIBCXXABI_STATIC_OUTPUT_NAME}"
 285     )
 286   target_link_libraries(cxxabi_static
 287     PUBLIC cxxabi_static_objects
 288     PRIVATE ${LIBCXXABI_STATIC_LIBRARIES} ${LIBCXXABI_LIBRARIES})
 289
 290   list(APPEND LIBCXXABI_BUILD_TARGETS "cxxabi_static")
 291   if (LIBCXXABI_INSTALL_STATIC_LIBRARY)
 292     list(APPEND LIBCXXABI_INSTALL_TARGETS "cxxabi_static")
 293   endif()
 294 endif()
 295
 296 # Add a meta-target for both libraries.
 297 add_custom_target(cxxabi DEPENDS ${LIBCXXABI_BUILD_TARGETS})
 298
 299 if (LIBCXXABI_INSTALL_LIBRARY)
 300   install(TARGETS ${LIBCXXABI_INSTALL_TARGETS}
 301     LIBRARY DESTINATION ${LIBCXXABI_INSTALL_LIBRARY_DIR} COMPONENT cxxabi
 302     ARCHIVE DESTINATION ${LIBCXXABI_INSTALL_LIBRARY_DIR} COMPONENT cxxabi
 303     RUNTIME DESTINATION ${LIBCXXABI_INSTALL_RUNTIME_DIR} COMPONENT cxxabi
 304     )
 305 endif()
 306
 307 if (NOT CMAKE_CONFIGURATION_TYPES AND LIBCXXABI_INSTALL_LIBRARY)
 308   add_custom_target(install-cxxabi
 309     DEPENDS cxxabi install-cxxabi-headers
 310     COMMAND "${CMAKE_COMMAND}"
 311             -DCMAKE_INSTALL_COMPONENT=cxxabi
 312             -P "${LIBCXXABI_BINARY_DIR}/cmake_install.cmake")
 313   add_custom_target(install-cxxabi-stripped
 314     DEPENDS cxxabi
 315     COMMAND "${CMAKE_COMMAND}"
 316             -DCMAKE_INSTALL_COMPONENT=cxxabi
 317             -DCMAKE_INSTALL_DO_STRIP=1
 318             -P "${LIBCXXABI_BINARY_DIR}/cmake_install.cmake")
 319 endif()