llvm/test/Other/spirv-sim/wave-read-lane-first.spv

   1 ; RUN: %if spirv-tools %{ spirv-as %s -o - | spirv-val - %}
   2 ; RUN: spirv-sim --function=simple --wave=4 --expects=0,1,2,0 -i %s
   3
   4 ; int simple() {
   5 ;   int m[4] = { 0, 1, 2, 0 };
   6 ;   int idx = WaveGetLaneIndex();
   7 ;   for (int i = 0; i < 4; i++) {
   8 ;     if (i == m[idx]) {
   9 ;       return WaveReadLaneFirst(idx);
  10 ;     }
  11 ;   }
  12 ;   return 0;
  13 ; }
  14                        OpCapability Shader
  15                        OpCapability GroupNonUniform
  16                        OpCapability GroupNonUniformBallot
  17                        OpMemoryModel Logical GLSL450
  18                        OpEntryPoint GLCompute %main "main" %WaveIndex
  19                        OpExecutionMode %main LocalSize 1 1 1
  20                        OpSource HLSL 670
  21                        OpName %simple "simple"
  22                        OpName %main "main"
  23                        OpDecorate %WaveIndex BuiltIn SubgroupLocalInvocationId
  24                 %int = OpTypeInt 32 1
  25                %uint = OpTypeInt 32 0
  26                %bool = OpTypeBool
  27               %int_0 = OpConstant %int 0
  28               %int_1 = OpConstant %int 1
  29               %int_2 = OpConstant %int 2
  30               %int_4 = OpConstant %int 4
  31              %uint_3 = OpConstant %uint 3
  32              %uint_4 = OpConstant %uint 4
  33                %void = OpTypeVoid
  34           %main_type = OpTypeFunction %void
  35         %simple_type = OpTypeFunction %int
  36           %uint_iptr = OpTypePointer Input %uint
  37            %int_fptr = OpTypePointer Function %int
  38      %arr_int_uint_4 = OpTypeArray %int %uint_4
  39 %arr_int_uint_4_fptr = OpTypePointer Function %arr_int_uint_4
  40           %WaveIndex = OpVariable %uint_iptr Input
  41                %main = OpFunction %void None %main_type
  42               %entry = OpLabel
  43                        OpReturn
  44                        OpFunctionEnd
  45              %simple = OpFunction %int None %simple_type
  46          %bb_entry_0 = OpLabel
  47                   %m = OpVariable %arr_int_uint_4_fptr Function
  48                 %idx = OpVariable %int_fptr Function
  49                   %i = OpVariable %int_fptr Function
  50                  %27 = OpCompositeConstruct %arr_int_uint_4 %int_0 %int_1 %int_2 %int_0
  51                        OpStore %m %27
  52                  %28 = OpLoad %uint %WaveIndex
  53                  %29 = OpBitcast %int %28
  54                        OpStore %idx %29
  55                        OpStore %i %int_0
  56                        OpBranch %for_check
  57           %for_check = OpLabel
  58                  %31 = OpLoad %int %i
  59                  %33 = OpSLessThan %bool %31 %int_4
  60                        OpLoopMerge %for_merge %for_continue None
  61                        OpBranchConditional %33 %for_body %for_merge
  62            %for_body = OpLabel
  63                  %37 = OpLoad %int %i
  64                  %38 = OpLoad %int %idx
  65                  %39 = OpAccessChain %int_fptr %m %38
  66                  %40 = OpLoad %int %39
  67                  %41 = OpIEqual %bool %37 %40
  68                        OpSelectionMerge %if_merge None
  69                        OpBranchConditional %41 %if_true %if_merge
  70             %if_true = OpLabel
  71                  %44 = OpLoad %int %idx
  72                  %45 = OpGroupNonUniformBroadcastFirst %int %uint_3 %44
  73                        OpReturnValue %45
  74            %if_merge = OpLabel
  75                        OpBranch %for_continue
  76        %for_continue = OpLabel
  77                  %47 = OpLoad %int %i
  78                  %48 = OpIAdd %int %47 %int_1
  79                        OpStore %i %48
  80                        OpBranch %for_check
  81           %for_merge = OpLabel
  82                        OpReturnValue %int_0
  83                        OpFunctionEnd