llvm/test/CodeGen/X86/win32-seh-catchpad-realign.ll

   1 ; RUN: llc -stack-symbol-ordering=0 < %s | FileCheck %s
   2
   3 ; The aligned alloca means that we have to realign the stack, which forces the
   4 ; use of ESI to address local variables.
   5
   6 target datalayout = "e-m:x-p:32:32-i64:64-f80:32-n8:16:32-a:0:32-S32"
   7 target triple = "i686--windows-msvc"
   8
   9 ; Function Attrs: nounwind
  10 define void @realigned_try() personality ptr @_except_handler3 {
  11 entry:
  12   %x = alloca [4 x i32], align 16
  13   invoke void @useit(ptr %x)
  14           to label %__try.cont unwind label %catch.dispatch
  15
  16 catch.dispatch:                                   ; preds = %entry
  17   %cs1 = catchswitch within none [label %__except.ret] unwind to caller
  18
  19 __except.ret:                                     ; preds = %catch.dispatch
  20   %pad = catchpad within %cs1 [ptr @"\01?filt$0@0@realigned_try@@"]
  21   catchret from %pad to label %__try.cont
  22
  23 __try.cont:                                       ; preds = %entry, %__except.ret
  24   ret void
  25 }
  26
  27 ; Function Attrs: nounwind argmemonly
  28
  29 ; Function Attrs: nounwind
  30 define internal i32 @"\01?filt$0@0@realigned_try@@"() {
  31 entry:
  32   ret i32 1
  33 }
  34
  35 declare void @useit(ptr)
  36
  37 declare i32 @_except_handler3(...)
  38
  39 ; CHECK-LABEL: _realigned_try:
  40 ; Prologue
  41 ; CHECK: pushl   %ebp
  42 ; CHECK: movl    %esp, %ebp
  43 ; CHECK: pushl   %ebx
  44 ; CHECK: pushl   %edi
  45 ; CHECK: pushl   %esi
  46 ; CHECK: andl    $-16, %esp
  47 ; CHECK: subl    $64, %esp
  48 ; CHECK: movl    %esp, %esi
  49 ; Spill EBP
  50 ; CHECK: movl    %ebp, 12(%esi)
  51 ; Spill ESP
  52 ; CHECK: movl    %esp, 36(%esi)
  53 ; The state is stored at ESI+56, the end of the node is ESI+60.
  54 ; CHECK: movl    $-1, 56(%esi)
  55 ;
  56 ; __try
  57 ; CHECK: calll _useit
  58 ;
  59 ; Epilogue
  60 ; CHECK: LBB0_2:       # %__try.cont
  61 ; CHECK: leal    -12(%ebp), %esp
  62 ; CHECK: popl    %esi
  63 ; CHECK: popl    %edi
  64 ; CHECK: popl    %ebx
  65 ; CHECK: popl    %ebp
  66 ; CHECK: retl
  67 ;
  68 ; CHECK: LBB0_1:                                 # %__except.ret
  69 ; Restore ESP
  70 ; CHECK: movl    -24(%ebp), %esp
  71 ; Recompute ESI by subtracting 60 from the end of the registration node.
  72 ; CHECK: leal    -60(%ebp), %esi
  73 ; Restore EBP
  74 ; CHECK: movl    12(%esi), %ebp
  75 ; Rejoin normal control flow
  76 ; CHECK: jmp     LBB0_2