llvm/test/Analysis/BasicAA/struct-geps.ll

   1 ; RUN: opt < %s -aa-pipeline=basic-aa -passes=aa-eval -print-all-alias-modref-info -disable-output 2>&1 | FileCheck %s
   2
   3 target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
   4
   5 %struct = type { i32, i32, i32 }
   6
   7 ; CHECK-LABEL: test_simple
   8
   9 ; CHECK-DAG: MayAlias: %struct* %st, i32* %x
  10 ; CHECK-DAG: MayAlias: %struct* %st, i32* %y
  11 ; CHECK-DAG: MayAlias: %struct* %st, i32* %z
  12
  13 ; CHECK-DAG: NoAlias: i32* %x, i32* %y
  14 ; CHECK-DAG: NoAlias: i32* %x, i32* %z
  15 ; CHECK-DAG: NoAlias: i32* %y, i32* %z
  16
  17 ; CHECK-DAG: MayAlias: %struct* %st, %struct* %y
  18 ; CHECK-DAG: MayAlias: i32* %x, %struct* %y
  19 ; CHECK-DAG: MayAlias: i32* %x, i80* %y
  20
  21 ; CHECK-DAG: MayAlias: %struct* %st, i64* %y
  22 ; CHECK-DAG: MayAlias: i64* %y, i32* %z
  23 ; CHECK-DAG: NoAlias: i32* %x, i64* %y
  24
  25 ; CHECK-DAG: MustAlias: %struct* %y, i32* %y
  26 ; CHECK-DAG: MustAlias: i64* %y, i32* %y
  27 ; CHECK-DAG: MustAlias: i80* %y, i32* %y
  28
  29 define void @test_simple(ptr %st, i64 %i, i64 %j, i64 %k) {
  30   %x = getelementptr inbounds %struct, ptr %st, i64 %i, i32 0
  31   %y = getelementptr inbounds %struct, ptr %st, i64 %j, i32 1
  32   %z = getelementptr inbounds %struct, ptr %st, i64 %k, i32 2
  33   load %struct, ptr %st
  34   load i32, ptr %x
  35   load i32, ptr %y
  36   load i32, ptr %z
  37   load %struct, ptr %y
  38   load i80, ptr %y
  39   load i64, ptr %y
  40   ret void
  41 }
  42
  43 ; As the GEP is not inbounds, these pointers may alias due to overflow.
  44 ; CHECK-LABEL: test_not_inbounds
  45 ; CHECK: MayAlias: i32* %x, i32* %y
  46 define void @test_not_inbounds(ptr %st, i64 %i, i64 %j, i64 %k) {
  47   %x = getelementptr %struct, ptr %st, i64 %i, i32 0
  48   %y = getelementptr %struct, ptr %st, i64 %j, i32 1
  49   load i32, ptr %x
  50   load i32, ptr %y
  51   ret void
  52 }
  53
  54 ; CHECK-LABEL: test_in_array
  55
  56 ; CHECK-DAG: MayAlias: [1 x %struct]* %st, i32* %x
  57 ; CHECK-DAG: MayAlias: [1 x %struct]* %st, i32* %y
  58 ; CHECK-DAG: MayAlias: [1 x %struct]* %st, i32* %z
  59
  60 ; CHECK-DAG: NoAlias: i32* %x, i32* %y
  61 ; CHECK-DAG: NoAlias: i32* %x, i32* %z
  62 ; CHECK-DAG: NoAlias: i32* %y, i32* %z
  63
  64 ; CHECK-DAG: MayAlias: [1 x %struct]* %st, %struct* %y
  65 ; CHECK-DAG: MayAlias: i32* %x, %struct* %y
  66 ; CHECK-DAG: MayAlias: i32* %x, i80* %y
  67
  68 ; CHECK-DAG: MayAlias: [1 x %struct]* %st, i64* %y
  69 ; CHECK-DAG: MayAlias: i64* %y, i32* %z
  70 ; CHECK-DAG: NoAlias: i32* %x, i64* %y
  71
  72 ; CHECK-DAG: MustAlias: %struct* %y, i32* %y
  73 ; CHECK-DAG: MustAlias: i64* %y, i32* %y
  74 ; CHECK-DAG: MustAlias: i80* %y, i32* %y
  75
  76 define void @test_in_array(ptr %st, i64 %i, i64 %j, i64 %k, i64 %i1, i64 %j1, i64 %k1) {
  77   %x = getelementptr inbounds [1 x %struct], ptr %st, i64 %i, i64 %i1, i32 0
  78   %y = getelementptr inbounds [1 x %struct], ptr %st, i64 %j, i64 %j1, i32 1
  79   %z = getelementptr inbounds [1 x %struct], ptr %st, i64 %k, i64 %k1, i32 2
  80   load [1 x %struct], ptr %st
  81   load i32, ptr %x
  82   load i32, ptr %y
  83   load i32, ptr %z
  84   load %struct, ptr %y
  85   load i80, ptr %y
  86   load i64, ptr %y
  87   ret void
  88 }
  89
  90 ; CHECK-LABEL: test_in_3d_array
  91
  92 ; CHECK-DAG: MayAlias: [1 x [1 x [1 x %struct]]]* %st, i32* %x
  93 ; CHECK-DAG: MayAlias: [1 x [1 x [1 x %struct]]]* %st, i32* %y
  94 ; CHECK-DAG: MayAlias: [1 x [1 x [1 x %struct]]]* %st, i32* %z
  95
  96 ; CHECK-DAG: NoAlias: i32* %x, i32* %y
  97 ; CHECK-DAG: NoAlias: i32* %x, i32* %z
  98 ; CHECK-DAG: NoAlias: i32* %y, i32* %z
  99
 100 ; CHECK-DAG: MayAlias: [1 x [1 x [1 x %struct]]]* %st, %struct* %y
 101 ; CHECK-DAG: MayAlias: i32* %x, %struct* %y
 102 ; CHECK-DAG: MayAlias: i32* %x, i80* %y
 103
 104 ; CHECK-DAG: MayAlias: [1 x [1 x [1 x %struct]]]* %st, i64* %y
 105 ; CHECK-DAG: MayAlias: i64* %y, i32* %z
 106 ; CHECK-DAG: NoAlias: i32* %x, i64* %y
 107
 108 ; CHECK-DAG: MustAlias: %struct* %y, i32* %y
 109 ; CHECK-DAG: MustAlias: i64* %y, i32* %y
 110 ; CHECK-DAG: MustAlias: i80* %y, i32* %y
 111
 112 define void @test_in_3d_array(ptr %st, i64 %i, i64 %j, i64 %k, i64 %i1, i64 %j1, i64 %k1, i64 %i2, i64 %j2, i64 %k2, i64 %i3, i64 %j3, i64 %k3) {
 113   %x = getelementptr inbounds [1 x [1 x [1 x %struct]]], ptr %st, i64 %i, i64 %i1, i64 %i2, i64 %i3, i32 0
 114   %y = getelementptr inbounds [1 x [1 x [1 x %struct]]], ptr %st, i64 %j, i64 %j1, i64 %j2, i64 %j3, i32 1
 115   %z = getelementptr inbounds [1 x [1 x [1 x %struct]]], ptr %st, i64 %k, i64 %k1, i64 %k2, i64 %k3, i32 2
 116   load [1 x [1 x [1 x %struct]]], ptr %st
 117   load i32, ptr %x
 118   load i32, ptr %y
 119   load i32, ptr %z
 120   load %struct, ptr %y
 121   load i80, ptr %y
 122   load i64, ptr %y
 123   ret void
 124 }
 125
 126 ; CHECK-LABEL: test_same_underlying_object_same_indices
 127
 128 ; CHECK-DAG: NoAlias: i32* %x, i32* %x2
 129 ; CHECK-DAG: NoAlias: i32* %y, i32* %y2
 130 ; CHECK-DAG: NoAlias: i32* %z, i32* %z2
 131
 132 ; CHECK-DAG: NoAlias: i32* %x, i32* %y2
 133 ; CHECK-DAG: NoAlias: i32* %x, i32* %z2
 134
 135 ; CHECK-DAG: NoAlias: i32* %x2, i32* %y
 136 ; CHECK-DAG: NoAlias: i32* %y, i32* %z2
 137
 138 ; CHECK-DAG: NoAlias: i32* %x2, i32* %z
 139 ; CHECK-DAG: NoAlias: i32* %y2, i32* %z
 140
 141 define void @test_same_underlying_object_same_indices(ptr %st, i64 %i, i64 %j, i64 %k) {
 142   %st2 = getelementptr inbounds %struct, ptr %st, i32 10
 143   %x2 = getelementptr inbounds %struct, ptr %st2, i64 %i, i32 0
 144   %y2 = getelementptr inbounds %struct, ptr %st2, i64 %j, i32 1
 145   %z2 = getelementptr inbounds %struct, ptr %st2, i64 %k, i32 2
 146   %x = getelementptr inbounds %struct, ptr %st, i64 %i, i32 0
 147   %y = getelementptr inbounds %struct, ptr %st, i64 %j, i32 1
 148   %z = getelementptr inbounds %struct, ptr %st, i64 %k, i32 2
 149   load i32, ptr %x
 150   load i32, ptr %y
 151   load i32, ptr %z
 152   load i32, ptr %x2
 153   load i32, ptr %y2
 154   load i32, ptr %z2
 155   ret void
 156 }
 157
 158 ; CHECK-LABEL: test_same_underlying_object_different_indices
 159
 160 ; CHECK-DAG: MayAlias: i32* %x, i32* %x2
 161 ; CHECK-DAG: MayAlias: i32* %y, i32* %y2
 162 ; CHECK-DAG: MayAlias: i32* %z, i32* %z2
 163
 164 ; CHECK-DAG: NoAlias: i32* %x, i32* %y2
 165 ; CHECK-DAG: NoAlias: i32* %x, i32* %z2
 166
 167 ; CHECK-DAG: NoAlias: i32* %x2, i32* %y
 168 ; CHECK-DAG: NoAlias: i32* %y, i32* %z2
 169
 170 ; CHECK-DAG: NoAlias: i32* %x2, i32* %z
 171 ; CHECK-DAG: NoAlias: i32* %y2, i32* %z
 172
 173 define void @test_same_underlying_object_different_indices(ptr %st, i64 %i1, i64 %j1, i64 %k1, i64 %i2, i64 %k2, i64 %j2) {
 174   %st2 = getelementptr inbounds %struct, ptr %st, i32 10
 175   %x2 = getelementptr inbounds %struct, ptr %st2, i64 %i2, i32 0
 176   %y2 = getelementptr inbounds %struct, ptr %st2, i64 %j2, i32 1
 177   %z2 = getelementptr inbounds %struct, ptr %st2, i64 %k2, i32 2
 178   %x = getelementptr inbounds %struct, ptr %st, i64 %i1, i32 0
 179   %y = getelementptr inbounds %struct, ptr %st, i64 %j1, i32 1
 180   %z = getelementptr inbounds %struct, ptr %st, i64 %k1, i32 2
 181   load i32, ptr %x
 182   load i32, ptr %y
 183   load i32, ptr %z
 184   load i32, ptr %x2
 185   load i32, ptr %y2
 186   load i32, ptr %z2
 187   ret void
 188 }
 189
 190
 191 %struct2 = type { [1 x { i32, i32 }], [2 x { i32 }] }
 192
 193 ; CHECK-LABEL: test_struct_in_array
 194 ; CHECK-DAG: MustAlias: i32* %x, i32* %y
 195 define void @test_struct_in_array(ptr %st, i64 %i, i64 %j, i64 %k) {
 196   %x = getelementptr inbounds %struct2, ptr %st, i32 0, i32 1, i32 1, i32 0
 197   %y = getelementptr inbounds %struct2, ptr %st, i32 0, i32 0, i32 1, i32 1
 198   load i32, ptr %x
 199   load i32, ptr %y
 200   ret void
 201 }
 202
 203 ; PR27418 - Treat GEP indices with the same value but different types the same
 204 ; CHECK-LABEL: test_different_index_types
 205 ; CHECK: MustAlias: i16* %tmp1, i16* %tmp2
 206 define void @test_different_index_types(ptr %arr) {
 207   %tmp1 = getelementptr inbounds [2 x i16], ptr %arr, i16 0, i32 1
 208   %tmp2 = getelementptr inbounds [2 x i16], ptr %arr, i16 0, i16 1
 209   load i16, ptr %tmp1
 210   load i16, ptr %tmp2
 211   ret void
 212 }