llvm/test/Instrumentation/DataFlowSanitizer/union.ll

   1 ; RUN: opt < %s -passes=dfsan -S | FileCheck %s
   2 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   3 target triple = "x86_64-unknown-linux-gnu"
   4
   5 @a = common global i32 0
   6 @b = common global i32 0
   7
   8 ; Check that we reuse unions where possible.
   9
  10 ; CHECK-LABEL: @f.dfsan
  11 define void @f(i32 %x, i32 %y) {
  12   ; CHECK: or i8
  13   %xay = add i32 %x, %y
  14   store i32 %xay, ptr @a
  15   ; CHECK-NOT: or i8
  16   %xmy = mul i32 %x, %y
  17   store i32 %xmy, ptr @b
  18   ret void
  19 }
  20
  21 ; In this case, we compute the unions on both sides because neither block
  22 ; dominates the other.
  23
  24 ; CHECK-LABEL: @g.dfsan
  25 define void @g(i1 %p, i32 %x, i32 %y) {
  26   br i1 %p, label %l1, label %l2
  27
  28 l1:
  29   ; CHECK: or i8
  30   %xay = add i32 %x, %y
  31   store i32 %xay, ptr @a
  32   br label %l3
  33
  34 l2:
  35   ; CHECK: or i8
  36   %xmy = mul i32 %x, %y
  37   store i32 %xmy, ptr @b
  38   br label %l3
  39
  40 l3:
  41   ret void
  42 }
  43
  44 ; In this case, we know that the label for %xayax subsumes the label for %xay.
  45
  46 ; CHECK-LABEL: @h.dfsan
  47 define i32 @h(i32 %x, i32 %y) {
  48   ; CHECK: or i8
  49   %xay = add i32 %x, %y
  50   ; CHECK-NOT: or i8
  51   %xayax = add i32 %xay, %x
  52   ret i32 %xayax
  53 }