llvm/test/CodeGen/X86/shrink-wrapping-vla.ll

   1 ; Test shrink wrapping placement is correct with respect to calls to llvm.{stacksave,stackrestore}
   2
   3 ; void f(int n, int x[]) {
   4 ;   if (n < 0)
   5 ;     return;
   6 ;
   7 ;  int a[n];
   8 ;
   9 ;  for (int i = 0; i < n; i++)
  10 ;    a[i] = x[n - i - 1];
  11 ;
  12 ;  for (int i = 0; i < n; i++)
  13 ;    x[i] = a[i] + 1;
  14 ; }
  15 ;
  16 ; RUN: llc -mtriple x86_64-linux %s -o - | FileCheck %s --check-prefix=CHECK
  17
  18 define dso_local void @f(i32 %n, ptr nocapture %x) {
  19 entry:
  20   %cmp = icmp slt i32 %n, 0
  21   br i1 %cmp, label %return, label %if.end
  22
  23 if.end:                                           ; preds = %entry
  24   %0 = zext i32 %n to i64
  25   %1 = tail call ptr @llvm.stacksave()
  26   %vla = alloca i32, i64 %0, align 16
  27   %cmp132 = icmp eq i32 %n, 0
  28   br i1 %cmp132, label %for.cond.cleanup8, label %for.body.lr.ph
  29
  30 for.body.lr.ph:                                   ; preds = %if.end
  31   %sub = add i32 %n, -1
  32   br label %for.body
  33
  34 for.cond6.preheader:                              ; preds = %for.body
  35   %cmp730 = icmp sgt i32 %n, 0
  36   br i1 %cmp730, label %for.body9, label %for.cond.cleanup8
  37
  38 for.body:                                         ; preds = %for.body, %for.body.lr.ph
  39   %indvars.iv34 = phi i64 [ 0, %for.body.lr.ph ], [ %indvars.iv.next35, %for.body ]
  40   %2 = trunc i64 %indvars.iv34 to i32
  41   %sub2 = sub i32 %sub, %2
  42   %idxprom = sext i32 %sub2 to i64
  43   %arrayidx = getelementptr inbounds i32, ptr %x, i64 %idxprom
  44   %3 = load i32, ptr %arrayidx, align 4
  45   %arrayidx4 = getelementptr inbounds i32, ptr %vla, i64 %indvars.iv34
  46   store i32 %3, ptr %arrayidx4, align 4
  47   %indvars.iv.next35 = add nuw nsw i64 %indvars.iv34, 1
  48   %exitcond37 = icmp eq i64 %indvars.iv.next35, %0
  49   br i1 %exitcond37, label %for.cond6.preheader, label %for.body
  50
  51 for.cond.cleanup8:                                ; preds = %for.body9, %if.end, %for.cond6.preheader
  52   tail call void @llvm.stackrestore(ptr %1)
  53   br label %return
  54
  55 for.body9:                                        ; preds = %for.cond6.preheader, %for.body9
  56   %indvars.iv = phi i64 [ %indvars.iv.next, %for.body9 ], [ 0, %for.cond6.preheader ]
  57   %arrayidx11 = getelementptr inbounds i32, ptr %vla, i64 %indvars.iv
  58   %4 = load i32, ptr %arrayidx11, align 4
  59   %add = add nsw i32 %4, 1
  60   %arrayidx13 = getelementptr inbounds i32, ptr %x, i64 %indvars.iv
  61   store i32 %add, ptr %arrayidx13, align 4
  62   %indvars.iv.next = add nuw nsw i64 %indvars.iv, 1
  63   %exitcond = icmp eq i64 %indvars.iv.next, %0
  64   br i1 %exitcond, label %for.cond.cleanup8, label %for.body9
  65
  66 return:                                           ; preds = %entry, %for.cond.cleanup8
  67   ret void
  68 }
  69
  70 ; Function Attrs: nounwind
  71 declare ptr @llvm.stacksave()
  72
  73 ; Function Attrs: nounwind
  74 declare void @llvm.stackrestore(ptr)
  75
  76 ; Check that llvm.stackrestore() happens before CSRs are popped off the stack
  77
  78 ; CHECK-LABEL: f
  79
  80 ; CHECK: pushq %rbp
  81 ; CHECK: movq %rsp, %rbp
  82
  83 ; Saving the SP via llvm.stacksave()
  84 ; CHECK: movq %rsp, [[SAVE:%r[a-z0-9]+]]
  85 ; VLA allocation
  86 ; CHECK: movq %rsp, [[TMP:%r[a-z0-9]+]]
  87 ; CHECK: subq %r{{[a-z0-9]+}}, [[TMP]]
  88 ; CHECK: movq [[TMP]], %rsp
  89
  90 ; The next instruction comes from llvm.stackrestore()
  91 ; CHECK:      movq [[SAVE]], %rsp
  92 ; Epilogue
  93 ; CHECK-NEXT: movq %rbp, %rsp
  94 ; CHECK-NEXT: popq %rbp