llvm/test/Assembler/ConstantExprNoFold.ll

   1 ; This test checks to make sure that constant exprs don't fold in some simple
   2 ; situations
   3
   4 ; RUN: llvm-as < %s | llvm-dis | FileCheck %s
   5 ; RUN: verify-uselistorder %s
   6
   7 ; Even give it a datalayout, to tempt folding as much as possible.
   8 target datalayout = "p:32:32"
   9
  10 @A = global i64 0
  11 @B = global i64 0
  12
  13 ; Don't fold this. @A might really be allocated next to @B, in which case the
  14 ; icmp should return true. It's not valid to *dereference* in @B from a pointer
  15 ; based on @A, but icmp isn't a dereference.
  16
  17 ; CHECK: @C = global i1 icmp eq (ptr getelementptr inbounds (i64, ptr @A, i64 1), ptr @B)
  18 @C = global i1 icmp eq (ptr getelementptr inbounds (i64, ptr @A, i64 1), ptr @B)
  19
  20 ; Don't fold this completely away either. In theory this could be simplified
  21 ; to only use a gep on one side of the icmp though.
  22
  23 ; CHECK: @D = global i1 icmp eq (ptr getelementptr inbounds (i64, ptr @A, i64 1), ptr getelementptr inbounds (i64, ptr @B, i64 2))
  24 @D = global i1 icmp eq (ptr getelementptr inbounds (i64, ptr @A, i64 1), ptr getelementptr inbounds (i64, ptr @B, i64 2))
  25
  26 ; CHECK: @E = global ptr addrspace(1) addrspacecast (ptr @A to ptr addrspace(1))
  27 @E = global ptr addrspace(1) addrspacecast(ptr @A to ptr addrspace(1))
  28
  29 ; Don't add an inbounds on @weak.gep, since @weak may be null.
  30 ; CHECK: @weak.gep = global ptr getelementptr (i32, ptr @weak, i32 1)
  31 @weak.gep = global ptr getelementptr (i32, ptr @weak, i32 1)
  32 @weak = extern_weak global i32
  33
  34 ; An object with weak linkage cannot have it's identity determined at compile time.
  35 ; CHECK: @F = global i1 icmp eq (ptr @weakany, ptr @glob)
  36 @F = global i1 icmp eq (ptr @weakany, ptr @glob)
  37 @weakany = weak global i32 0
  38
  39 ; Empty globals might end up anywhere, even on top of another global.
  40 ; CHECK: @empty.cmp = global i1 icmp eq (ptr @empty.1, ptr @empty.2)
  41 @empty.1 = external global [0 x i8], align 1
  42 @empty.2 = external global [0 x i8], align 1
  43 @empty.cmp = global i1 icmp eq (ptr @empty.1, ptr @empty.2)
  44
  45 ; Two unnamed_addr globals can share an address
  46 ; CHECK: @unnamed.cmp = global i1 icmp eq (ptr @unnamed.1, ptr @unnamed.2)
  47 @unnamed.1 = unnamed_addr constant [5 x i8] c"asdf\00"
  48 @unnamed.2 = unnamed_addr constant [5 x i8] c"asdf\00"
  49 @unnamed.cmp = global i1 icmp eq (ptr @unnamed.1, ptr @unnamed.2)
  50
  51 @addrspace3 = internal addrspace(3) global i32 undef
  52
  53 ; CHECK: @no.fold.addrspace.icmp.eq.gv.null = global i1 icmp eq (ptr addrspace(3) @addrspace3, ptr addrspace(3) null)
  54 ; CHECK: @no.fold.addrspace.icmp.eq.null.gv = global i1 icmp eq (ptr addrspace(3) @addrspace3, ptr addrspace(3) null)
  55 ; CHECK: @no.fold.addrspace.icmp.ne.gv.null = global i1 icmp ne (ptr addrspace(3) @addrspace3, ptr addrspace(3) null)
  56 ; CHECK: @no.fold.addrspace.icmp.ne.null.gv = global i1 icmp ne (ptr addrspace(3) @addrspace3, ptr addrspace(3) null)
  57 @no.fold.addrspace.icmp.eq.gv.null = global i1 icmp eq (ptr addrspace(3) @addrspace3, ptr addrspace(3) null)
  58 @no.fold.addrspace.icmp.eq.null.gv = global i1 icmp eq (ptr addrspace(3) null, ptr addrspace(3) @addrspace3)
  59 @no.fold.addrspace.icmp.ne.gv.null = global i1 icmp ne (ptr addrspace(3) @addrspace3, ptr addrspace(3) null)
  60 @no.fold.addrspace.icmp.ne.null.gv = global i1 icmp ne (ptr addrspace(3) null, ptr addrspace(3) @addrspace3)
  61
  62 ; Don't add an inbounds on @glob.a3, since it's not inbounds.
  63 ; CHECK: @glob.a3 = alias i32, getelementptr (i32, ptr @glob.a2, i32 1)
  64 @glob = global i32 0
  65 @glob.a3 = alias i32, getelementptr (i32, ptr @glob.a2, i32 1)
  66 @glob.a2 = alias i32, getelementptr (i32, ptr @glob.a1, i32 1)
  67 @glob.a1 = alias i32, ptr @glob