llvm/cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckStructHasMember)
  11 include(CheckCCompilerFlag)
  12 include(CMakePushCheckState)
  13
  14 include(CheckCompilerVersion)
  15 include(CheckProblematicConfigurations)
  16 include(HandleLLVMStdlib)
  17
  18 if( UNIX AND NOT (APPLE OR BEOS OR HAIKU) )
  19   # Used by check_symbol_exists:
  20   list(APPEND CMAKE_REQUIRED_LIBRARIES "m")
  21 endif()
  22 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  23 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  24     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  25   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  26 endif()
  27
  28 # Do checks with _XOPEN_SOURCE and large-file API on AIX, because we will build
  29 # with those too.
  30 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
  31           list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_XOPEN_SOURCE=700")
  32           list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_LARGE_FILE_API")
  33 endif()
  34
  35 # Do checks with _FILE_OFFSET_BITS=64 on Solaris, because we will build
  36 # with those too.
  37 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  38           list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_FILE_OFFSET_BITS=64")
  39 endif()
  40
  41 # include checks
  42 check_include_file(dlfcn.h HAVE_DLFCN_H)
  43 check_include_file(errno.h HAVE_ERRNO_H)
  44 check_include_file(fcntl.h HAVE_FCNTL_H)
  45 check_include_file(link.h HAVE_LINK_H)
  46 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  47 if( NOT PURE_WINDOWS )
  48   check_include_file(pthread.h HAVE_PTHREAD_H)
  49 endif()
  50 check_include_file(signal.h HAVE_SIGNAL_H)
  51 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  52 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  53 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  54 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  55 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  56 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  57 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  58 check_include_file(sysexits.h HAVE_SYSEXITS_H)
  59 check_include_file(termios.h HAVE_TERMIOS_H)
  60 check_include_file(unistd.h HAVE_UNISTD_H)
  61 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  62 check_include_file(fenv.h HAVE_FENV_H)
  63 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  64 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  65
  66 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  67 check_include_file(CrashReporterClient.h HAVE_CRASHREPORTERCLIENT_H)
  68 if(APPLE)
  69   include(CheckCSourceCompiles)
  70   CHECK_C_SOURCE_COMPILES("
  71      static const char *__crashreporter_info__ = 0;
  72      asm(\".desc ___crashreporter_info__, 0x10\");
  73      int main() { return 0; }"
  74     HAVE_CRASHREPORTER_INFO)
  75 endif()
  76
  77 if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  78   check_include_file(linux/magic.h HAVE_LINUX_MAGIC_H)
  79   if(NOT HAVE_LINUX_MAGIC_H)
  80     # older kernels use split files
  81     check_include_file(linux/nfs_fs.h HAVE_LINUX_NFS_FS_H)
  82     check_include_file(linux/smb.h HAVE_LINUX_SMB_H)
  83   endif()
  84 endif()
  85
  86 # library checks
  87 if( NOT PURE_WINDOWS )
  88   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  89   if (HAVE_LIBPTHREAD)
  90     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  91     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  92   else()
  93     # this could be Android
  94     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  95     if (PTHREAD_IN_LIBC)
  96       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  97       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  98     endif()
  99   endif()
 100   check_library_exists(dl dlopen "" HAVE_LIBDL)
 101   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 102 endif()
 103
 104 # Check for libpfm.
 105 include(FindLibpfm)
 106
 107 if(HAVE_LIBPTHREAD)
 108   # We want to find pthreads library and at the moment we do want to
 109   # have it reported as '-l<lib>' instead of '-pthread'.
 110   # TODO: switch to -pthread once the rest of the build system can deal with it.
 111   set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 112   set(THREADS_HAVE_PTHREAD_ARG Off)
 113   find_package(Threads REQUIRED)
 114   set(LLVM_PTHREAD_LIB ${CMAKE_THREAD_LIBS_INIT})
 115 endif()
 116
 117 if(LLVM_ENABLE_ZLIB)
 118   if(LLVM_ENABLE_ZLIB STREQUAL FORCE_ON)
 119     find_package(ZLIB REQUIRED)
 120   elseif(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 121     find_package(ZLIB)
 122   endif()
 123   if(ZLIB_FOUND)
 124     # Check if zlib we found is usable; for example, we may have found a 32-bit
 125     # library on a 64-bit system which would result in a link-time failure.
 126     cmake_push_check_state()
 127     list(APPEND CMAKE_REQUIRED_INCLUDES ${ZLIB_INCLUDE_DIRS})
 128     list(APPEND CMAKE_REQUIRED_LIBRARIES ${ZLIB_LIBRARY})
 129     check_symbol_exists(compress2 zlib.h HAVE_ZLIB)
 130     cmake_pop_check_state()
 131     if(LLVM_ENABLE_ZLIB STREQUAL FORCE_ON AND NOT HAVE_ZLIB)
 132       message(FATAL_ERROR "Failed to configure zlib")
 133     endif()
 134   endif()
 135   set(LLVM_ENABLE_ZLIB "${HAVE_ZLIB}")
 136 endif()
 137
 138 if(LLVM_ENABLE_LIBXML2)
 139   if(LLVM_ENABLE_LIBXML2 STREQUAL FORCE_ON)
 140     find_package(LibXml2 REQUIRED)
 141   elseif(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 142     find_package(LibXml2)
 143   endif()
 144   if(LibXml2_FOUND)
 145     # Check if libxml2 we found is usable; for example, we may have found a 32-bit
 146     # library on a 64-bit system which would result in a link-time failure.
 147     cmake_push_check_state()
 148     list(APPEND CMAKE_REQUIRED_INCLUDES ${LIBXML2_INCLUDE_DIRS})
 149     list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBXML2_LIBRARIES})
 150     list(APPEND CMAKE_REQUIRED_DEFINITIONS ${LIBXML2_DEFINITIONS})
 151     check_symbol_exists(xmlReadMemory libxml/xmlreader.h HAVE_LIBXML2)
 152     cmake_pop_check_state()
 153     if(LLVM_ENABLE_LIBXML2 STREQUAL FORCE_ON AND NOT HAVE_LIBXML2)
 154       message(FATAL_ERROR "Failed to configure libxml2")
 155     endif()
 156   endif()
 157   set(LLVM_ENABLE_LIBXML2 "${HAVE_LIBXML2}")
 158 endif()
 159
 160 if(LLVM_ENABLE_CURL)
 161   if(LLVM_ENABLE_CURL STREQUAL FORCE_ON)
 162     find_package(CURL REQUIRED)
 163   else()
 164     find_package(CURL)
 165   endif()
 166   if(CURL_FOUND)
 167     # Check if curl we found is usable; for example, we may have found a 32-bit
 168     # library on a 64-bit system which would result in a link-time failure.
 169     cmake_push_check_state()
 170     list(APPEND CMAKE_REQUIRED_LIBRARIES CURL::libcurl)
 171     check_symbol_exists(curl_easy_init curl/curl.h HAVE_CURL)
 172     cmake_pop_check_state()
 173     if(LLVM_ENABLE_CURL STREQUAL FORCE_ON AND NOT HAVE_CURL)
 174       message(FATAL_ERROR "Failed to configure curl")
 175     endif()
 176   endif()
 177   set(LLVM_ENABLE_CURL "${HAVE_CURL}")
 178 endif()
 179
 180 # Don't look for these libraries if we're using MSan, since uninstrumented third
 181 # party code may call MSan interceptors like strlen, leading to false positives.
 182 if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 183   # Don't look for these libraries on Windows.
 184   if (NOT PURE_WINDOWS)
 185     # Skip libedit if using ASan as it contains memory leaks.
 186     if (LLVM_ENABLE_LIBEDIT AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*")
 187       find_package(LibEdit)
 188       set(HAVE_LIBEDIT ${LibEdit_FOUND})
 189     else()
 190       set(HAVE_LIBEDIT 0)
 191     endif()
 192     if(LLVM_ENABLE_TERMINFO)
 193       if(LLVM_ENABLE_TERMINFO STREQUAL FORCE_ON)
 194         find_package(Terminfo REQUIRED)
 195       else()
 196         find_package(Terminfo)
 197       endif()
 198       set(LLVM_ENABLE_TERMINFO "${Terminfo_FOUND}")
 199     endif()
 200   else()
 201     set(LLVM_ENABLE_TERMINFO 0)
 202   endif()
 203 else()
 204   set(LLVM_ENABLE_TERMINFO 0)
 205 endif()
 206
 207 check_library_exists(xar xar_open "" LLVM_HAVE_LIBXAR)
 208 if(LLVM_HAVE_LIBXAR)
 209   message(STATUS "The xar file format has been deprecated: LLVM_HAVE_LIBXAR might be removed in the future.")
 210   # The xar file format has been deprecated since macOS 12.0.
 211   if (CMAKE_OSX_DEPLOYMENT_TARGET VERSION_GREATER_EQUAL 12)
 212     set(LLVM_HAVE_LIBXAR 0)
 213   else()
 214     set(XAR_LIB xar)
 215   endif()
 216 endif()
 217
 218 # function checks
 219 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 220 find_package(Backtrace)
 221 set(HAVE_BACKTRACE ${Backtrace_FOUND})
 222 set(BACKTRACE_HEADER ${Backtrace_HEADER})
 223
 224 # Prevent check_symbol_exists from using API that is not supported for a given
 225 # deployment target.
 226 check_c_compiler_flag("-Werror=unguarded-availability-new" "C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW")
 227 if(C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW)
 228   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror=unguarded-availability-new")
 229 endif()
 230
 231 # Determine whether we can register EH tables.
 232 check_symbol_exists(__register_frame "${CMAKE_CURRENT_LIST_DIR}/unwind.h" HAVE_REGISTER_FRAME)
 233 check_symbol_exists(__deregister_frame "${CMAKE_CURRENT_LIST_DIR}/unwind.h" HAVE_DEREGISTER_FRAME)
 234 check_symbol_exists(__unw_add_dynamic_fde "${CMAKE_CURRENT_LIST_DIR}/unwind.h" HAVE_UNW_ADD_DYNAMIC_FDE)
 235
 236 check_symbol_exists(_Unwind_Backtrace "unwind.h" HAVE__UNWIND_BACKTRACE)
 237 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 238 check_symbol_exists(sysconf unistd.h HAVE_SYSCONF)
 239 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 240 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 241 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 242 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 243 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 244 # AddressSanitizer conflicts with lib/Support/Unix/Signals.inc
 245 # Avoid sigaltstack on Apple platforms, where backtrace() cannot handle it
 246 # (rdar://7089625) and _Unwind_Backtrace is unusable because it cannot unwind
 247 # past the signal handler after an assertion failure (rdar://29866587).
 248 if( HAVE_SIGNAL_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*" AND NOT APPLE )
 249   check_symbol_exists(sigaltstack signal.h HAVE_SIGALTSTACK)
 250 endif()
 251 set(CMAKE_REQUIRED_DEFINITIONS "-D_LARGEFILE64_SOURCE")
 252 check_symbol_exists(lseek64 "sys/types.h;unistd.h" HAVE_LSEEK64)
 253 set(CMAKE_REQUIRED_DEFINITIONS "")
 254 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
 255 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 256 check_symbol_exists(mallinfo2 malloc.h HAVE_MALLINFO2)
 257 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 258                     HAVE_MALLOC_ZONE_STATISTICS)
 259 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 260 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 261 check_symbol_exists(pread unistd.h HAVE_PREAD)
 262 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 263 check_symbol_exists(strerror string.h HAVE_STRERROR)
 264 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 265 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 266 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 267 if( PURE_WINDOWS )
 268   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 269
 270   check_function_exists(_alloca HAVE__ALLOCA)
 271   check_function_exists(__alloca HAVE___ALLOCA)
 272   check_function_exists(__chkstk HAVE___CHKSTK)
 273   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
 274   check_function_exists(___chkstk HAVE____CHKSTK)
 275   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
 276
 277   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 278   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 279   check_function_exists(__divdi3 HAVE___DIVDI3)
 280   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 281   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 282   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 283   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 284   check_function_exists(__moddi3 HAVE___MODDI3)
 285   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 286   check_function_exists(__umoddi3 HAVE___UMODDI3)
 287
 288   check_function_exists(__main HAVE___MAIN)
 289   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 290 endif()
 291 if( HAVE_DLFCN_H )
 292   if( HAVE_LIBDL )
 293     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 294   endif()
 295   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 296   check_symbol_exists(dladdr dlfcn.h HAVE_DLADDR)
 297   if( HAVE_LIBDL )
 298     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 299   endif()
 300 endif()
 301
 302 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec
 303     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC)
 304 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 305 # The st_mtim.tv_nsec member of a `stat` structure is not reliable on some AIX
 306 # environments.
 307   set(HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC 0)
 308 else()
 309   CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec
 310       "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC)
 311 endif()
 312
 313 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 314 if( LLVM_USING_GLIBC )
 315   add_definitions( -D_GNU_SOURCE )
 316   list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
 317 endif()
 318 # This check requires _GNU_SOURCE
 319 if (NOT PURE_WINDOWS)
 320   if (LLVM_PTHREAD_LIB)
 321     list(APPEND CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 322   endif()
 323   check_symbol_exists(pthread_getname_np pthread.h HAVE_PTHREAD_GETNAME_NP)
 324   check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 325   if (LLVM_PTHREAD_LIB)
 326     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 327   endif()
 328 endif()
 329
 330 # available programs checks
 331 function(llvm_find_program name)
 332   string(TOUPPER ${name} NAME)
 333   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 334
 335   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 336   mark_as_advanced(LLVM_PATH_${NAME})
 337   if(LLVM_PATH_${NAME})
 338     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 339     mark_as_advanced(HAVE_${NAME})
 340   else(LLVM_PATH_${NAME})
 341     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 342   endif(LLVM_PATH_${NAME})
 343 endfunction()
 344
 345 if (LLVM_ENABLE_DOXYGEN)
 346   llvm_find_program(dot)
 347 endif ()
 348
 349 if(LLVM_ENABLE_FFI)
 350   set(FFI_REQUIRE_INCLUDE On)
 351   if(LLVM_ENABLE_FFI STREQUAL FORCE_ON)
 352     find_package(FFI REQUIRED)
 353   else()
 354     find_package(FFI)
 355   endif()
 356   set(LLVM_ENABLE_FFI "${FFI_FOUND}")
 357 else()
 358   unset(HAVE_FFI_FFI_H CACHE)
 359   unset(HAVE_FFI_H CACHE)
 360   unset(HAVE_FFI_CALL CACHE)
 361 endif()
 362
 363 check_symbol_exists(proc_pid_rusage "libproc.h" HAVE_PROC_PID_RUSAGE)
 364
 365 # Whether we can use std::is_trivially_copyable to verify llvm::is_trivially_copyable.
 366 CHECK_CXX_SOURCE_COMPILES("
 367 #include <type_traits>
 368 struct T { int val; };
 369 static_assert(std::is_trivially_copyable<T>::value, \"ok\");
 370 int main() { return 0;}
 371 " HAVE_STD_IS_TRIVIALLY_COPYABLE)
 372
 373
 374 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 375 include(CheckAtomic)
 376
 377 if( LLVM_ENABLE_PIC )
 378   set(ENABLE_PIC 1)
 379 else()
 380   set(ENABLE_PIC 0)
 381   check_cxx_compiler_flag("-fno-pie" SUPPORTS_NO_PIE_FLAG)
 382   if(SUPPORTS_NO_PIE_FLAG)
 383     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fno-pie")
 384   endif()
 385 endif()
 386
 387 check_cxx_compiler_flag("-Wvariadic-macros" SUPPORTS_VARIADIC_MACROS_FLAG)
 388 check_cxx_compiler_flag("-Wgnu-zero-variadic-macro-arguments"
 389                         SUPPORTS_GNU_ZERO_VARIADIC_MACRO_ARGUMENTS_FLAG)
 390
 391 set(USE_NO_MAYBE_UNINITIALIZED 0)
 392 set(USE_NO_UNINITIALIZED 0)
 393
 394 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 395 # false positives.
 396 if (CMAKE_COMPILER_IS_GNUCXX)
 397   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 398   if (HAS_MAYBE_UNINITIALIZED)
 399     set(USE_NO_MAYBE_UNINITIALIZED 1)
 400   else()
 401     # Only recent versions of gcc make the distinction between -Wuninitialized
 402     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 403     # turn off all uninitialized use warnings.
 404     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 405     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 406   endif()
 407 endif()
 408
 409 # By default, we target the host, but this can be overridden at CMake
 410 # invocation time.
 411 include(GetHostTriple)
 412 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 413
 414 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 415     "Host on which LLVM binaries will run")
 416
 417 # Determine the native architecture.
 418 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 419 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 420   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 421 endif ()
 422
 423 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 424   set(LLVM_NATIVE_ARCH X86)
 425 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 426   set(LLVM_NATIVE_ARCH X86)
 427 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 428   set(LLVM_NATIVE_ARCH X86)
 429 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 430   set(LLVM_NATIVE_ARCH X86)
 431 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 432   set(LLVM_NATIVE_ARCH Sparc)
 433 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 434   set(LLVM_NATIVE_ARCH PowerPC)
 435 elseif (LLVM_NATIVE_ARCH MATCHES "ppc64le")
 436   set(LLVM_NATIVE_ARCH PowerPC)
 437 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 438   set(LLVM_NATIVE_ARCH AArch64)
 439 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 440   set(LLVM_NATIVE_ARCH AArch64)
 441 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 442   set(LLVM_NATIVE_ARCH ARM)
 443 elseif (LLVM_NATIVE_ARCH MATCHES "avr")
 444   set(LLVM_NATIVE_ARCH AVR)
 445 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 446   set(LLVM_NATIVE_ARCH Mips)
 447 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 448   set(LLVM_NATIVE_ARCH XCore)
 449 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 450   set(LLVM_NATIVE_ARCH MSP430)
 451 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 452   set(LLVM_NATIVE_ARCH Hexagon)
 453 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 454   set(LLVM_NATIVE_ARCH SystemZ)
 455 elseif (LLVM_NATIVE_ARCH MATCHES "wasm32")
 456   set(LLVM_NATIVE_ARCH WebAssembly)
 457 elseif (LLVM_NATIVE_ARCH MATCHES "wasm64")
 458   set(LLVM_NATIVE_ARCH WebAssembly)
 459 elseif (LLVM_NATIVE_ARCH MATCHES "riscv32")
 460   set(LLVM_NATIVE_ARCH RISCV)
 461 elseif (LLVM_NATIVE_ARCH MATCHES "riscv64")
 462   set(LLVM_NATIVE_ARCH RISCV)
 463 elseif (LLVM_NATIVE_ARCH STREQUAL "m68k")
 464   set(LLVM_NATIVE_ARCH M68k)
 465 else ()
 466   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 467 endif ()
 468
 469 # If build targets includes "host" or "Native", then replace with native architecture.
 470 foreach (NATIVE_KEYWORD host Native)
 471   list(FIND LLVM_TARGETS_TO_BUILD ${NATIVE_KEYWORD} idx)
 472   if( NOT idx LESS 0 )
 473     list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 474     list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 475     list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 476   endif()
 477 endforeach()
 478
 479 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 480 if (NATIVE_ARCH_IDX EQUAL -1)
 481   message(STATUS
 482     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 483 else ()
 484   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 485   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 486   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 487   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 488   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 489
 490   # We don't have an ASM parser for all architectures yet.
 491   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 492     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 493   endif ()
 494
 495   # We don't have an disassembler for all architectures yet.
 496   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 497     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 498   endif ()
 499 endif ()
 500
 501 if( MSVC )
 502   set(SHLIBEXT ".lib")
 503   set(stricmp "_stricmp")
 504   set(strdup "_strdup")
 505
 506   # Allow setting clang-cl's /winsysroot flag.
 507   set(LLVM_WINSYSROOT "" CACHE STRING
 508     "If set, argument to clang-cl's /winsysroot")
 509
 510   if (LLVM_WINSYSROOT)
 511     set(MSVC_DIA_SDK_DIR "${LLVM_WINSYSROOT}/DIA SDK" CACHE PATH
 512         "Path to the DIA SDK")
 513   else()
 514     set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK" CACHE PATH
 515         "Path to the DIA SDK")
 516   endif()
 517
 518   # See if the DIA SDK is available and usable.
 519   # Due to a bug in MSVC 2013's installation software, it is possible
 520   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
 521   # install directory.  If this happens, the installation is corrupt
 522   # and there's nothing we can do.  It happens with enough frequency
 523   # though that we should handle it.  We do so by simply checking that
 524   # the DIA SDK folder exists.  Should this happen you will need to
 525   # uninstall VS 2012 and then re-install VS 2013.
 526   if (IS_DIRECTORY "${MSVC_DIA_SDK_DIR}")
 527     set(HAVE_DIA_SDK 1)
 528   else()
 529     set(HAVE_DIA_SDK 0)
 530   endif()
 531
 532   option(LLVM_ENABLE_DIA_SDK "Use MSVC DIA SDK for debugging if available."
 533                              ${HAVE_DIA_SDK})
 534
 535   if(LLVM_ENABLE_DIA_SDK AND NOT HAVE_DIA_SDK)
 536     message(FATAL_ERROR "DIA SDK not found. If you have both VS 2012 and 2013 installed, you may need to uninstall the former and re-install the latter afterwards.")
 537   endif()
 538 else()
 539   set(LLVM_ENABLE_DIA_SDK 0)
 540 endif( MSVC )
 541
 542 if( LLVM_ENABLE_THREADS )
 543   # Check if threading primitives aren't supported on this platform
 544   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 545     set(LLVM_ENABLE_THREADS 0)
 546   endif()
 547 endif()
 548
 549 if( LLVM_ENABLE_THREADS )
 550   message(STATUS "Threads enabled.")
 551 else( LLVM_ENABLE_THREADS )
 552   message(STATUS "Threads disabled.")
 553 endif()
 554
 555 if (LLVM_ENABLE_DOXYGEN)
 556   message(STATUS "Doxygen enabled.")
 557   find_package(Doxygen REQUIRED)
 558
 559   if (DOXYGEN_FOUND)
 560     # If we find doxygen and we want to enable doxygen by default create a
 561     # global aggregate doxygen target for generating llvm and any/all
 562     # subprojects doxygen documentation.
 563     if (LLVM_BUILD_DOCS)
 564       add_custom_target(doxygen ALL)
 565     endif()
 566
 567     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 568     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 569       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external search.")
 570       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 571     endif()
 572   endif()
 573 else()
 574   message(STATUS "Doxygen disabled.")
 575 endif()
 576
 577 set(LLVM_BINDINGS "")
 578 find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 579 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 580   message(STATUS "Go bindings disabled.")
 581 else()
 582   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 583     message(STATUS "Go bindings disabled.")
 584   else()
 585     execute_process(COMMAND ${GO_EXECUTABLE} run ${PROJECT_SOURCE_DIR}/bindings/go/conftest.go
 586                     RESULT_VARIABLE GO_CONFTEST)
 587     if(GO_CONFTEST STREQUAL "0")
 588       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 589       message(STATUS "Go bindings enabled.")
 590     else()
 591       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 592     endif()
 593   endif()
 594 endif()
 595
 596 find_program(GOLD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.gold ld.gold ${LLVM_DEFAULT_TARGET_TRIPLE}-ld ld DOC "The gold linker")
 597 set(LLVM_BINUTILS_INCDIR "" CACHE PATH
 598     "PATH to binutils/include containing plugin-api.h for gold plugin.")
 599
 600 if(CMAKE_GENERATOR MATCHES "Ninja")
 601   execute_process(COMMAND ${CMAKE_MAKE_PROGRAM} --version
 602     OUTPUT_VARIABLE NINJA_VERSION
 603     OUTPUT_STRIP_TRAILING_WHITESPACE)
 604   set(NINJA_VERSION ${NINJA_VERSION} CACHE STRING "Ninja version number" FORCE)
 605   message(STATUS "Ninja version: ${NINJA_VERSION}")
 606 endif()
 607
 608 if(CMAKE_GENERATOR MATCHES "Ninja" AND
 609     NOT "${NINJA_VERSION}" VERSION_LESS "1.9.0" AND
 610     CMAKE_HOST_APPLE AND CMAKE_HOST_SYSTEM_VERSION VERSION_GREATER "15.6.0")
 611   set(LLVM_TOUCH_STATIC_LIBRARIES ON)
 612 endif()
 613
 614 if(CMAKE_HOST_APPLE AND APPLE)
 615   if(NOT CMAKE_XCRUN)
 616     find_program(CMAKE_XCRUN NAMES xcrun)
 617   endif()
 618   if(CMAKE_XCRUN)
 619     execute_process(COMMAND ${CMAKE_XCRUN} -find ld
 620       OUTPUT_VARIABLE LD64_EXECUTABLE
 621       OUTPUT_STRIP_TRAILING_WHITESPACE)
 622   else()
 623     find_program(LD64_EXECUTABLE NAMES ld DOC "The ld64 linker")
 624   endif()
 625
 626   if(LD64_EXECUTABLE)
 627     set(LD64_EXECUTABLE ${LD64_EXECUTABLE} CACHE PATH "ld64 executable")
 628     message(STATUS "Found ld64 - ${LD64_EXECUTABLE}")
 629   endif()
 630 endif()
 631
 632 # Keep the version requirements in sync with bindings/ocaml/README.txt.
 633 include(FindOCaml)
 634 include(AddOCaml)
 635 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 636   message(STATUS "OCaml bindings disabled.")
 637 else()
 638   find_package(OCaml)
 639   if( NOT OCAML_FOUND )
 640     message(STATUS "OCaml bindings disabled.")
 641   else()
 642     if( OCAML_VERSION VERSION_LESS "4.00.0" )
 643       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
 644     else()
 645       find_ocamlfind_package(ctypes VERSION 0.4 OPTIONAL)
 646       if( HAVE_OCAML_CTYPES )
 647         message(STATUS "OCaml bindings enabled.")
 648         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
 649
 650         set(LLVM_OCAML_INSTALL_PATH "${OCAML_STDLIB_PATH}" CACHE STRING
 651             "Install directory for LLVM OCaml packages")
 652       else()
 653         message(STATUS "OCaml bindings disabled, need ctypes >=0.4.")
 654       endif()
 655     endif()
 656   endif()
 657 endif()
 658
 659 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")
 660
 661 function(find_python_module module)
 662   string(REPLACE "." "_" module_name ${module})
 663   string(TOUPPER ${module_name} module_upper)
 664   set(FOUND_VAR PY_${module_upper}_FOUND)
 665   if (DEFINED ${FOUND_VAR})
 666     return()
 667   endif()
 668
 669   execute_process(COMMAND "${Python3_EXECUTABLE}" "-c" "import ${module}"
 670     RESULT_VARIABLE status
 671     ERROR_QUIET)
 672
 673   if(status)
 674     set(${FOUND_VAR} OFF CACHE BOOL "Failed to find python module '${module}'")
 675     message(STATUS "Could NOT find Python module ${module}")
 676   else()
 677   set(${FOUND_VAR} ON CACHE BOOL "Found python module '${module}'")
 678     message(STATUS "Found Python module ${module}")
 679   endif()
 680 endfunction()
 681
 682 set (PYTHON_MODULES
 683   pygments
 684   # Some systems still don't have pygments.lexers.c_cpp which was introduced in
 685   # version 2.0 in 2014...
 686   pygments.lexers.c_cpp
 687   yaml
 688   )
 689 foreach(module ${PYTHON_MODULES})
 690   find_python_module(${module})
 691 endforeach()
 692
 693 if(PY_PYGMENTS_FOUND AND PY_PYGMENTS_LEXERS_C_CPP_FOUND AND PY_YAML_FOUND)
 694   set (LLVM_HAVE_OPT_VIEWER_MODULES 1)
 695 else()
 696   set (LLVM_HAVE_OPT_VIEWER_MODULES 0)
 697 endif()
 698
 699 function(llvm_get_host_prefixes_and_suffixes)
 700   # Not all platform files will set these variables (relying on them being
 701   # implicitly empty if they're unset), so unset the variables before including
 702   # the platform file, to prevent any values from the target system leaking.
 703   unset(CMAKE_STATIC_LIBRARY_PREFIX)
 704   unset(CMAKE_STATIC_LIBRARY_SUFFIX)
 705   unset(CMAKE_SHARED_LIBRARY_PREFIX)
 706   unset(CMAKE_SHARED_LIBRARY_SUFFIX)
 707   unset(CMAKE_IMPORT_LIBRARY_PREFIX)
 708   unset(CMAKE_IMPORT_LIBRARY_SUFFIX)
 709   unset(CMAKE_EXECUTABLE_SUFFIX)
 710   unset(CMAKE_LINK_LIBRARY_SUFFIX)
 711   include(Platform/${CMAKE_HOST_SYSTEM_NAME} OPTIONAL RESULT_VARIABLE _includedFile)
 712   if (_includedFile)
 713     set(LLVM_HOST_STATIC_LIBRARY_PREFIX ${CMAKE_STATIC_LIBRARY_PREFIX} PARENT_SCOPE)
 714     set(LLVM_HOST_STATIC_LIBRARY_SUFFIX ${CMAKE_STATIC_LIBRARY_SUFFIX} PARENT_SCOPE)
 715     set(LLVM_HOST_SHARED_LIBRARY_PREFIX ${CMAKE_SHARED_LIBRARY_PREFIX} PARENT_SCOPE)
 716     set(LLVM_HOST_SHARED_LIBRARY_SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX} PARENT_SCOPE)
 717     set(LLVM_HOST_IMPORT_LIBRARY_PREFIX ${CMAKE_IMPORT_LIBRARY_PREFIX} PARENT_SCOPE)
 718     set(LLVM_HOST_IMPORT_LIBRARY_SUFFIX ${CMAKE_IMPORT_LIBRARY_SUFFIX} PARENT_SCOPE)
 719     set(LLVM_HOST_EXECUTABLE_SUFFIX ${CMAKE_EXECUTABLE_SUFFIX} PARENT_SCOPE)
 720     set(LLVM_HOST_LINK_LIBRARY_SUFFIX ${CMAKE_LINK_LIBRARY_SUFFIX} PARENT_SCOPE)
 721   endif()
 722 endfunction()
 723
 724 llvm_get_host_prefixes_and_suffixes()