llvm/lib/Target/Mips/MipsCallingConv.td

   1 //===-- MipsCallingConv.td - Calling Conventions for Mips --*- tablegen -*-===//
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6 //
   7 //===----------------------------------------------------------------------===//
   8 // This describes the calling conventions for Mips architecture.
   9 //===----------------------------------------------------------------------===//
  10
  11 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  12 class CCIfSubtarget<string F, CCAction A, string Invert = "">
  13     : CCIf<!strconcat(Invert,
  14                       "static_cast<const MipsSubtarget&>"
  15                         "(State.getMachineFunction().getSubtarget()).",
  16                       F),
  17            A>;
  18
  19 // The inverse of CCIfSubtarget
  20 class CCIfSubtargetNot<string F, CCAction A> : CCIfSubtarget<F, A, "!">;
  21
  22 /// Match if the original argument (before lowering) was a float.
  23 /// For example, this is true for i32's that were lowered from soft-float.
  24 class CCIfOrigArgWasNotFloat<CCAction A>
  25     : CCIf<"!static_cast<MipsCCState *>(&State)->WasOriginalArgFloat(ValNo)",
  26            A>;
  27
  28 /// Match if the original argument (before lowering) was a 128-bit float (i.e.
  29 /// long double).
  30 class CCIfOrigArgWasF128<CCAction A>
  31     : CCIf<"static_cast<MipsCCState *>(&State)->WasOriginalArgF128(ValNo)", A>;
  32
  33 /// Match if this specific argument is a vararg.
  34 /// This is slightly different fro CCIfIsVarArg which matches if any argument is
  35 /// a vararg.
  36 class CCIfArgIsVarArg<CCAction A>
  37     : CCIf<"!static_cast<MipsCCState *>(&State)->IsCallOperandFixed(ValNo)", A>;
  38
  39 /// Match if the return was a floating point vector.
  40 class CCIfOrigArgWasNotVectorFloat<CCAction A>
  41     : CCIf<"!static_cast<MipsCCState *>(&State)"
  42                 "->WasOriginalRetVectorFloat(ValNo)", A>;
  43
  44 /// Match if the special calling conv is the specified value.
  45 class CCIfSpecialCallingConv<string CC, CCAction A>
  46     : CCIf<"static_cast<MipsCCState *>(&State)->getSpecialCallingConv() == "
  47                "MipsCCState::" # CC, A>;
  48
  49 // For soft-float, f128 values are returned in A0_64 rather than V1_64.
  50 def RetCC_F128SoftFloat : CallingConv<[
  51   CCAssignToReg<[V0_64, A0_64]>
  52 ]>;
  53
  54 // For hard-float, f128 values are returned as a pair of f64's rather than a
  55 // pair of i64's.
  56 def RetCC_F128HardFloat : CallingConv<[
  57   CCBitConvertToType<f64>,
  58
  59   // Contrary to the ABI documentation, a struct containing a long double is
  60   // returned in $f0, and $f1 instead of the usual $f0, and $f2. This is to
  61   // match the de facto ABI as implemented by GCC.
  62   CCIfInReg<CCAssignToReg<[D0_64, D1_64]>>,
  63
  64   CCAssignToReg<[D0_64, D2_64]>
  65 ]>;
  66
  67 // Handle F128 specially since we can't identify the original type during the
  68 // tablegen-erated code.
  69 def RetCC_F128 : CallingConv<[
  70   CCIfSubtarget<"useSoftFloat()",
  71       CCIfType<[i64], CCDelegateTo<RetCC_F128SoftFloat>>>,
  72   CCIfSubtargetNot<"useSoftFloat()",
  73       CCIfType<[i64], CCDelegateTo<RetCC_F128HardFloat>>>
  74 ]>;
  75
  76 //===----------------------------------------------------------------------===//
  77 // Mips O32 Calling Convention
  78 //===----------------------------------------------------------------------===//
  79
  80 def CC_MipsO32 : CallingConv<[
  81   // Promote i8/i16 arguments to i32.
  82   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
  83
  84   // Integer values get stored in stack slots that are 4 bytes in
  85   // size and 4-byte aligned.
  86   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
  87
  88   // Integer values get stored in stack slots that are 8 bytes in
  89   // size and 8-byte aligned.
  90   CCIfType<[f64], CCAssignToStack<8, 8>>
  91 ]>;
  92
  93 // Only the return rules are defined here for O32. The rules for argument
  94 // passing are defined in MipsISelLowering.cpp.
  95 def RetCC_MipsO32 : CallingConv<[
  96   // Promote i1/i8/i16 return values to i32.
  97   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
  98
  99   // i32 are returned in registers V0, V1, A0, A1, unless the original return
 100   // type was a vector of floats.
 101   CCIfOrigArgWasNotVectorFloat<CCIfType<[i32],
 102                                         CCAssignToReg<[V0, V1, A0, A1]>>>,
 103
 104   // f32 are returned in registers F0, F2
 105   CCIfType<[f32], CCAssignToReg<[F0, F2]>>,
 106
 107   // f64 arguments are returned in D0_64 and D2_64 in FP64bit mode or
 108   // in D0 and D1 in FP32bit mode.
 109   CCIfType<[f64], CCIfSubtarget<"isFP64bit()", CCAssignToReg<[D0_64, D2_64]>>>,
 110   CCIfType<[f64], CCIfSubtargetNot<"isFP64bit()", CCAssignToReg<[D0, D1]>>>
 111 ]>;
 112
 113 def CC_MipsO32_FP32 : CustomCallingConv;
 114 def CC_MipsO32_FP64 : CustomCallingConv;
 115
 116 def CC_MipsO32_FP : CallingConv<[
 117   CCIfSubtargetNot<"isFP64bit()", CCDelegateTo<CC_MipsO32_FP32>>,
 118   CCIfSubtarget<"isFP64bit()", CCDelegateTo<CC_MipsO32_FP64>>
 119 ]>;
 120
 121 //===----------------------------------------------------------------------===//
 122 // Mips N32/64 Calling Convention
 123 //===----------------------------------------------------------------------===//
 124
 125 def CC_MipsN_SoftFloat : CallingConv<[
 126   CCAssignToRegWithShadow<[A0, A1, A2, A3,
 127                            T0, T1, T2, T3],
 128                           [D12_64, D13_64, D14_64, D15_64,
 129                            D16_64, D17_64, D18_64, D19_64]>,
 130   CCAssignToStack<4, 8>
 131 ]>;
 132
 133 def CC_MipsN : CallingConv<[
 134   CCIfType<[i8, i16, i32, i64],
 135       CCIfSubtargetNot<"isLittle()",
 136           CCIfInReg<CCPromoteToUpperBitsInType<i64>>>>,
 137
 138   // All integers (except soft-float integers) are promoted to 64-bit.
 139   CCIfType<[i8, i16, i32], CCIfOrigArgWasNotFloat<CCPromoteToType<i64>>>,
 140
 141   // The only i32's we have left are soft-float arguments.
 142   CCIfSubtarget<"useSoftFloat()", CCIfType<[i32],
 143                 CCDelegateTo<CC_MipsN_SoftFloat>>>,
 144
 145   // Integer arguments are passed in integer registers.
 146   CCIfType<[i64], CCAssignToRegWithShadow<[A0_64, A1_64, A2_64, A3_64,
 147                                            T0_64, T1_64, T2_64, T3_64],
 148                                           [D12_64, D13_64, D14_64, D15_64,
 149                                            D16_64, D17_64, D18_64, D19_64]>>,
 150
 151   // f32 arguments are passed in single precision FP registers.
 152   CCIfType<[f32], CCAssignToRegWithShadow<[F12, F13, F14, F15,
 153                                            F16, F17, F18, F19],
 154                                           [A0_64, A1_64, A2_64, A3_64,
 155                                            T0_64, T1_64, T2_64, T3_64]>>,
 156
 157   // f64 arguments are passed in double precision FP registers.
 158   CCIfType<[f64], CCAssignToRegWithShadow<[D12_64, D13_64, D14_64, D15_64,
 159                                            D16_64, D17_64, D18_64, D19_64],
 160                                           [A0_64, A1_64, A2_64, A3_64,
 161                                            T0_64, T1_64, T2_64, T3_64]>>,
 162
 163   // All stack parameter slots become 64-bit doublewords and are 8-byte aligned.
 164   CCIfType<[f32], CCAssignToStack<4, 8>>,
 165   CCIfType<[i64, f64], CCAssignToStack<8, 8>>
 166 ]>;
 167
 168 // N32/64 variable arguments.
 169 // All arguments are passed in integer registers.
 170 def CC_MipsN_VarArg : CallingConv<[
 171   CCIfType<[i8, i16, i32, i64],
 172       CCIfSubtargetNot<"isLittle()",
 173           CCIfInReg<CCPromoteToUpperBitsInType<i64>>>>,
 174
 175   // All integers are promoted to 64-bit.
 176   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 177
 178   CCIfType<[f32], CCAssignToReg<[A0, A1, A2, A3, T0, T1, T2, T3]>>,
 179
 180   CCIfType<[i64, f64], CCAssignToReg<[A0_64, A1_64, A2_64, A3_64,
 181                                       T0_64, T1_64, T2_64, T3_64]>>,
 182
 183   // All stack parameter slots become 64-bit doublewords and are 8-byte aligned.
 184   CCIfType<[f32], CCAssignToStack<4, 8>>,
 185   CCIfType<[i64, f64], CCAssignToStack<8, 8>>
 186 ]>;
 187
 188 def RetCC_MipsN : CallingConv<[
 189   // f128 needs to be handled similarly to f32 and f64. However, f128 is not
 190   // legal and is lowered to i128 which is further lowered to a pair of i64's.
 191   // This presents us with a problem for the calling convention since hard-float
 192   // still needs to pass them in FPU registers, and soft-float needs to use $v0,
 193   // and $a0 instead of the usual $v0, and $v1. We therefore resort to a
 194   // pre-analyze (see PreAnalyzeReturnForF128()) step to pass information on
 195   // whether the result was originally an f128 into the tablegen-erated code.
 196   //
 197   // f128 should only occur for the N64 ABI where long double is 128-bit. On
 198   // N32, long double is equivalent to double.
 199   CCIfType<[i64], CCIfOrigArgWasF128<CCDelegateTo<RetCC_F128>>>,
 200
 201   // Aggregate returns are positioned at the lowest address in the slot for
 202   // both little and big-endian targets. When passing in registers, this
 203   // requires that big-endian targets shift the value into the upper bits.
 204   CCIfSubtarget<"isLittle()",
 205       CCIfType<[i8, i16, i32, i64], CCIfInReg<CCPromoteToType<i64>>>>,
 206   CCIfSubtargetNot<"isLittle()",
 207       CCIfType<[i8, i16, i32, i64],
 208           CCIfInReg<CCPromoteToUpperBitsInType<i64>>>>,
 209
 210   // i64 are returned in registers V0_64, V1_64
 211   CCIfType<[i64], CCAssignToReg<[V0_64, V1_64]>>,
 212
 213   // f32 are returned in registers F0, F2
 214   CCIfType<[f32], CCAssignToReg<[F0, F2]>>,
 215
 216   // f64 are returned in registers D0, D2
 217   CCIfType<[f64], CCAssignToReg<[D0_64, D2_64]>>
 218 ]>;
 219
 220 //===----------------------------------------------------------------------===//
 221 // Mips FastCC Calling Convention
 222 //===----------------------------------------------------------------------===//
 223 def CC_MipsO32_FastCC : CallingConv<[
 224   // f64 arguments are passed in double-precision floating pointer registers.
 225   CCIfType<[f64], CCIfSubtargetNot<"isFP64bit()",
 226                                    CCAssignToReg<[D0, D1, D2, D3, D4, D5, D6,
 227                                                   D7, D8, D9]>>>,
 228   CCIfType<[f64], CCIfSubtarget<"isFP64bit()", CCIfSubtarget<"useOddSPReg()",
 229                                 CCAssignToReg<[D0_64, D1_64, D2_64, D3_64,
 230                                                D4_64, D5_64, D6_64, D7_64,
 231                                                D8_64, D9_64, D10_64, D11_64,
 232                                                D12_64, D13_64, D14_64, D15_64,
 233                                                D16_64, D17_64, D18_64,
 234                                                D19_64]>>>>,
 235   CCIfType<[f64], CCIfSubtarget<"isFP64bit()", CCIfSubtarget<"noOddSPReg()",
 236                                 CCAssignToReg<[D0_64, D2_64, D4_64, D6_64,
 237                                                D8_64, D10_64, D12_64, D14_64,
 238                                                D16_64, D18_64]>>>>,
 239
 240   // Stack parameter slots for f64 are 64-bit doublewords and 8-byte aligned.
 241   CCIfType<[f64], CCAssignToStack<8, 8>>
 242 ]>;
 243
 244 def CC_MipsN_FastCC : CallingConv<[
 245   // Integer arguments are passed in integer registers.
 246   CCIfType<[i64], CCAssignToReg<[A0_64, A1_64, A2_64, A3_64, T0_64, T1_64,
 247                                  T2_64, T3_64, T4_64, T5_64, T6_64, T7_64,
 248                                  T8_64, V1_64]>>,
 249
 250   // f64 arguments are passed in double-precision floating pointer registers.
 251   CCIfType<[f64], CCAssignToReg<[D0_64, D1_64, D2_64, D3_64, D4_64, D5_64,
 252                                  D6_64, D7_64, D8_64, D9_64, D10_64, D11_64,
 253                                  D12_64, D13_64, D14_64, D15_64, D16_64, D17_64,
 254                                  D18_64, D19_64]>>,
 255
 256   // Stack parameter slots for i64 and f64 are 64-bit doublewords and
 257   // 8-byte aligned.
 258   CCIfType<[i64, f64], CCAssignToStack<8, 8>>
 259 ]>;
 260
 261 def CC_Mips_FastCC : CallingConv<[
 262   // Handles byval parameters.
 263   CCIfByVal<CCPassByVal<4, 4>>,
 264
 265   // Promote i8/i16 arguments to i32.
 266   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 267
 268   // Integer arguments are passed in integer registers. All scratch registers,
 269   // except for AT, V0 and T9, are available to be used as argument registers.
 270   CCIfType<[i32], CCIfSubtargetNot<"isTargetNaCl()",
 271       CCAssignToReg<[A0, A1, A2, A3, T0, T1, T2, T3, T4, T5, T6, T7, T8, V1]>>>,
 272
 273   // In NaCl, T6, T7 and T8 are reserved and not available as argument
 274   // registers for fastcc.  T6 contains the mask for sandboxing control flow
 275   // (indirect jumps and calls).  T7 contains the mask for sandboxing memory
 276   // accesses (loads and stores).  T8 contains the thread pointer.
 277   CCIfType<[i32], CCIfSubtarget<"isTargetNaCl()",
 278       CCAssignToReg<[A0, A1, A2, A3, T0, T1, T2, T3, T4, T5, V1]>>>,
 279
 280   // f32 arguments are passed in single-precision floating pointer registers.
 281   CCIfType<[f32], CCIfSubtarget<"useOddSPReg()",
 282       CCAssignToReg<[F0, F1, F2, F3, F4, F5, F6, F7, F8, F9, F10, F11, F12, F13,
 283                      F14, F15, F16, F17, F18, F19]>>>,
 284
 285   // Don't use odd numbered single-precision registers for -mno-odd-spreg.
 286   CCIfType<[f32], CCIfSubtarget<"noOddSPReg()",
 287       CCAssignToReg<[F0, F2, F4, F6, F8, F10, F12, F14, F16, F18]>>>,
 288
 289   // Stack parameter slots for i32 and f32 are 32-bit words and 4-byte aligned.
 290   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 291
 292   CCIfSubtarget<"isABI_O32()", CCDelegateTo<CC_MipsO32_FastCC>>,
 293   CCDelegateTo<CC_MipsN_FastCC>
 294 ]>;
 295
 296 //===----------------------------------------------------------------------===//
 297 // Mips Calling Convention Dispatch
 298 //===----------------------------------------------------------------------===//
 299
 300 def RetCC_Mips : CallingConv<[
 301   CCIfSubtarget<"isABI_N32()", CCDelegateTo<RetCC_MipsN>>,
 302   CCIfSubtarget<"isABI_N64()", CCDelegateTo<RetCC_MipsN>>,
 303   CCDelegateTo<RetCC_MipsO32>
 304 ]>;
 305
 306 def CC_Mips_ByVal : CallingConv<[
 307   CCIfSubtarget<"isABI_O32()", CCIfByVal<CCPassByVal<4, 4>>>,
 308   CCIfByVal<CCPassByVal<8, 8>>
 309 ]>;
 310
 311 def CC_Mips16RetHelper : CallingConv<[
 312   CCIfByVal<CCDelegateTo<CC_Mips_ByVal>>,
 313
 314   // Integer arguments are passed in integer registers.
 315   CCIfType<[i32], CCAssignToReg<[V0, V1, A0, A1]>>
 316 ]>;
 317
 318 def CC_Mips_FixedArg : CallingConv<[
 319   // Mips16 needs special handling on some functions.
 320   CCIf<"State.getCallingConv() != CallingConv::Fast",
 321       CCIfSpecialCallingConv<"Mips16RetHelperConv",
 322            CCDelegateTo<CC_Mips16RetHelper>>>,
 323
 324   CCIfByVal<CCDelegateTo<CC_Mips_ByVal>>,
 325
 326   // f128 needs to be handled similarly to f32 and f64 on hard-float. However,
 327   // f128 is not legal and is lowered to i128 which is further lowered to a pair
 328   // of i64's.
 329   // This presents us with a problem for the calling convention since hard-float
 330   // still needs to pass them in FPU registers. We therefore resort to a
 331   // pre-analyze (see PreAnalyzeFormalArgsForF128()) step to pass information on
 332   // whether the argument was originally an f128 into the tablegen-erated code.
 333   //
 334   // f128 should only occur for the N64 ABI where long double is 128-bit. On
 335   // N32, long double is equivalent to double.
 336   CCIfType<[i64],
 337       CCIfSubtargetNot<"useSoftFloat()",
 338           CCIfOrigArgWasF128<CCBitConvertToType<f64>>>>,
 339
 340   CCIfCC<"CallingConv::Fast", CCDelegateTo<CC_Mips_FastCC>>,
 341
 342   CCIfSubtarget<"isABI_O32()", CCDelegateTo<CC_MipsO32_FP>>,
 343   CCDelegateTo<CC_MipsN>
 344 ]>;
 345
 346 def CC_Mips_VarArg : CallingConv<[
 347   CCIfByVal<CCDelegateTo<CC_Mips_ByVal>>,
 348
 349   CCIfSubtarget<"isABI_O32()", CCDelegateTo<CC_MipsO32_FP>>,
 350   CCDelegateTo<CC_MipsN_VarArg>
 351 ]>;
 352
 353 def CC_Mips : CallingConv<[
 354   CCIfVarArg<CCIfArgIsVarArg<CCDelegateTo<CC_Mips_VarArg>>>,
 355   CCDelegateTo<CC_Mips_FixedArg>
 356 ]>;
 357
 358 //===----------------------------------------------------------------------===//
 359 // Callee-saved register lists.
 360 //===----------------------------------------------------------------------===//
 361
 362 def CSR_SingleFloatOnly : CalleeSavedRegs<(add (sequence "F%u", 31, 20), RA, FP,
 363                                                (sequence "S%u", 7, 0))>;
 364
 365 def CSR_O32_FPXX : CalleeSavedRegs<(add (sequence "D%u", 15, 10), RA, FP,
 366                                         (sequence "S%u", 7, 0))> {
 367   let OtherPreserved = (add (decimate (sequence "F%u", 30, 20), 2));
 368 }
 369
 370 def CSR_O32 : CalleeSavedRegs<(add (sequence "D%u", 15, 10), RA, FP,
 371                                    (sequence "S%u", 7, 0))>;
 372
 373 def CSR_O32_FP64 :
 374   CalleeSavedRegs<(add (decimate (sequence "D%u_64", 30, 20), 2), RA, FP,
 375                        (sequence "S%u", 7, 0))>;
 376
 377 def CSR_N32 : CalleeSavedRegs<(add D20_64, D22_64, D24_64, D26_64, D28_64,
 378                                    D30_64, RA_64, FP_64, GP_64,
 379                                    (sequence "S%u_64", 7, 0))>;
 380
 381 def CSR_N64 : CalleeSavedRegs<(add (sequence "D%u_64", 31, 24), RA_64, FP_64,
 382                                    GP_64, (sequence "S%u_64", 7, 0))>;
 383
 384 def CSR_Mips16RetHelper :
 385   CalleeSavedRegs<(add V0, V1, FP,
 386                    (sequence "A%u", 3, 0), (sequence "S%u", 7, 0),
 387                    (sequence "D%u", 15, 10))>;
 388
 389 def CSR_Interrupt_32R6 : CalleeSavedRegs<(add (sequence "A%u", 3, 0),
 390                                               (sequence "S%u", 7, 0),
 391                                               (sequence "V%u", 1, 0),
 392                                               (sequence "T%u", 9, 0),
 393                                               RA, FP, GP, AT)>;
 394
 395 def CSR_Interrupt_32 : CalleeSavedRegs<(add (sequence "A%u", 3, 0),
 396                                             (sequence "S%u", 7, 0),
 397                                             (sequence "V%u", 1, 0),
 398                                             (sequence "T%u", 9, 0),
 399                                             RA, FP, GP, AT, LO0, HI0)>;
 400
 401 def CSR_Interrupt_64R6 : CalleeSavedRegs<(add (sequence "A%u_64", 3, 0),
 402                                               (sequence "V%u_64", 1, 0),
 403                                               (sequence "S%u_64", 7, 0),
 404                                               (sequence "T%u_64", 9, 0),
 405                                               RA_64, FP_64, GP_64, AT_64)>;
 406
 407 def CSR_Interrupt_64 : CalleeSavedRegs<(add (sequence "A%u_64", 3, 0),
 408                                             (sequence "S%u_64", 7, 0),
 409                                             (sequence "T%u_64", 9, 0),
 410                                             (sequence "V%u_64", 1, 0),
 411                                             RA_64, FP_64, GP_64, AT_64,
 412                                             LO0_64, HI0_64)>;