llvm/CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.20.0)
   4
   5 set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
   6 include(${LLVM_COMMON_CMAKE_UTILS}/Modules/CMakePolicy.cmake
   7   NO_POLICY_SCOPE)
   8
   9 # Builds with custom install names and installation rpath setups may not work
  10 # in the build tree. Allow these cases to use CMake's default build tree
  11 # behavior by setting `LLVM_NO_INSTALL_NAME_DIR_FOR_BUILD_TREE` to do this.
  12 option(LLVM_NO_INSTALL_NAME_DIR_FOR_BUILD_TREE "If set, use CMake's default build tree install name directory logic (Darwin only)" OFF)
  13 mark_as_advanced(LLVM_NO_INSTALL_NAME_DIR_FOR_BUILD_TREE)
  14 if(NOT LLVM_NO_INSTALL_NAME_DIR_FOR_BUILD_TREE)
  15   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 18)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX git)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if(NOT DEFINED LLVM_SHLIB_SYMBOL_VERSION)
  37   # "Symbol version prefix for libLLVM.so"
  38   set(LLVM_SHLIB_SYMBOL_VERSION "LLVM_${LLVM_VERSION_MAJOR}")
  39 endif()
  40
  41 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (MSVC_TOOLSET_VERSION LESS 142) AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  42   message(WARNING "Visual Studio generators use the x86 host compiler by "
  43                   "default, even for 64-bit targets. This can result in linker "
  44                   "instability and out of memory errors. To use the 64-bit "
  45                   "host compiler, pass -Thost=x64 on the CMake command line.")
  46 endif()
  47
  48 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
  49   # Some CMake features like object libraries get confused if you don't
  50   # explicitly specify an architecture setting with the Xcode generator.
  51   set(CMAKE_OSX_ARCHITECTURES "x86_64")
  52 endif()
  53
  54 project(LLVM
  55   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  56   LANGUAGES C CXX ASM)
  57
  58 if (NOT DEFINED CMAKE_INSTALL_LIBDIR AND DEFINED LLVM_LIBDIR_SUFFIX)
  59   # Must go before `include(GNUInstallDirs)`.
  60   set(CMAKE_INSTALL_LIBDIR "lib${LLVM_LIBDIR_SUFFIX}")
  61 endif()
  62
  63 # Must go after `DEFINED LLVM_LIBDIR_SUFFIX` check.
  64 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  65
  66 # Must go after `project(..)`.
  67 include(GNUInstallDirs)
  68
  69 # This C++ standard is required to build LLVM.
  70 set(LLVM_REQUIRED_CXX_STANDARD 17)
  71
  72 # If we find that the cache contains CMAKE_CXX_STANDARD it means that it's a old CMakeCache.txt
  73 # and we can just inform the user and then reset it.
  74 if($CACHE{CMAKE_CXX_STANDARD} AND $CACHE{CMAKE_CXX_STANDARD} LESS ${LLVM_REQUIRED_CXX_STANDARD})
  75   message(WARNING "Resetting cache value for CMAKE_CXX_STANDARD to ${LLVM_REQUIRED_CXX_STANDARD}")
  76   unset(CMAKE_CXX_STANDARD CACHE)
  77 endif()
  78
  79 # if CMAKE_CXX_STANDARD is still set after the cache unset above it means that the user requested it
  80 # and we allow it to be set to something newer than the required standard but otherwise we fail.
  81 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD LESS ${LLVM_REQUIRED_CXX_STANDARD})
  82   message(FATAL_ERROR "Requested CMAKE_CXX_STANDARD=${CMAKE_CXX_STANDARD} which is less than the required ${LLVM_REQUIRED_CXX_STANDARD}.")
  83 endif()
  84
  85 set(CMAKE_CXX_STANDARD ${LLVM_REQUIRED_CXX_STANDARD} CACHE STRING "C++ standard to conform to")
  86 set(CMAKE_CXX_STANDARD_REQUIRED YES)
  87
  88 if (CYGWIN)
  89   # Cygwin is a bit stricter and lack things like 'strdup', 'stricmp', etc in
  90   # c++xx mode.
  91   set(CMAKE_CXX_EXTENSIONS YES)
  92 else()
  93   set(CMAKE_CXX_EXTENSIONS NO)
  94 endif()
  95
  96 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  97   message(FATAL_ERROR "
  98 No build type selected. You need to pass -DCMAKE_BUILD_TYPE=<type> in order to configure LLVM.
  99 Available options are:
 100   * -DCMAKE_BUILD_TYPE=Release - For an optimized build with no assertions or debug info.
 101   * -DCMAKE_BUILD_TYPE=Debug - For an unoptimized build with assertions and debug info.
 102   * -DCMAKE_BUILD_TYPE=RelWithDebInfo - For an optimized build with no assertions but with debug info.
 103   * -DCMAKE_BUILD_TYPE=MinSizeRel - For a build optimized for size instead of speed.
 104 Learn more about these options in our documentation at https://llvm.org/docs/CMake.html#cmake-build-type
 105 ")
 106 endif()
 107
 108 # Set default build type for cmake's try_compile module.
 109 # CMake 3.17 or newer sets CMAKE_DEFAULT_BUILD_TYPE to one of the
 110 # items from CMAKE_CONFIGURATION_TYPES. Logic below can be further
 111 # simplified once LLVM's minimum CMake version is updated to 3.17.
 112 if(CMAKE_DEFAULT_BUILD_TYPE)
 113   set(CMAKE_TRY_COMPILE_CONFIGURATION ${CMAKE_DEFAULT_BUILD_TYPE})
 114 else()
 115   if(CMAKE_CONFIGURATION_TYPES)
 116     list(GET CMAKE_CONFIGURATION_TYPES 0 CMAKE_TRY_COMPILE_CONFIGURATION)
 117   elseif(CMAKE_BUILD_TYPE)
 118     set(CMAKE_TRY_COMPILE_CONFIGURATION ${CMAKE_BUILD_TYPE})
 119   endif()
 120 endif()
 121
 122 # Side-by-side subprojects layout: automatically set the
 123 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 124 # This allows an easy way of setting up a build directory for llvm and another
 125 # one for llvm+clang+... using the same sources.
 126 set(LLVM_ALL_PROJECTS "bolt;clang;clang-tools-extra;compiler-rt;cross-project-tests;libc;libclc;lld;lldb;mlir;openmp;polly;pstl")
 127 # The flang project is not yet part of "all" projects (see C++ requirements)
 128 set(LLVM_EXTRA_PROJECTS "flang")
 129 # List of all known projects in the mono repo
 130 set(LLVM_KNOWN_PROJECTS "${LLVM_ALL_PROJECTS};${LLVM_EXTRA_PROJECTS}")
 131 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 132     "Semicolon-separated list of projects to build (${LLVM_KNOWN_PROJECTS}), or \"all\".")
 133 # Make sure expansion happens first to not handle "all" in rest of the checks.
 134 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 135   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 136 endif()
 137 foreach(proj ${LLVM_ENABLE_PROJECTS})
 138   if (NOT proj STREQUAL "llvm" AND NOT "${proj}" IN_LIST LLVM_KNOWN_PROJECTS)
 139      MESSAGE(FATAL_ERROR "${proj} isn't a known project: ${LLVM_KNOWN_PROJECTS}. Did you mean to enable it as a runtime in LLVM_ENABLE_RUNTIMES?")
 140   endif()
 141 endforeach()
 142
 143 if ("flang" IN_LIST LLVM_ENABLE_PROJECTS)
 144   if (NOT "mlir" IN_LIST LLVM_ENABLE_PROJECTS)
 145     message(STATUS "Enabling MLIR as a dependency to flang")
 146     list(APPEND LLVM_ENABLE_PROJECTS "mlir")
 147   endif()
 148
 149   if (NOT "clang" IN_LIST LLVM_ENABLE_PROJECTS)
 150     message(FATAL_ERROR "Clang is not enabled, but is required for the Flang driver")
 151   endif()
 152 endif()
 153
 154 # Select the runtimes to build
 155 #
 156 # As we migrate runtimes to using the bootstrapping build, the set of default runtimes
 157 # should grow as we remove those runtimes from LLVM_ENABLE_PROJECTS above.
 158 set(LLVM_DEFAULT_RUNTIMES "libcxx;libcxxabi;libunwind")
 159 set(LLVM_SUPPORTED_RUNTIMES "libc;libunwind;libcxxabi;pstl;libcxx;compiler-rt;openmp;llvm-libgcc")
 160 set(LLVM_ENABLE_RUNTIMES "" CACHE STRING
 161   "Semicolon-separated list of runtimes to build, or \"all\" (${LLVM_DEFAULT_RUNTIMES}). Supported runtimes are ${LLVM_SUPPORTED_RUNTIMES}.")
 162 if(LLVM_ENABLE_RUNTIMES STREQUAL "all")
 163   set(LLVM_ENABLE_RUNTIMES ${LLVM_DEFAULT_RUNTIMES})
 164 endif()
 165 foreach(proj IN LISTS LLVM_ENABLE_RUNTIMES)
 166   if (NOT "${proj}" IN_LIST LLVM_SUPPORTED_RUNTIMES)
 167     message(FATAL_ERROR "Runtime \"${proj}\" is not a supported runtime. Supported runtimes are: ${LLVM_SUPPORTED_RUNTIMES}")
 168   endif()
 169 endforeach()
 170
 171 if ("libc" IN_LIST LLVM_ENABLE_RUNTIMES)
 172   # To build the libc runtime, we need to be able to build few libc build
 173   # tools from the "libc" project. So, we add it to the list of enabled
 174   # projects.
 175   if (NOT "libc" IN_LIST LLVM_ENABLE_PROJECTS)
 176     message(STATUS "Enabling libc project to build libc build tools")
 177     list(APPEND LLVM_ENABLE_PROJECTS "libc")
 178   endif()
 179 endif()
 180
 181 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
 182 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
 183 # several reasons:
 184 #
 185 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
 186 # source of truth for which projects to build. This means we will ignore user
 187 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
 188 # them.
 189 #
 190 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
 191 # non-empty list but now the user wishes to disable building all other projects
 192 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
 193 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
 194 # building all the projects that were previously enabled.
 195 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
 196 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
 197
 198 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
 199   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
 200   foreach(proj ${LLVM_KNOWN_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
 201     string(TOUPPER "${proj}" upper_proj)
 202     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 203     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
 204       message(STATUS "${proj} project is enabled")
 205       set(SHOULD_ENABLE_PROJECT TRUE)
 206       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 207       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 208         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 209       endif()
 210       if( LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR STREQUAL "" )
 211         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "" FORCE)
 212       else()
 213         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "")
 214       endif()
 215     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
 216       message(STATUS "${proj} project is enabled")
 217       set(SHOULD_ENABLE_PROJECT TRUE)
 218     else()
 219       message(STATUS "${proj} project is disabled")
 220       set(SHOULD_ENABLE_PROJECT FALSE)
 221     endif()
 222     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 223     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 224     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 225     # we should deprecate allowing users to set these variables by turning them
 226     # into normal CMake variables rather than cache variables.
 227     set(LLVM_TOOL_${upper_proj}_BUILD
 228       ${SHOULD_ENABLE_PROJECT}
 229       CACHE
 230       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 231     )
 232   endforeach()
 233 endif()
 234 unset(SHOULD_ENABLE_PROJECT)
 235
 236 # Build llvm with ccache if the package is present
 237 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 238 if(LLVM_CCACHE_BUILD)
 239   find_program(CCACHE_PROGRAM ccache)
 240   if(CCACHE_PROGRAM)
 241     set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 242     set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 243     set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 244         CACHE STRING "Parameters to pass through to ccache")
 245
 246     if(NOT CMAKE_SYSTEM_NAME MATCHES "Windows")
 247       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 248       if (LLVM_CCACHE_MAXSIZE)
 249         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 250       endif()
 251       if (LLVM_CCACHE_DIR)
 252         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 253       endif()
 254       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 255     else()
 256       if(LLVM_CCACHE_MAXSIZE OR LLVM_CCACHE_DIR OR
 257          NOT LLVM_CCACHE_PARAMS MATCHES "CCACHE_CPP2=yes CCACHE_HASHDIR=yes")
 258         message(FATAL_ERROR "Ccache configuration through CMake is not supported on Windows. Please use environment variables.")
 259       endif()
 260       # RULE_LAUNCH_COMPILE should work with Ninja but currently has issues
 261       # with cmd.exe and some MSVC tools other than cl.exe
 262       set(CMAKE_C_COMPILER_LAUNCHER ${CCACHE_PROGRAM})
 263       set(CMAKE_CXX_COMPILER_LAUNCHER ${CCACHE_PROGRAM})
 264     endif()
 265   else()
 266     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 267   endif()
 268 endif()
 269
 270 set(LLVM_EXTERNAL_PROJECT_BUILD_TOOL_ARGS "" CACHE STRING
 271   "Optional arguments for the native tool used in CMake --build invocations for external projects.")
 272 mark_as_advanced(LLVM_EXTERNAL_PROJECT_BUILD_TOOL_ARGS)
 273
 274 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 275
 276 # Some features of the LLVM build may be disallowed when dependency debugging is
 277 # enabled. In particular you cannot use ccache because we want to force compile
 278 # operations to always happen.
 279 if(LLVM_DEPENDENCY_DEBUGGING)
 280   if(NOT CMAKE_HOST_APPLE)
 281     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 282   endif()
 283   if(LLVM_CCACHE_BUILD)
 284     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 285   endif()
 286 endif()
 287
 288 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 289 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 290 if(LLVM_ENABLE_GISEL_COV)
 291   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 292 endif()
 293
 294 # Add path for custom modules
 295 list(INSERT CMAKE_MODULE_PATH 0
 296   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 297   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 298   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
 299   )
 300
 301 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 302 # for use by clang_complete, YouCompleteMe, etc.
 303 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 304
 305 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 306   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 307
 308 option(LLVM_INSTALL_CCTOOLS_SYMLINKS
 309   "Install symlinks from the cctools tool names to the corresponding LLVM tools." OFF)
 310
 311 # By default we use symlinks on Unix platforms and copy binaries on Windows
 312 # If you have the correct setup on Windows you can use this option to enable
 313 # symlinks and save a lot of diskspace.
 314 option(LLVM_USE_SYMLINKS "Use symlinks instead of copying binaries" ${CMAKE_HOST_UNIX})
 315
 316 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 317
 318 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 319
 320 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 321 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 322 # the installation by default. See llvm.org/PR31905.
 323 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 324
 325 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 326 if ( LLVM_USE_FOLDERS )
 327   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 328 endif()
 329
 330 include(VersionFromVCS)
 331
 332 option(LLVM_APPEND_VC_REV
 333   "Embed the version control system revision in LLVM" ON)
 334
 335 set(LLVM_FORCE_VC_REVISION
 336   "" CACHE STRING "Force custom VC revision for LLVM_APPEND_VC_REV")
 337
 338 set(LLVM_FORCE_VC_REPOSITORY
 339   "" CACHE STRING "Force custom VC repository for LLVM_APPEND_VC_REV")
 340
 341 option(LLVM_TOOL_LLVM_DRIVER_BUILD "Enables building the llvm multicall tool" OFF)
 342
 343 set(PACKAGE_NAME LLVM)
 344 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 345 set(PACKAGE_BUGREPORT "https://github.com/llvm/llvm-project/issues/")
 346
 347 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 348   "Default URL where bug reports are to be submitted.")
 349
 350 # Configure CPack.
 351 if(NOT DEFINED CPACK_PACKAGE_INSTALL_DIRECTORY)
 352   set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 353 endif()
 354 if(NOT DEFINED CPACK_PACKAGE_VENDOR)
 355   set(CPACK_PACKAGE_VENDOR "LLVM")
 356 endif()
 357 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 358 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 359 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 360 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 361 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 362 if(WIN32 AND NOT UNIX)
 363   set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 364   if(NOT DEFINED CPACK_PACKAGE_INSTALL_REGISTRY_KEY)
 365     set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 366   endif()
 367   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 368   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 369   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 370   set(CPACK_NSIS_MODIFY_PATH "ON")
 371   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 372   if( CMAKE_CL_64 )
 373     if(NOT DEFINED CPACK_NSIS_INSTALL_ROOT)
 374       set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 375     endif()
 376   endif()
 377 endif()
 378 include(CPack)
 379
 380 # Sanity check our source directory to make sure that we are not trying to
 381 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 382 # sure that we don't have any stray generated files lying around in the tree
 383 # (which would end up getting picked up by header search, instead of the correct
 384 # versions).
 385 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 386   message(FATAL_ERROR "In-source builds are not allowed.
 387 Please create a directory and run cmake from there, passing the path
 388 to this source directory as the last argument.
 389 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 390 Please delete them.")
 391 endif()
 392
 393 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 394
 395 if (CMAKE_BUILD_TYPE AND
 396     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 397   message(WARNING "Unknown value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 398 endif()
 399
 400 # LLVM_INSTALL_PACKAGE_DIR needs to be declared prior to adding the tools
 401 # subdirectory in order to have the value available for llvm-config.
 402 include(GNUInstallPackageDir)
 403 set(LLVM_INSTALL_PACKAGE_DIR "${CMAKE_INSTALL_PACKAGEDIR}/llvm" CACHE STRING
 404   "Path for CMake subdirectory for LLVM (defaults to '${CMAKE_INSTALL_PACKAGEDIR}/llvm')")
 405
 406 set(LLVM_TOOLS_INSTALL_DIR "${CMAKE_INSTALL_BINDIR}" CACHE STRING
 407     "Path for binary subdirectory (defaults to '${CMAKE_INSTALL_BINDIR}')")
 408 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 409
 410 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 411     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 412 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 413
 414 set(LLVM_EXAMPLES_INSTALL_DIR "examples" CACHE STRING
 415     "Path for examples subdirectory (enabled by LLVM_BUILD_EXAMPLES=ON) (defaults to 'examples')")
 416 mark_as_advanced(LLVM_EXAMPLES_INSTALL_DIR)
 417
 418 # They are used as destination of target generators.
 419 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 420 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 421 if(WIN32 OR CYGWIN)
 422   # DLL platform -- put DLLs into bin.
 423   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 424 else()
 425   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 426 endif()
 427
 428 # Each of them corresponds to llvm-config's.
 429 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 430 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 431 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 432 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 433 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 434
 435
 436 # Note: LLVM_CMAKE_DIR does not include generated files
 437 set(LLVM_CMAKE_DIR ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 438 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 439 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 440
 441 # List of all targets to be built by default:
 442 set(LLVM_ALL_TARGETS
 443   AArch64
 444   AMDGPU
 445   ARM
 446   AVR
 447   BPF
 448   Hexagon
 449   Lanai
 450   LoongArch
 451   Mips
 452   MSP430
 453   NVPTX
 454   PowerPC
 455   RISCV
 456   Sparc
 457   SystemZ
 458   VE
 459   WebAssembly
 460   X86
 461   XCore
 462   )
 463
 464 set(LLVM_ALL_EXPERIMENTAL_TARGETS
 465   ARC
 466   CSKY
 467   DirectX
 468   M68k
 469   SPIRV
 470   Xtensa
 471 )
 472
 473 # List of targets with JIT support:
 474 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 475
 476 set(LLVM_TARGETS_TO_BUILD "all"
 477     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 478
 479 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 480     CACHE STRING "Semicolon-separated list of experimental targets to build, or \"all\".")
 481
 482 option(BUILD_SHARED_LIBS
 483   "Build all libraries as shared libraries instead of static" OFF)
 484
 485 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 486 if(LLVM_ENABLE_BACKTRACES)
 487   set(ENABLE_BACKTRACES 1)
 488 endif()
 489
 490 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 491
 492 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 493 if(LLVM_ENABLE_CRASH_OVERRIDES)
 494   set(ENABLE_CRASH_OVERRIDES 1)
 495 endif()
 496
 497 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 498
 499 set(WINDOWS_PREFER_FORWARD_SLASH_DEFAULT OFF)
 500 if (MINGW)
 501   # Cygwin doesn't identify itself as Windows, and thus gets path::Style::posix
 502   # as native path style, regardless of what this is set to.
 503   set(WINDOWS_PREFER_FORWARD_SLASH_DEFAULT ON)
 504 endif()
 505 option(LLVM_WINDOWS_PREFER_FORWARD_SLASH "Prefer path names with forward slashes on Windows." ${WINDOWS_PREFER_FORWARD_SLASH_DEFAULT})
 506
 507 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 508 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 509 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 510
 511 set(LLVM_TARGET_ARCH "host"
 512   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 513
 514 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 515
 516 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 517
 518 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 519
 520 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 521
 522 # On z/OS, threads cannot be used because TLS is not supported.
 523 if (CMAKE_SYSTEM_NAME MATCHES "OS390")
 524   option(LLVM_ENABLE_THREADS "Use threads if available." OFF)
 525 else()
 526   option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 527 endif()
 528
 529 set(LLVM_ENABLE_ZLIB "ON" CACHE STRING "Use zlib for compression/decompression if available. Can be ON, OFF, or FORCE_ON")
 530
 531 set(LLVM_ENABLE_ZSTD "ON" CACHE STRING "Use zstd for compression/decompression if available. Can be ON, OFF, or FORCE_ON")
 532
 533 set(LLVM_USE_STATIC_ZSTD FALSE CACHE BOOL "Use static version of zstd. Can be TRUE, FALSE")
 534
 535 set(LLVM_ENABLE_CURL "OFF" CACHE STRING "Use libcurl for the HTTP client if available. Can be ON, OFF, or FORCE_ON")
 536
 537 set(LLVM_ENABLE_HTTPLIB "OFF" CACHE STRING "Use cpp-httplib HTTP server library if available. Can be ON, OFF, or FORCE_ON")
 538
 539 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 540
 541 option(LLVM_ENABLE_Z3_SOLVER
 542   "Enable Support for the Z3 constraint solver in LLVM."
 543   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 544 )
 545
 546 if (LLVM_ENABLE_Z3_SOLVER)
 547   find_package(Z3 4.7.1)
 548
 549   if (LLVM_Z3_INSTALL_DIR)
 550     if (NOT Z3_FOUND)
 551       message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 552     endif()
 553   endif()
 554
 555   if (NOT Z3_FOUND)
 556     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 557   endif()
 558
 559   set(LLVM_WITH_Z3 1)
 560 endif()
 561
 562 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 563
 564
 565 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 566   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 567 endif()
 568
 569 if(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD STREQUAL "all")
 570   set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${LLVM_ALL_EXPERIMENTAL_TARGETS})
 571 endif()
 572
 573 set(LLVM_TARGETS_TO_BUILD
 574    ${LLVM_TARGETS_TO_BUILD}
 575    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 576 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 577
 578 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 579 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 580 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 581   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 582 else()
 583   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 584 endif()
 585 option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 586 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 587 option(LLVM_ENABLE_LLVM_LIBC "Set to on to link all LLVM executables against LLVM libc, assuming it is accessible by the host compiler." OFF)
 588 option(LLVM_STATIC_LINK_CXX_STDLIB "Statically link the standard library." OFF)
 589 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 590 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 591 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 592
 593 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 594 option(LLVM_UNREACHABLE_OPTIMIZE "Optimize llvm_unreachable() as undefined behavior (default), guaranteed trap when OFF" ON)
 595
 596 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 597   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 598 else()
 599   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 600 endif()
 601
 602 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 603
 604 # While adding scalable vector support to LLVM, we temporarily want to
 605 # allow an implicit conversion of TypeSize to uint64_t, and to allow
 606 # code to get the fixed number of elements from a possibly scalable vector.
 607 # This CMake flag enables a more strict mode where it asserts that the type
 608 # is not a scalable vector type.
 609 #
 610 # Enabling this flag makes it easier to find cases where the compiler makes
 611 # assumptions on the size being 'fixed size', when building tests for
 612 # SVE/SVE2 or other scalable vector architectures.
 613 option(LLVM_ENABLE_STRICT_FIXED_SIZE_VECTORS
 614        "Enable assertions that type is not scalable in implicit conversion from TypeSize to uint64_t and calls to getNumElements" OFF)
 615
 616 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 617   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 618
 619 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 620        "Set to ON to force using an old, unsupported host toolchain." OFF)
 621
 622 set(LLVM_LOCAL_RPATH "" CACHE FILEPATH
 623   "If set, an absolute path added as rpath on binaries that do not already contain an executable-relative rpath.")
 624
 625 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 626        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 627
 628 option(LLVM_USE_INTEL_JITEVENTS
 629   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 630   OFF)
 631
 632 if( LLVM_USE_INTEL_JITEVENTS )
 633   # Verify we are on a supported platform
 634   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 635     message(FATAL_ERROR
 636       "Intel JIT API support is available on Linux and Windows only.")
 637   endif()
 638 endif( LLVM_USE_INTEL_JITEVENTS )
 639
 640 option(LLVM_USE_OPROFILE
 641   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 642
 643 option(LLVM_EXTERNALIZE_DEBUGINFO
 644   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 645
 646 option(LLVM_EXPERIMENTAL_DEBUGINFO_ITERATORS
 647   "Add extra Booleans to ilist_iterators to communicate facts for debug-info" OFF)
 648
 649 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 650   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 651
 652 # If enabled, verify we are on a platform that supports oprofile.
 653 if( LLVM_USE_OPROFILE )
 654   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 655     message(FATAL_ERROR "OProfile support is available on Linux only.")
 656   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 657 endif( LLVM_USE_OPROFILE )
 658
 659 option(LLVM_USE_PERF
 660   "Use perf JIT interface to inform perf about JIT code" OFF)
 661
 662 # If enabled, verify we are on a platform that supports perf.
 663 if( LLVM_USE_PERF )
 664   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 665     message(FATAL_ERROR "perf support is available on Linux only.")
 666   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 667 endif( LLVM_USE_PERF )
 668
 669 set(LLVM_USE_SANITIZER "" CACHE STRING
 670   "Define the sanitizer used to build binaries and tests.")
 671 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 672 set(LLVM_UBSAN_FLAGS
 673     "-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 674     CACHE STRING
 675     "Compile flags set to enable UBSan. Only used if LLVM_USE_SANITIZER contains 'Undefined'.")
 676 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 677   "Path to fuzzing library for linking with fuzz targets")
 678
 679 option(LLVM_USE_SPLIT_DWARF
 680   "Use -gsplit-dwarf when compiling llvm and --gdb-index when linking." OFF)
 681
 682 # Define an option controlling whether we should build for 32-bit on 64-bit
 683 # platforms, where supported.
 684 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT (WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX"))
 685   # TODO: support other platforms and toolchains.
 686   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 687 endif()
 688
 689 # Define the default arguments to use with 'lit', and an option for the user to
 690 # override.
 691 set(LIT_ARGS_DEFAULT "-sv")
 692 if (MSVC_IDE OR XCODE)
 693   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 694 endif()
 695 if(LLVM_INDIVIDUAL_TEST_COVERAGE)
 696    set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --per-test-coverage")
 697 endif()
 698 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 699
 700 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 701 if( WIN32 AND NOT CYGWIN )
 702   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 703 endif()
 704 set(LLVM_NATIVE_TOOL_DIR "" CACHE PATH "Path to a directory containing prebuilt matching native tools (such as llvm-tblgen)")
 705
 706 set(LLVM_INTEGRATED_CRT_ALLOC "" CACHE PATH "Replace the Windows CRT allocator with any of {rpmalloc|mimalloc|snmalloc}. Only works with CMAKE_MSVC_RUNTIME_LIBRARY=MultiThreaded.")
 707 if(LLVM_INTEGRATED_CRT_ALLOC)
 708   if(NOT WIN32)
 709     message(FATAL_ERROR "LLVM_INTEGRATED_CRT_ALLOC is only supported on Windows.")
 710   endif()
 711   if(LLVM_USE_SANITIZER)
 712     message(FATAL_ERROR "LLVM_INTEGRATED_CRT_ALLOC cannot be used along with LLVM_USE_SANITIZER!")
 713   endif()
 714   if(CMAKE_BUILD_TYPE AND uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 715     message(FATAL_ERROR "The Debug target isn't supported along with LLVM_INTEGRATED_CRT_ALLOC!")
 716   endif()
 717 endif()
 718
 719 # Define options to control the inclusion and default build behavior for
 720 # components which may not strictly be necessary (tools, examples, and tests).
 721 #
 722 # This is primarily to support building smaller or faster project files.
 723 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 724 option(LLVM_BUILD_TOOLS
 725   "Build the LLVM tools. If OFF, just generate build targets." ON)
 726
 727 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 728 option(LLVM_BUILD_UTILS
 729   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 730
 731 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 732 option(LLVM_BUILD_RUNTIMES
 733   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 734
 735 option(LLVM_BUILD_RUNTIME
 736   "Build the LLVM runtime libraries." ON)
 737 option(LLVM_BUILD_EXAMPLES
 738   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 739 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 740
 741 if(LLVM_BUILD_EXAMPLES)
 742   add_compile_definitions(BUILD_EXAMPLES)
 743 endif(LLVM_BUILD_EXAMPLES)
 744
 745 option(LLVM_BUILD_TESTS
 746   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 747 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 748
 749 option(LLVM_INSTALL_GTEST
 750   "Install the llvm gtest library.  This should be on if you want to do
 751    stand-alone builds of the other projects and run their unit tests." OFF)
 752
 753 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 754 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 755 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 756
 757 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 758 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 759 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 760 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 761 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 762 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 763
 764 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "${CMAKE_INSTALL_DOCDIR}/llvm/doxygen-html"
 765     CACHE STRING "Doxygen-generated HTML documentation install directory")
 766 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "${CMAKE_INSTALL_DOCDIR}/llvm/ocaml-html"
 767     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 768
 769 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 770   "Build compiler-rt as an external project." OFF)
 771
 772 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 773   "Show target and host info when tools are invoked with --version." ON)
 774
 775 # You can configure which libraries from LLVM you want to include in the
 776 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 777 # list of LLVM components. All component names handled by llvm-config are valid.
 778 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 779   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 780     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 781 endif()
 782
 783 if(MSVC)
 784   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 785   # Set this variable to OFF here so it can't be set with a command-line
 786   # argument.
 787   set (LLVM_LINK_LLVM_DYLIB OFF)
 788   if (BUILD_SHARED_LIBS)
 789     message(FATAL_ERROR "BUILD_SHARED_LIBS options is not supported on Windows.")
 790   endif()
 791 else()
 792   option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 793   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 794   set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 795   if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 796     set(LLVM_BUILD_LLVM_DYLIB_default ON)
 797   endif()
 798   option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 799 endif()
 800
 801 if (LLVM_LINK_LLVM_DYLIB AND BUILD_SHARED_LIBS)
 802   message(FATAL_ERROR "Cannot enable BUILD_SHARED_LIBS with LLVM_LINK_LLVM_DYLIB.  We recommend disabling BUILD_SHARED_LIBS.")
 803 endif()
 804
 805 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 806 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 807   set(LLVM_USE_HOST_TOOLS ON)
 808 endif()
 809
 810 option(LLVM_OMIT_DAGISEL_COMMENTS "Do not add comments to DAG ISel" ON)
 811 if (CMAKE_BUILD_TYPE AND uppercase_CMAKE_BUILD_TYPE MATCHES "^(RELWITHDEBINFO|DEBUG)$")
 812   set(LLVM_OMIT_DAGISEL_COMMENTS OFF)
 813 endif()
 814
 815 if (MSVC_IDE)
 816   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 817 endif()
 818
 819 if(NOT LLVM_INDIVIDUAL_TEST_COVERAGE)
 820   if(LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR LLVM_ENABLE_IR_PGO)
 821     if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 822       # A pool size of 1-2 is probably sufficient on an SSD. 3-4 should be fine
 823       # for spinning disks. Anything higher may only help on slower mediums.
 824       set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 825     endif()
 826     if(NOT LLVM_PROFILE_FILE_PATTERN)
 827       if(NOT LLVM_PROFILE_DATA_DIR)
 828         file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 829       endif()
 830       file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 831     endif()
 832     if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 833       if(NOT LLVM_CSPROFILE_DATA_DIR)
 834         file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 835       endif()
 836       file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 837     endif()
 838   endif()
 839 endif()
 840
 841 if (LLVM_BUILD_STATIC)
 842   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 843   # Remove shared library suffixes from use in find_library
 844   foreach (shared_lib_suffix ${CMAKE_SHARED_LIBRARY_SUFFIX} ${CMAKE_IMPORT_LIBRARY_SUFFIX})
 845     list(FIND CMAKE_FIND_LIBRARY_SUFFIXES ${shared_lib_suffix} shared_lib_suffix_idx)
 846     if(NOT ${shared_lib_suffix_idx} EQUAL -1)
 847       list(REMOVE_AT CMAKE_FIND_LIBRARY_SUFFIXES ${shared_lib_suffix_idx})
 848     endif()
 849   endforeach()
 850 endif()
 851
 852 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 853 if(CMAKE_HOST_APPLE AND APPLE)
 854   include(UseLibtool)
 855 endif()
 856
 857 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 858 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 859 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 860
 861 if(CMAKE_SYSTEM_NAME MATCHES "BSD|Linux|OS390")
 862   set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR_default ON)
 863 else()
 864   set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR_default OFF)
 865 endif()
 866 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR ${LLVM_ENABLE_PER_TARGET_RUNTIME_DIR_default} CACHE BOOL
 867   "Enable per-target runtimes directory")
 868
 869 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 870   "Profiling data file to use when compiling in order to improve runtime performance.")
 871
 872 if(LLVM_INCLUDE_TESTS)
 873   # Lit test suite requires at least python 3.6
 874   set(LLVM_MINIMUM_PYTHON_VERSION 3.6)
 875 else()
 876   # FIXME: it is unknown if this is the actual minimum bound
 877   set(LLVM_MINIMUM_PYTHON_VERSION 3.0)
 878 endif()
 879
 880 # Find python before including config-ix, since it needs to be able to search
 881 # for python modules.
 882 find_package(Python3 ${LLVM_MINIMUM_PYTHON_VERSION} REQUIRED
 883     COMPONENTS Interpreter)
 884
 885 # All options referred to from HandleLLVMOptions have to be specified
 886 # BEFORE this include, otherwise options will not be correctly set on
 887 # first cmake run
 888 include(config-ix)
 889
 890 # By default, we target the host, but this can be overridden at CMake
 891 # invocation time. Except on 64-bit AIX, where the system toolchain
 892 # expect 32-bit objects by default.
 893 if("${LLVM_HOST_TRIPLE}" MATCHES "^powerpc64-ibm-aix")
 894   string(REGEX REPLACE "^powerpc64" "powerpc" LLVM_DEFAULT_TARGET_TRIPLE_DEFAULT "${LLVM_HOST_TRIPLE}")
 895 else()
 896   # Only set default triple when native target is enabled.
 897   if (LLVM_NATIVE_TARGET)
 898     set(LLVM_DEFAULT_TARGET_TRIPLE_DEFAULT "${LLVM_HOST_TRIPLE}")
 899   endif()
 900 endif()
 901
 902 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE_DEFAULT}" CACHE STRING
 903     "Default target for which LLVM will generate code." )
 904 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 905
 906 set(LLVM_TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 907
 908 if(WIN32 OR CYGWIN)
 909   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 910     set(LLVM_ENABLE_PLUGINS_default ON)
 911   else()
 912     set(LLVM_ENABLE_PLUGINS_default OFF)
 913   endif()
 914 else()
 915   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 916 endif()
 917 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 918
 919 set(LLVM_ENABLE_NEW_PASS_MANAGER TRUE CACHE BOOL
 920   "Enable the new pass manager by default.")
 921 if(NOT LLVM_ENABLE_NEW_PASS_MANAGER)
 922   message(FATAL_ERROR "Enabling the legacy pass manager on the cmake level is"
 923                       " no longer supported.")
 924 endif()
 925
 926 include(HandleLLVMOptions)
 927
 928 ######
 929
 930 # Configure all of the various header file fragments LLVM uses which depend on
 931 # configuration variables.
 932 set(LLVM_ENUM_TARGETS "")
 933 set(LLVM_ENUM_ASM_PRINTERS "")
 934 set(LLVM_ENUM_ASM_PARSERS "")
 935 set(LLVM_ENUM_DISASSEMBLERS "")
 936 set(LLVM_ENUM_TARGETMCAS "")
 937 set(LLVM_ENUM_EXEGESIS "")
 938 foreach(t ${LLVM_TARGETS_TO_BUILD})
 939   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 940
 941   # Make sure that any experimental targets were passed via
 942   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 943   # We allow experimental targets that are not in LLVM_ALL_EXPERIMENTAL_TARGETS,
 944   # as long as they are passed via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.
 945   if ( NOT "${t}" IN_LIST LLVM_ALL_TARGETS AND NOT "${t}" IN_LIST LLVM_EXPERIMENTAL_TARGETS_TO_BUILD )
 946     if( "${t}" IN_LIST LLVM_ALL_EXPERIMENTAL_TARGETS )
 947       message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 948         "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 949     else()
 950       message(FATAL_ERROR "The target `${t}' is not a core tier target. It may be "
 951         "experimental, if so it must be passed via "
 952         "LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.\n"
 953         "Core tier targets: ${LLVM_ALL_TARGETS}\n"
 954         "Known experimental targets: ${LLVM_ALL_EXPERIMENTAL_TARGETS}")
 955     endif()
 956   else()
 957     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 958   endif()
 959
 960   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 961   if( asmp_file )
 962     set(LLVM_ENUM_ASM_PRINTERS
 963       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 964   endif()
 965   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 966     set(LLVM_ENUM_ASM_PARSERS
 967       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 968   endif()
 969   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 970     set(LLVM_ENUM_DISASSEMBLERS
 971       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 972   endif()
 973   if( EXISTS ${td}/MCA/CMakeLists.txt )
 974     set(LLVM_ENUM_TARGETMCAS
 975       "${LLVM_ENUM_TARGETMCAS}LLVM_TARGETMCA(${t})\n")
 976   endif()
 977   if( EXISTS ${LLVM_MAIN_SRC_DIR}/tools/llvm-exegesis/lib/${t}/CMakeLists.txt )
 978     set(LLVM_ENUM_EXEGESIS
 979       "${LLVM_ENUM_EXEGESIS}LLVM_EXEGESIS(${t})\n")
 980   endif()
 981 endforeach(t)
 982
 983 # Provide an LLVM_ namespaced alias for use in #cmakedefine.
 984 set(LLVM_BUILD_SHARED_LIBS ${BUILD_SHARED_LIBS})
 985
 986 # Produce the target definition files, which provide a way for clients to easily
 987 # include various classes of targets.
 988 configure_file(
 989   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 990   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 991   )
 992 configure_file(
 993   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 994   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 995   )
 996 configure_file(
 997   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 998   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 999   )
1000 configure_file(
1001   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
1002   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
1003   )
1004 configure_file(
1005   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/TargetMCAs.def.in
1006   ${LLVM_INCLUDE_DIR}/llvm/Config/TargetMCAs.def
1007   )
1008 configure_file(
1009   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/TargetExegesis.def.in
1010   ${LLVM_INCLUDE_DIR}/llvm/Config/TargetExegesis.def
1011   )
1012
1013 # They are not referenced. See set_output_directory().
1014 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
1015 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_LIBRARY_DIR} )
1016 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_LIBRARY_DIR} )
1017
1018 # For up-to-date instructions for installing the TFLite dependency, refer to
1019 # the bot setup script: https://github.com/google/ml-compiler-opt/blob/main/buildbot/buildbot_init.sh
1020 set(LLVM_HAVE_TFLITE "" CACHE BOOL "Use tflite")
1021 if (LLVM_HAVE_TFLITE)
1022   find_package(tensorflow-lite REQUIRED)
1023 endif()
1024
1025 # For up-to-date instructions for installing the Tensorflow dependency, refer to
1026 # the bot setup script: https://github.com/google/ml-compiler-opt/blob/main/buildbot/buildbot_init.sh
1027 # Specifically, assuming python3 is installed:
1028 # python3 -m pip install --upgrade pip && python3 -m pip install --user tf_nightly==2.3.0.dev20200528
1029 # Then set TENSORFLOW_AOT_PATH to the package install - usually it's ~/.local/lib/python3.7/site-packages/tensorflow
1030 #
1031 set(TENSORFLOW_AOT_PATH "" CACHE PATH "Path to TensorFlow pip install dir")
1032
1033 if (NOT TENSORFLOW_AOT_PATH STREQUAL "")
1034   set(LLVM_HAVE_TF_AOT "ON" CACHE BOOL "Tensorflow AOT available")
1035   set(TENSORFLOW_AOT_COMPILER
1036     "${TENSORFLOW_AOT_PATH}/../../../../bin/saved_model_cli"
1037     CACHE PATH "Path to the Tensorflow AOT compiler")
1038   include_directories(${TENSORFLOW_AOT_PATH}/include)
1039   add_subdirectory(${TENSORFLOW_AOT_PATH}/xla_aot_runtime_src
1040     ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/tf_runtime)
1041   install(TARGETS tf_xla_runtime EXPORT LLVMExports
1042     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX} COMPONENT tf_xla_runtime)
1043   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS tf_xla_runtime)
1044   # Once we add more modules, we should handle this more automatically.
1045   if (DEFINED LLVM_OVERRIDE_MODEL_HEADER_INLINERSIZEMODEL)
1046     set(LLVM_INLINER_MODEL_PATH "none")
1047   elseif(NOT DEFINED LLVM_INLINER_MODEL_PATH
1048       OR "${LLVM_INLINER_MODEL_PATH}" STREQUAL ""
1049       OR "${LLVM_INLINER_MODEL_PATH}" STREQUAL "autogenerate")
1050     set(LLVM_INLINER_MODEL_PATH "autogenerate")
1051     set(LLVM_INLINER_MODEL_AUTOGENERATED 1)
1052   endif()
1053   if (DEFINED LLVM_OVERRIDE_MODEL_HEADER_REGALLOCEVICTMODEL)
1054     set(LLVM_RAEVICT_MODEL_PATH "none")
1055   elseif(NOT DEFINED LLVM_RAEVICT_MODEL_PATH
1056       OR "${LLVM_RAEVICT_MODEL_PATH}" STREQUAL ""
1057       OR "${LLVM_RAEVICT_MODEL_PATH}" STREQUAL "autogenerate")
1058     set(LLVM_RAEVICT_MODEL_PATH "autogenerate")
1059     set(LLVM_RAEVICT_MODEL_AUTOGENERATED 1)
1060   endif()
1061
1062 endif()
1063
1064 # Configure the three LLVM configuration header files.
1065 configure_file(
1066   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
1067   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
1068 configure_file(
1069   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
1070   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
1071 configure_file(
1072   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
1073   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
1074
1075 # Add target for generating source rpm package.
1076 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
1077     CACHE FILEPATH ".spec file to use for srpm generation")
1078 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
1079 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
1080
1081 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
1082 string(LENGTH "${revision}" revision_length)
1083 set(LLVM_RPM_SPEC_REVISION "${revision}")
1084
1085 configure_file(
1086   ${LLVM_SRPM_USER_BINARY_SPECFILE}
1087   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
1088
1089 add_custom_target(srpm
1090   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
1091   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
1092 set_target_properties(srpm PROPERTIES FOLDER "Misc")
1093
1094 if(APPLE AND DARWIN_LTO_LIBRARY)
1095   set(CMAKE_EXE_LINKER_FLAGS
1096     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
1097   set(CMAKE_SHARED_LINKER_FLAGS
1098     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
1099   set(CMAKE_MODULE_LINKER_FLAGS
1100     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
1101 endif()
1102
1103 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
1104 # break things. In this case we need to enable the large-file API as well.
1105 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
1106           add_compile_definitions(_XOPEN_SOURCE=700)
1107           add_compile_definitions(_LARGE_FILE_API)
1108
1109   # Modules should be built with -shared -Wl,-G, so we can use runtime linking
1110   # with plugins.
1111   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -shared -Wl,-G")
1112
1113   # Also set the correct flags for building shared libraries.
1114   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -shared")
1115 endif()
1116
1117 # Build with _XOPEN_SOURCE on z/OS.
1118 if (CMAKE_SYSTEM_NAME MATCHES "OS390")
1119   add_compile_definitions(_XOPEN_SOURCE=600)
1120   add_compile_definitions(_OPEN_SYS) # Needed for process information.
1121   add_compile_definitions(_OPEN_SYS_FILE_EXT) # Needed for EBCDIC I/O.
1122 endif()
1123
1124 # Build with _FILE_OFFSET_BITS=64 on Solaris to match g++ >= 9.
1125 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
1126           add_compile_definitions(_FILE_OFFSET_BITS=64)
1127 endif()
1128
1129 set(CMAKE_INCLUDE_CURRENT_DIR ON)
1130
1131 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
1132
1133 # when crosscompiling import the executable targets from a file
1134 if(LLVM_USE_HOST_TOOLS)
1135   include(CrossCompile)
1136   llvm_create_cross_target(LLVM NATIVE "" Release)
1137 endif(LLVM_USE_HOST_TOOLS)
1138 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
1139 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
1140 # (this is a variable that CrossCompile sets on recursive invocations)
1141 endif()
1142
1143 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
1144    # special hack for Solaris to handle crazy system sys/regset.h
1145    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
1146 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
1147
1148 # Make sure we don't get -rdynamic in every binary. For those that need it,
1149 # use export_executable_symbols(target).
1150 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
1151
1152 include(AddLLVM)
1153 include(TableGen)
1154
1155 include(LLVMDistributionSupport)
1156
1157 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
1158   # People report that -O3 is unreliable on MinGW. The traditional
1159   # build also uses -O2 for that reason:
1160   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
1161 endif()
1162
1163 if(LLVM_INCLUDE_TESTS)
1164   umbrella_lit_testsuite_begin(check-all)
1165 endif()
1166
1167 # Put this before tblgen. Else we have a circular dependence.
1168 add_subdirectory(lib/Demangle)
1169 add_subdirectory(lib/Support)
1170 add_subdirectory(lib/TableGen)
1171
1172 add_subdirectory(utils/TableGen)
1173
1174 add_subdirectory(include)
1175
1176 add_subdirectory(lib)
1177
1178 if( LLVM_INCLUDE_UTILS )
1179   add_subdirectory(utils/FileCheck)
1180   add_subdirectory(utils/PerfectShuffle)
1181   add_subdirectory(utils/count)
1182   add_subdirectory(utils/not)
1183   add_subdirectory(utils/UnicodeData)
1184   add_subdirectory(utils/yaml-bench)
1185   add_subdirectory(utils/split-file)
1186   if( LLVM_INCLUDE_TESTS )
1187     add_subdirectory(${LLVM_THIRD_PARTY_DIR}/unittest ${CMAKE_CURRENT_BINARY_DIR}/third-party/unittest)
1188   endif()
1189 else()
1190   if ( LLVM_INCLUDE_TESTS )
1191     message(FATAL_ERROR "Including tests when not building utils will not work.
1192     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
1193   endif()
1194 endif()
1195
1196 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
1197 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
1198   add_subdirectory(utils/LLVMVisualizers)
1199 endif()
1200
1201 foreach( binding ${LLVM_BINDINGS_LIST} )
1202   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
1203     add_subdirectory(bindings/${binding})
1204   endif()
1205 endforeach()
1206
1207 add_subdirectory(projects)
1208
1209 if( LLVM_INCLUDE_TOOLS )
1210   add_subdirectory(tools)
1211 endif()
1212
1213 if( LLVM_INCLUDE_RUNTIMES )
1214   add_subdirectory(runtimes)
1215 endif()
1216
1217 if( LLVM_INCLUDE_EXAMPLES )
1218   add_subdirectory(examples)
1219 endif()
1220
1221 if( LLVM_INCLUDE_TESTS )
1222   set(LLVM_GTEST_RUN_UNDER
1223     "" CACHE STRING
1224     "Define the wrapper program that LLVM unit tests should be run under.")
1225   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
1226     include(LLVMExternalProjectUtils)
1227     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
1228       USE_TOOLCHAIN
1229       EXCLUDE_FROM_ALL
1230       NO_INSTALL
1231       ALWAYS_CLEAN)
1232   endif()
1233   add_subdirectory(utils/lit)
1234   add_subdirectory(test)
1235   add_subdirectory(unittests)
1236
1237   if (WIN32)
1238     # This utility is used to prevent crashing tests from calling Dr. Watson on
1239     # Windows.
1240     add_subdirectory(utils/KillTheDoctor)
1241   endif()
1242
1243   umbrella_lit_testsuite_end(check-all)
1244   get_property(LLVM_ALL_LIT_DEPENDS GLOBAL PROPERTY LLVM_ALL_LIT_DEPENDS)
1245   get_property(LLVM_ALL_ADDITIONAL_TEST_DEPENDS
1246       GLOBAL PROPERTY LLVM_ALL_ADDITIONAL_TEST_DEPENDS)
1247   add_custom_target(test-depends
1248       DEPENDS ${LLVM_ALL_LIT_DEPENDS} ${LLVM_ALL_ADDITIONAL_TEST_DEPENDS})
1249   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
1250 endif()
1251
1252 if (LLVM_INCLUDE_DOCS)
1253   add_subdirectory(docs)
1254 endif()
1255
1256 add_subdirectory(cmake/modules)
1257
1258 # Do this last so that all lit targets have already been created.
1259 if (LLVM_INCLUDE_UTILS)
1260   add_subdirectory(utils/llvm-lit)
1261 endif()
1262
1263 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1264   install(DIRECTORY include/llvm include/llvm-c
1265     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1266     COMPONENT llvm-headers
1267     FILES_MATCHING
1268     PATTERN "*.def"
1269     PATTERN "*.h"
1270     PATTERN "*.td"
1271     PATTERN "*.inc"
1272     PATTERN "LICENSE.TXT"
1273     )
1274
1275   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1276     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1277     COMPONENT llvm-headers
1278     FILES_MATCHING
1279     PATTERN "*.def"
1280     PATTERN "*.h"
1281     PATTERN "*.gen"
1282     PATTERN "*.inc"
1283     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1284     PATTERN "CMakeFiles" EXCLUDE
1285     PATTERN "config.h" EXCLUDE
1286     )
1287
1288   if (LLVM_INSTALL_MODULEMAPS)
1289     install(DIRECTORY include
1290             DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1291             COMPONENT llvm-headers
1292             FILES_MATCHING
1293             PATTERN "module.modulemap"
1294             )
1295     install(FILES include/module.install.modulemap
1296             DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1297             COMPONENT llvm-headers
1298             RENAME "module.extern.modulemap"
1299             )
1300   endif(LLVM_INSTALL_MODULEMAPS)
1301
1302   # Installing the headers needs to depend on generating any public
1303   # tablegen'd headers.
1304   add_custom_target(llvm-headers DEPENDS intrinsics_gen omp_gen)
1305   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1306
1307   if (NOT LLVM_ENABLE_IDE)
1308     add_llvm_install_targets(install-llvm-headers
1309                              DEPENDS llvm-headers
1310                              COMPONENT llvm-headers)
1311   endif()
1312
1313   # Custom target to install all libraries.
1314   add_custom_target(llvm-libraries)
1315   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1316
1317   if (NOT LLVM_ENABLE_IDE)
1318     add_llvm_install_targets(install-llvm-libraries
1319                              DEPENDS llvm-libraries
1320                              COMPONENT llvm-libraries)
1321   endif()
1322
1323   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1324   if(LLVM_LIBS)
1325     list(REMOVE_DUPLICATES LLVM_LIBS)
1326     foreach(lib ${LLVM_LIBS})
1327       add_dependencies(llvm-libraries ${lib})
1328       if (NOT LLVM_ENABLE_IDE)
1329         add_dependencies(install-llvm-libraries install-${lib})
1330         add_dependencies(install-llvm-libraries-stripped install-${lib}-stripped)
1331       endif()
1332     endforeach()
1333   endif()
1334 endif()
1335
1336 # This must be at the end of the LLVM root CMakeLists file because it must run
1337 # after all targets are created.
1338 llvm_distribution_add_targets()
1339 process_llvm_pass_plugins(GEN_CONFIG)
1340 include(CoverageReport)
1341
1342 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1343 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1344   include(InstallRequiredSystemLibraries)
1345 endif()
1346
1347 if (LLVM_INCLUDE_BENCHMARKS)
1348   # Override benchmark defaults so that when the library itself is updated these
1349   # modifications are not lost.
1350   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1351   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1352   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1353   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1354   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1355   set(BENCHMARK_ENABLE_WERROR ${LLVM_ENABLE_WERROR} CACHE BOOL
1356     "Handle -Werror for Google Benchmark based on LLVM_ENABLE_WERROR" FORCE)
1357   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1358   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1359   add_subdirectory(${LLVM_THIRD_PARTY_DIR}/benchmark
1360     ${CMAKE_CURRENT_BINARY_DIR}/third-party/benchmark)
1361   add_subdirectory(benchmarks)
1362 endif()
1363
1364 if (LLVM_INCLUDE_UTILS AND LLVM_INCLUDE_TOOLS)
1365   add_subdirectory(utils/llvm-locstats)
1366 endif()