llvm/test/CodeGen/ARM/ParallelDSP/smlald0.ll

   1 ; RUN: opt -mtriple=armv8m.main-none-none-eabi -mattr=+dsp < %s -arm-parallel-dsp -S | FileCheck %s
   2 ; RUN: opt -mtriple=armv8m.maineb-none-none-eabi -mattr=+dsp < %s -arm-parallel-dsp -S | FileCheck %s --check-prefix=CHECK-UNSUPPORTED
   3 ;
   4 ; The Cortex-M0 does not support unaligned accesses:
   5 ; RUN: opt -mtriple=armv6m-none-none-eabi < %s -arm-parallel-dsp -S | FileCheck %s --check-prefix=CHECK-UNSUPPORTED
   6 ;
   7 ; Check DSP extension:
   8 ; RUN: opt -mtriple=armv8m.main-none-none-eabi -mattr=-dsp < %s -arm-parallel-dsp -S | FileCheck %s --check-prefix=CHECK-UNSUPPORTED
   9
  10 define dso_local i64 @OneReduction(i32 %arg, ptr nocapture readnone %arg1, ptr nocapture readonly %arg2, ptr nocapture readonly %arg3) {
  11 ;
  12 ; CHECK-LABEL: @OneReduction
  13 ; CHECK:  %mac1{{\.}}026 = phi i64 [ [[V8:%[0-9]+]], %for.body ], [ 0, %for.body.preheader ]
  14 ; CHECK:  [[V7:%[0-9]+]] = load i32, ptr %arrayidx, align 2
  15 ; CHECK:  [[V5:%[0-9]+]] = load i32, ptr %arrayidx3, align 2
  16 ; CHECK:  [[V8]] = call i64 @llvm.arm.smlald(i32 [[V5]], i32 [[V7]], i64 %mac1{{\.}}026)
  17 ; CHECK-NOT: call i64 @llvm.arm.smlald
  18 ;
  19 ; CHECK-UNSUPPORTED-NOT:  call i64 @llvm.arm.smlald
  20 ;
  21 entry:
  22   %cmp24 = icmp sgt i32 %arg, 0
  23   br i1 %cmp24, label %for.body.preheader, label %for.cond.cleanup
  24
  25 for.body.preheader:
  26   %.pre = load i16, ptr %arg3, align 2
  27   %.pre27 = load i16, ptr %arg2, align 2
  28   br label %for.body
  29
  30 for.cond.cleanup:
  31   %mac1.0.lcssa = phi i64 [ 0, %entry ], [ %add11, %for.body ]
  32   ret i64 %mac1.0.lcssa
  33
  34 for.body:
  35 ; One reduction statement here:
  36   %mac1.026 = phi i64 [ %add11, %for.body ], [ 0, %for.body.preheader ]
  37
  38   %i.025 = phi i32 [ %add, %for.body ], [ 0, %for.body.preheader ]
  39   %arrayidx = getelementptr inbounds i16, ptr %arg3, i32 %i.025
  40   %0 = load i16, ptr %arrayidx, align 2
  41   %add = add nuw nsw i32 %i.025, 1
  42   %arrayidx1 = getelementptr inbounds i16, ptr %arg3, i32 %add
  43   %1 = load i16, ptr %arrayidx1, align 2
  44   %arrayidx3 = getelementptr inbounds i16, ptr %arg2, i32 %i.025
  45   %2 = load i16, ptr %arrayidx3, align 2
  46   %conv = sext i16 %2 to i64
  47   %conv4 = sext i16 %0 to i64
  48   %mul = mul nsw i64 %conv, %conv4
  49   %arrayidx6 = getelementptr inbounds i16, ptr %arg2, i32 %add
  50   %3 = load i16, ptr %arrayidx6, align 2
  51   %conv7 = sext i16 %3 to i64
  52   %conv8 = sext i16 %1 to i64
  53   %mul9 = mul nsw i64 %conv7, %conv8
  54   %add10 = add i64 %mul, %mac1.026
  55
  56 ; Here the Mul is the LHS, and the Add the RHS.
  57   %add11 = add i64 %mul9, %add10
  58
  59   %exitcond = icmp ne i32 %add, %arg
  60   br i1 %exitcond, label %for.body, label %for.cond.cleanup
  61 }
  62
  63 define dso_local arm_aapcs_vfpcc i64 @TwoReductions(i32 %arg, ptr nocapture readnone %arg1, ptr nocapture readonly %arg2, ptr nocapture readonly %arg3) {
  64 ;
  65 ; CHECK-LABEL: @TwoReductions
  66 ;
  67 ; CHECK:  %mac1{{\.}}058 = phi i64 [ [[V10:%[0-9]+]], %for.body ], [ 0, %for.body.preheader ]
  68 ; CHECK:  %mac2{{\.}}057 = phi i64 [ [[V17:%[0-9]+]], %for.body ], [ 0, %for.body.preheader ]
  69 ; CHECK:  [[V10]] = call i64 @llvm.arm.smlald(i32 %{{.*}}, i32 %{{.*}}, i64 %mac1{{\.}}058)
  70 ; CHECK:  [[V17]] = call i64 @llvm.arm.smlald(i32 %{{.*}}, i32 %{{.*}}, i64 %mac2{{\.}}057)
  71 ; CHECK-NOT: call i64 @llvm.arm.smlald
  72 ;
  73 entry:
  74   %cmp55 = icmp sgt i32 %arg, 0
  75   br i1 %cmp55, label %for.body.preheader, label %for.cond.cleanup
  76
  77 for.cond.cleanup:
  78   %mac2.0.lcssa = phi i64 [ 0, %entry ], [ %add28, %for.body ]
  79   %mac1.0.lcssa = phi i64 [ 0, %entry ], [ %add16, %for.body ]
  80   %add30 = add nsw i64 %mac1.0.lcssa, %mac2.0.lcssa
  81   ret i64 %add30
  82
  83 for.body.preheader:
  84   br label %for.body
  85
  86 for.body:
  87 ; And two reduction statements here:
  88   %mac1.058 = phi i64 [ %add16, %for.body ], [ 0, %for.body.preheader ]
  89   %mac2.057 = phi i64 [ %add28, %for.body ], [ 0, %for.body.preheader ]
  90
  91   %i.056 = phi i32 [ %add29, %for.body ], [ 0, %for.body.preheader ]
  92   %arrayidx = getelementptr inbounds i16, ptr %arg3, i32 %i.056
  93   %0 = load i16, ptr %arrayidx, align 2
  94   %add1 = or i32 %i.056, 1
  95   %arrayidx2 = getelementptr inbounds i16, ptr %arg3, i32 %add1
  96   %1 = load i16, ptr %arrayidx2, align 2
  97   %add3 = or i32 %i.056, 2
  98   %arrayidx4 = getelementptr inbounds i16, ptr %arg3, i32 %add3
  99   %2 = load i16, ptr %arrayidx4, align 2
 100
 101   %add5 = or i32 %i.056, 3
 102   %arrayidx6 = getelementptr inbounds i16, ptr %arg3, i32 %add5
 103   %3 = load i16, ptr %arrayidx6, align 2
 104   %arrayidx8 = getelementptr inbounds i16, ptr %arg2, i32 %i.056
 105   %4 = load i16, ptr %arrayidx8, align 2
 106   %conv = sext i16 %4 to i64
 107   %conv9 = sext i16 %0 to i64
 108   %mul = mul nsw i64 %conv, %conv9
 109   %arrayidx11 = getelementptr inbounds i16, ptr %arg2, i32 %add1
 110   %5 = load i16, ptr %arrayidx11, align 2
 111   %conv12 = sext i16 %5 to i64
 112   %conv13 = sext i16 %1 to i64
 113   %mul14 = mul nsw i64 %conv12, %conv13
 114   %add15 = add i64 %mul, %mac1.058
 115   %add16 = add i64 %add15, %mul14
 116   %arrayidx18 = getelementptr inbounds i16, ptr %arg2, i32 %add3
 117   %6 = load i16, ptr %arrayidx18, align 2
 118   %conv19 = sext i16 %6 to i64
 119   %conv20 = sext i16 %2 to i64
 120   %mul21 = mul nsw i64 %conv19, %conv20
 121   %arrayidx23 = getelementptr inbounds i16, ptr %arg2, i32 %add5
 122   %7 = load i16, ptr %arrayidx23, align 2
 123   %conv24 = sext i16 %7 to i64
 124   %conv25 = sext i16 %3 to i64
 125   %mul26 = mul nsw i64 %conv24, %conv25
 126   %add27 = add i64 %mul21, %mac2.057
 127   %add28 = add i64 %add27, %mul26
 128   %add29 = add nuw nsw i32 %i.056, 4
 129   %cmp = icmp slt i32 %add29, %arg
 130   br i1 %cmp, label %for.body, label %for.cond.cleanup
 131 }
 132
 133 define i64 @reduction_zext(i32 %arg, ptr nocapture readnone %arg1, ptr nocapture readonly %arg2, ptr nocapture readonly %arg3) {
 134 ; CHECK-LABEL: @reduction_zext
 135 ; CHECK-NOT: call i64 @llvm.arm.smlald
 136 ; CHECK-NOT: call i32 @llvm.arm.smlad
 137 entry:
 138   %cmp24 = icmp sgt i32 %arg, 0
 139   br i1 %cmp24, label %for.body.preheader, label %for.cond.cleanup
 140
 141 for.body.preheader:
 142   %.pre = load i16, ptr %arg3, align 2
 143   %.pre27 = load i16, ptr %arg2, align 2
 144   br label %for.body
 145
 146 for.cond.cleanup:
 147   %mac1.0.lcssa = phi i64 [ 0, %entry ], [ %add11, %for.body ]
 148   ret i64 %mac1.0.lcssa
 149
 150 for.body:
 151   %mac1.026 = phi i64 [ %add11, %for.body ], [ 0, %for.body.preheader ]
 152   %i.025 = phi i32 [ %add, %for.body ], [ 0, %for.body.preheader ]
 153   %arrayidx = getelementptr inbounds i16, ptr %arg3, i32 %i.025
 154   %0 = load i16, ptr %arrayidx, align 2
 155   %add = add nuw nsw i32 %i.025, 1
 156   %arrayidx1 = getelementptr inbounds i16, ptr %arg3, i32 %add
 157   %1 = load i16, ptr %arrayidx1, align 2
 158   %arrayidx3 = getelementptr inbounds i16, ptr %arg2, i32 %i.025
 159   %2 = load i16, ptr %arrayidx3, align 2
 160   %conv = sext i16 %2 to i64
 161   %conv4 = zext i16 %0 to i64
 162   %mul = mul nsw i64 %conv, %conv4
 163   %arrayidx6 = getelementptr inbounds i16, ptr %arg2, i32 %add
 164   %3 = load i16, ptr %arrayidx6, align 2
 165   %conv7 = sext i16 %3 to i64
 166   %conv8 = zext i16 %1 to i64
 167   %mul9 = mul nsw i64 %conv7, %conv8
 168   %add10 = add i64 %mul, %mac1.026
 169   %add11 = add i64 %mul9, %add10
 170   %exitcond = icmp ne i32 %add, %arg
 171   br i1 %exitcond, label %for.body, label %for.cond.cleanup
 172 }