llvm/test/ThinLTO/X86/devirt.ll

   1 ; REQUIRES: x86-registered-target
   2
   3 ; Test devirtualization through the thin link and backend.
   4
   5 ; Generate split module with summary for hybrid Thin/Regular LTO WPD.
   6 ; RUN: opt -thinlto-bc -thinlto-split-lto-unit -o %t.o %s
   7
   8 ; Check that we have module flag showing splitting enabled, and that we don't
   9 ; generate summary information needed for index-based WPD.
  10 ; RUN: llvm-modextract -b -n=0 %t.o -o %t.o.0
  11 ; RUN: llvm-dis -o - %t.o.0 | FileCheck %s --check-prefix=ENABLESPLITFLAG --implicit-check-not=vTableFuncs --implicit-check-not=typeidCompatibleVTable
  12 ; RUN: llvm-modextract -b -n=1 %t.o -o %t.o.1
  13 ; RUN: llvm-dis -o - %t.o.1 | FileCheck %s --check-prefix=ENABLESPLITFLAG --implicit-check-not=vTableFuncs --implicit-check-not=typeidCompatibleVTable
  14 ; ENABLESPLITFLAG: !{i32 1, !"EnableSplitLTOUnit", i32 1}
  15
  16 ; Generate unsplit module with summary for ThinLTO index-based WPD.
  17 ; RUN: opt -thinlto-bc -o %t2.o %s
  18
  19 ; Check that we don't have module flag when splitting not enabled for ThinLTO,
  20 ; and that we generate summary information needed for index-based WPD.
  21 ; RUN: llvm-dis -o - %t2.o | FileCheck %s --check-prefix=NOENABLESPLITFLAG
  22 ; NOENABLESPLITFLAG-DAG: !{i32 1, !"EnableSplitLTOUnit", i32 0}
  23 ; NOENABLESPLITFLAG-DAG: [[An:\^[0-9]+]] = gv: (name: "_ZN1A1nEi"
  24 ; NOENABLESPLITFLAG-DAG: [[Bf:\^[0-9]+]] = gv: (name: "_ZN1B1fEi"
  25 ; NOENABLESPLITFLAG-DAG: [[Cf:\^[0-9]+]] = gv: (name: "_ZN1C1fEi"
  26 ; NOENABLESPLITFLAG-DAG: [[Dm:\^[0-9]+]] = gv: (name: "_ZN1D1mEi"
  27 ; NOENABLESPLITFLAG-DAG: [[B:\^[0-9]+]] = gv: (name: "_ZTV1B", {{.*}} vTableFuncs: ((virtFunc: [[Bf]], offset: 16), (virtFunc: [[An]], offset: 24)), refs: ([[Bf]], [[An]])
  28 ; NOENABLESPLITFLAG-DAG: [[C:\^[0-9]+]] = gv: (name: "_ZTV1C", {{.*}} vTableFuncs: ((virtFunc: [[Cf]], offset: 16), (virtFunc: [[An]], offset: 24)), refs: ([[An]], [[Cf]])
  29 ; NOENABLESPLITFLAG-DAG: [[D:\^[0-9]+]] = gv: (name: "_ZTV1D", {{.*}} vTableFuncs: ((virtFunc: [[Dm]], offset: 16)), refs: ([[Dm]])
  30 ; NOENABLESPLITFLAG-DAG: typeidCompatibleVTable: (name: "_ZTS1A", summary: ((offset: 16, [[B]]), (offset: 16, [[C]])))
  31 ; NOENABLESPLITFLAG-DAG: typeidCompatibleVTable: (name: "_ZTS1B", summary: ((offset: 16, [[B]])))
  32 ; NOENABLESPLITFLAG-DAG: typeidCompatibleVTable: (name: "_ZTS1C", summary: ((offset: 16, [[C]])))
  33 ; Type Id on _ZTV1D should have been promoted
  34 ; NOENABLESPLITFLAG-DAG: typeidCompatibleVTable: (name: "1.{{.*}}", summary: ((offset: 16, [[D]])))
  35
  36 ; Index based WPD
  37 ; RUN: llvm-lto2 run %t2.o -save-temps -pass-remarks=. \
  38 ; RUN:   -whole-program-visibility \
  39 ; RUN:   -o %t3 \
  40 ; RUN:   -r=%t2.o,test,px \
  41 ; RUN:   -r=%t2.o,_ZN1A1nEi,p \
  42 ; RUN:   -r=%t2.o,_ZN1B1fEi,p \
  43 ; RUN:   -r=%t2.o,_ZN1C1fEi,p \
  44 ; RUN:   -r=%t2.o,_ZN1D1mEi,p \
  45 ; RUN:   -r=%t2.o,_ZTV1B,px \
  46 ; RUN:   -r=%t2.o,_ZTV1C,px \
  47 ; RUN:   -r=%t2.o,_ZTV1D,px 2>&1 | FileCheck %s --check-prefix=REMARK
  48 ; RUN: llvm-dis %t3.1.4.opt.bc -o - | FileCheck %s --check-prefix=CHECK-IR
  49
  50 ; Check that we're able to prevent specific function from being
  51 ; devirtualized when running index based WPD.
  52 ; RUN: llvm-lto2 run %t2.o -save-temps -pass-remarks=. \
  53 ; RUN:   -whole-program-visibility \
  54 ; RUN:   -wholeprogramdevirt-skip=_ZN1A1nEi \
  55 ; RUN:   -o %t3 \
  56 ; RUN:   -r=%t2.o,test,px \
  57 ; RUN:   -r=%t2.o,_ZN1A1nEi,p \
  58 ; RUN:   -r=%t2.o,_ZN1B1fEi,p \
  59 ; RUN:   -r=%t2.o,_ZN1C1fEi,p \
  60 ; RUN:   -r=%t2.o,_ZN1D1mEi,p \
  61 ; RUN:   -r=%t2.o,_ZTV1B,px \
  62 ; RUN:   -r=%t2.o,_ZTV1C,px \
  63 ; RUN:   -r=%t2.o,_ZTV1D,px 2>&1 | FileCheck %s --check-prefix=SKIP
  64
  65 ; RUN: llvm-lto2 run %t.o -save-temps -pass-remarks=. \
  66 ; RUN:   -whole-program-visibility \
  67 ; RUN:   -o %t3 \
  68 ; RUN:   -r=%t.o,test,px \
  69 ; RUN:   -r=%t.o,_ZN1A1nEi,p \
  70 ; RUN:   -r=%t.o,_ZN1B1fEi,p \
  71 ; RUN:   -r=%t.o,_ZN1C1fEi,p \
  72 ; RUN:   -r=%t.o,_ZN1D1mEi,p \
  73 ; RUN:   -r=%t.o,_ZTV1B, \
  74 ; RUN:   -r=%t.o,_ZTV1C, \
  75 ; RUN:   -r=%t.o,_ZTV1D, \
  76 ; RUN:   -r=%t.o,_ZN1A1nEi, \
  77 ; RUN:   -r=%t.o,_ZN1B1fEi, \
  78 ; RUN:   -r=%t.o,_ZN1C1fEi, \
  79 ; RUN:   -r=%t.o,_ZN1D1mEi, \
  80 ; RUN:   -r=%t.o,_ZTV1B,px \
  81 ; RUN:   -r=%t.o,_ZTV1C,px \
  82 ; RUN:   -r=%t.o,_ZTV1D,px 2>&1 | FileCheck %s --check-prefix=REMARK --dump-input=fail
  83 ; RUN: llvm-dis %t3.1.4.opt.bc -o - | FileCheck %s --check-prefix=CHECK-IR
  84
  85 ; REMARK-DAG: single-impl: devirtualized a call to _ZN1A1nEi
  86 ; REMARK-DAG: single-impl: devirtualized a call to _ZN1D1mEi
  87
  88 ; SKIP-NOT: devirtualized a call to _ZN1A1nEi
  89
  90 target datalayout = "e-m:e-p270:32:32-p271:32:32-p272:64:64-i64:64-f80:128-n8:16:32:64-S128"
  91 target triple = "x86_64-grtev4-linux-gnu"
  92
  93 %struct.A = type { ptr }
  94 %struct.B = type { %struct.A }
  95 %struct.C = type { %struct.A }
  96 %struct.D = type { ptr }
  97
  98 @_ZTV1B = constant { [4 x ptr] } { [4 x ptr] [ptr null, ptr undef, ptr @_ZN1B1fEi, ptr @_ZN1A1nEi] }, !type !0, !type !1
  99 @_ZTV1C = constant { [4 x ptr] } { [4 x ptr] [ptr null, ptr undef, ptr @_ZN1C1fEi, ptr @_ZN1A1nEi] }, !type !0, !type !2
 100 @_ZTV1D = constant { [3 x ptr] } { [3 x ptr] [ptr null, ptr undef, ptr @_ZN1D1mEi] }, !type !3
 101
 102
 103 ; CHECK-IR-LABEL: define i32 @test
 104 define i32 @test(ptr %obj, ptr %obj2, i32 %a) {
 105 entry:
 106   %vtable = load ptr, ptr %obj
 107   %p = call i1 @llvm.type.test(ptr %vtable, metadata !"_ZTS1A")
 108   call void @llvm.assume(i1 %p)
 109   %fptrptr = getelementptr ptr, ptr %vtable, i32 1
 110   %fptr1 = load ptr, ptr %fptrptr, align 8
 111
 112   ; Check that the call was devirtualized.
 113   ; CHECK-IR: %call = tail call i32 @_ZN1A1nEi
 114   ; Ensure !prof and !callees metadata for indirect call promotion removed.
 115   ; CHECK-IR-NOT: prof
 116   ; CHECK-IR-NOT: callees
 117   %call = tail call i32 %fptr1(ptr nonnull %obj, i32 %a), !prof !5, !callees !6
 118
 119   %fptr22 = load ptr, ptr %vtable, align 8
 120
 121   ; We still have to call it as virtual.
 122   ; CHECK-IR: %call3 = tail call i32 %fptr22
 123   %call3 = tail call i32 %fptr22(ptr nonnull %obj, i32 %call)
 124
 125   %vtable2 = load ptr, ptr %obj2
 126   %p2 = call i1 @llvm.type.test(ptr %vtable2, metadata !4)
 127   call void @llvm.assume(i1 %p2)
 128
 129   %fptr33 = load ptr, ptr %vtable2, align 8
 130
 131   ; Check that the call was devirtualized.
 132   ; CHECK-IR: %call4 = tail call i32 @_ZN1D1mEi
 133   %call4 = tail call i32 %fptr33(ptr nonnull %obj2, i32 %call3)
 134   ret i32 %call4
 135 }
 136 ; CHECK-IR-LABEL: ret i32
 137 ; CHECK-IR-LABEL: }
 138
 139 declare i1 @llvm.type.test(ptr, metadata)
 140 declare void @llvm.assume(i1)
 141
 142 define i32 @_ZN1B1fEi(ptr %this, i32 %a) #0 {
 143    ret i32 0;
 144 }
 145
 146 define i32 @_ZN1A1nEi(ptr %this, i32 %a) #0 {
 147    ret i32 0;
 148 }
 149
 150 define i32 @_ZN1C1fEi(ptr %this, i32 %a) #0 {
 151    ret i32 0;
 152 }
 153
 154 define i32 @_ZN1D1mEi(ptr %this, i32 %a) #0 {
 155    ret i32 0;
 156 }
 157
 158 ; Make sure we don't inline or otherwise optimize out the direct calls.
 159 attributes #0 = { noinline optnone }
 160
 161 !0 = !{i64 16, !"_ZTS1A"}
 162 !1 = !{i64 16, !"_ZTS1B"}
 163 !2 = !{i64 16, !"_ZTS1C"}
 164 !3 = !{i64 16, !4}
 165 !4 = distinct !{}
 166 !5 = !{!"VP", i32 0, i64 1, i64 1621563287929432257, i64 1}
 167 !6 = !{ptr @_ZN1A1nEi}