clang/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.20.0)
   2 set(LLVM_SUBPROJECT_TITLE "Clang")
   3
   4 if(NOT DEFINED LLVM_COMMON_CMAKE_UTILS)
   5   set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
   6 endif()
   7 include(${LLVM_COMMON_CMAKE_UTILS}/Modules/CMakePolicy.cmake
   8   NO_POLICY_SCOPE)
   9
  10 # If we are not building as a part of LLVM, build Clang as an
  11 # standalone project, using LLVM as an external library:
  12 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  13   project(Clang)
  14   set(CLANG_BUILT_STANDALONE TRUE)
  15 endif()
  16
  17 # Make sure that our source directory is on the current cmake module path so that
  18 # we can include cmake files from this directory.
  19 list(INSERT CMAKE_MODULE_PATH 0
  20   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  21   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
  22   )
  23
  24 # Must go below project(..)
  25 include(GNUInstallDirs)
  26 include(GetDarwinLinkerVersion)
  27
  28 if(CLANG_BUILT_STANDALONE)
  29   set(CMAKE_CXX_STANDARD 17 CACHE STRING "C++ standard to conform to")
  30   set(CMAKE_CXX_STANDARD_REQUIRED YES)
  31   set(CMAKE_CXX_EXTENSIONS NO)
  32
  33   if(NOT MSVC_IDE)
  34     set(LLVM_ENABLE_ASSERTIONS ${ENABLE_ASSERTIONS}
  35       CACHE BOOL "Enable assertions")
  36     # Assertions should follow llvm-config's.
  37     mark_as_advanced(LLVM_ENABLE_ASSERTIONS)
  38   endif()
  39
  40   find_package(LLVM REQUIRED HINTS "${LLVM_CMAKE_DIR}")
  41   list(APPEND CMAKE_MODULE_PATH "${LLVM_DIR}")
  42
  43   # Turn into CACHE PATHs for overwritting
  44   set(LLVM_INCLUDE_DIRS ${LLVM_INCLUDE_DIRS} CACHE PATH "Path to llvm/include and any other header dirs needed")
  45   set(LLVM_BINARY_DIR "${LLVM_BINARY_DIR}" CACHE PATH "Path to LLVM build tree")
  46   set(LLVM_MAIN_SRC_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../llvm" CACHE PATH "Path to LLVM source tree")
  47   set(LLVM_TOOLS_BINARY_DIR "${LLVM_TOOLS_BINARY_DIR}" CACHE PATH "Path to llvm/bin")
  48   set(LLVM_LIBRARY_DIR "${LLVM_LIBRARY_DIR}" CACHE PATH "Path to llvm/lib")
  49
  50   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR}
  51     NO_DEFAULT_PATH)
  52
  53   # They are used as destination of target generators.
  54   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  55   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  56   if(WIN32 OR CYGWIN)
  57     # DLL platform -- put DLLs into bin.
  58     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  59   else()
  60     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
  61   endif()
  62
  63   option(LLVM_INSTALL_TOOLCHAIN_ONLY
  64     "Only include toolchain files in the 'install' target." OFF)
  65
  66   option(LLVM_FORCE_USE_OLD_TOOLCHAIN
  67     "Set to ON to force using an old, unsupported host toolchain." OFF)
  68   option(CLANG_ENABLE_BOOTSTRAP "Generate the clang bootstrap target" OFF)
  69   option(LLVM_ENABLE_LIBXML2 "Use libxml2 if available." ON)
  70
  71   include(AddLLVM)
  72   include(TableGen)
  73   include(HandleLLVMOptions)
  74   include(VersionFromVCS)
  75   include(CheckAtomic)
  76   include(GetErrcMessages)
  77   include(LLVMDistributionSupport)
  78
  79   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
  80   set(BUG_REPORT_URL "${LLVM_PACKAGE_BUGREPORT}" CACHE STRING
  81     "Default URL where bug reports are to be submitted.")
  82
  83   if (NOT DEFINED LLVM_INCLUDE_TESTS)
  84     set(LLVM_INCLUDE_TESTS ON)
  85   endif()
  86
  87   include_directories(${LLVM_INCLUDE_DIRS})
  88   link_directories("${LLVM_LIBRARY_DIR}")
  89
  90   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
  91   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
  92   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
  93
  94   find_package(Python3 ${LLVM_MINIMUM_PYTHON_VERSION} REQUIRED
  95     COMPONENTS Interpreter)
  96
  97   if(LLVM_INCLUDE_TESTS)
  98     # Check prebuilt llvm/utils.
  99     if(EXISTS ${LLVM_TOOLS_BINARY_DIR}/FileCheck${CMAKE_EXECUTABLE_SUFFIX}
 100         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/count${CMAKE_EXECUTABLE_SUFFIX}
 101         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/not${CMAKE_EXECUTABLE_SUFFIX})
 102       set(LLVM_UTILS_PROVIDED ON)
 103     endif()
 104
 105     # Seek installed Lit.
 106     find_program(LLVM_LIT
 107                  NAMES llvm-lit lit.py lit
 108                  PATHS "${LLVM_MAIN_SRC_DIR}/utils/lit"
 109                  DOC "Path to lit.py")
 110
 111     if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 112       # Note: path not really used, except for checking if lit was found
 113       if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 114         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit utils/llvm-lit)
 115       endif()
 116       if(NOT LLVM_UTILS_PROVIDED)
 117         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/FileCheck utils/FileCheck)
 118         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/count utils/count)
 119         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/not utils/not)
 120         set(LLVM_UTILS_PROVIDED ON)
 121         set(CLANG_TEST_DEPS FileCheck count not)
 122       endif()
 123     endif()
 124
 125     if (NOT TARGET llvm_gtest)
 126         message(FATAL_ERROR "llvm-gtest not found. Please install llvm-gtest or disable tests with -DLLVM_INCLUDE_TESTS=OFF")
 127     endif()
 128
 129     if(LLVM_LIT)
 130       # Define the default arguments to use with 'lit', and an option for the user
 131       # to override.
 132       set(LIT_ARGS_DEFAULT "-sv")
 133       if (MSVC OR XCODE)
 134         set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 135       endif()
 136       set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 137
 138       get_errc_messages(LLVM_LIT_ERRC_MESSAGES)
 139
 140       # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 141       if( WIN32 AND NOT CYGWIN )
 142         set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 143       endif()
 144     else()
 145       set(LLVM_INCLUDE_TESTS OFF)
 146     endif()
 147
 148     umbrella_lit_testsuite_begin(check-all)
 149   endif() # LLVM_INCLUDE_TESTS
 150 endif() # standalone
 151
 152 # This allows disabling clang's XML dependency even if LLVM finds libxml2.
 153 # By default, clang depends on libxml2 if LLVM does.
 154 option(CLANG_ENABLE_LIBXML2 "Whether libclang may depend on libxml2"
 155        ${LLVM_ENABLE_LIBXML2})
 156
 157 if(CLANG_ENABLE_LIBXML2)
 158   # Don't look for libxml if we're using MSan, since uninstrumented third party
 159   # code may call MSan interceptors like strlen, leading to false positives.
 160   if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 161     set (LIBXML2_FOUND 0)
 162     find_package(LibXml2 2.5.3 QUIET)
 163     if (LIBXML2_FOUND)
 164       set(CLANG_HAVE_LIBXML 1)
 165     endif()
 166   endif()
 167 endif()
 168
 169 if(CLANG_ENABLE_CIR)
 170   if (CLANG_BUILT_STANDALONE)
 171     message(FATAL_ERROR
 172       "ClangIR is not yet supported in the standalone build.")
 173   endif()
 174   if (NOT "${LLVM_ENABLE_PROJECTS}" MATCHES "MLIR|mlir")
 175     message(FATAL_ERROR
 176       "Cannot build ClangIR without MLIR in LLVM_ENABLE_PROJECTS")
 177   endif()
 178 endif()
 179
 180 include(CheckIncludeFile)
 181 check_include_file(sys/resource.h CLANG_HAVE_RLIMITS)
 182
 183 # This check requires _GNU_SOURCE on linux
 184 check_include_file(dlfcn.h CLANG_HAVE_DLFCN_H)
 185 if( CLANG_HAVE_DLFCN_H )
 186   include(CheckLibraryExists)
 187   include(CheckSymbolExists)
 188   check_library_exists(dl dlopen "" HAVE_LIBDL)
 189   if( HAVE_LIBDL )
 190     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 191   endif()
 192   list(APPEND CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)
 193   check_symbol_exists(dladdr dlfcn.h CLANG_HAVE_DLADDR)
 194   list(REMOVE_ITEM CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)
 195   if( HAVE_LIBDL )
 196     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 197   endif()
 198 endif()
 199
 200 set(CLANG_RESOURCE_DIR "" CACHE STRING
 201   "Relative directory from the Clang binary to its resource files.")
 202
 203 set(C_INCLUDE_DIRS "" CACHE STRING
 204   "Colon separated list of directories clang will search for headers.")
 205
 206 set(USE_DEPRECATED_GCC_INSTALL_PREFIX OFF CACHE BOOL "Temporary workaround before GCC_INSTALL_PREFIX is completely removed")
 207 set(GCC_INSTALL_PREFIX "" CACHE PATH "Directory where gcc is installed." )
 208 set(DEFAULT_SYSROOT "" CACHE STRING
 209   "Default <path> to all compiler invocations for --sysroot=<path>." )
 210 if(GCC_INSTALL_PREFIX AND NOT USE_DEPRECATED_GCC_INSTALL_PREFIX)
 211   message(FATAL_ERROR "GCC_INSTALL_PREFIX is deprecated and will be removed. Use "
 212     "configuration files (https://clang.llvm.org/docs/UsersManual.html#configuration-files)"
 213     "to specify the default --gcc-install-dir= or --gcc-triple=. --gcc-toolchain= is discouraged. "
 214     "See https://github.com/llvm/llvm-project/pull/77537 for detail.")
 215 endif()
 216
 217 set(ENABLE_LINKER_BUILD_ID OFF CACHE BOOL "pass --build-id to ld")
 218
 219 set(ENABLE_X86_RELAX_RELOCATIONS ON CACHE BOOL
 220     "enable x86 relax relocations by default")
 221
 222 set(PPC_LINUX_DEFAULT_IEEELONGDOUBLE OFF CACHE BOOL
 223     "Enable IEEE binary128 as default long double format on PowerPC Linux.")
 224
 225 set(CLANG_SPAWN_CC1 OFF CACHE BOOL
 226     "Whether clang should use a new process for the CC1 invocation")
 227
 228 option(CLANG_DEFAULT_PIE_ON_LINUX "Default to -fPIE and -pie on linux-gnu" ON)
 229
 230 set(CLANG_DEFAULT_LINKER "" CACHE STRING
 231   "Default linker to use (linker name or absolute path, empty for platform default)")
 232
 233 set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 234   "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default")
 235 if (NOT(CLANG_DEFAULT_CXX_STDLIB STREQUAL "" OR
 236         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libstdc++" OR
 237         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libc++"))
 238   message(WARNING "Resetting default C++ stdlib to use platform default")
 239   set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 240     "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default" FORCE)
 241 endif()
 242
 243 set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 244   "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)")
 245 if (NOT(CLANG_DEFAULT_RTLIB STREQUAL "" OR
 246         CLANG_DEFAULT_RTLIB STREQUAL "libgcc" OR
 247         CLANG_DEFAULT_RTLIB STREQUAL "compiler-rt"))
 248   message(WARNING "Resetting default rtlib to use platform default")
 249   set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 250     "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)" FORCE)
 251 endif()
 252
 253 set(CLANG_DEFAULT_UNWINDLIB "" CACHE STRING
 254   "Default unwind library to use (\"none\" \"libgcc\" or \"libunwind\", empty to match runtime library.)")
 255 if (CLANG_DEFAULT_UNWINDLIB STREQUAL "")
 256   if (CLANG_DEFAULT_RTLIB STREQUAL "libgcc")
 257     set (CLANG_DEFAULT_UNWINDLIB "libgcc" CACHE STRING "" FORCE)
 258   endif()
 259 endif()
 260
 261 if (NOT(CLANG_DEFAULT_UNWINDLIB STREQUAL "" OR
 262         CLANG_DEFAULT_UNWINDLIB STREQUAL "none" OR
 263         CLANG_DEFAULT_UNWINDLIB STREQUAL "libgcc" OR
 264         CLANG_DEFAULT_UNWINDLIB STREQUAL "libunwind"))
 265   message(WARNING "Resetting default unwindlib to use platform default")
 266   set(CLANG_DEFAULT_UNWINDLIB "" CACHE STRING
 267     "Default unwind library to use (\"none\" \"libgcc\" or \"libunwind\", empty to match runtime library.)" FORCE)
 268 endif()
 269
 270 set(CLANG_DEFAULT_OBJCOPY "objcopy" CACHE STRING
 271   "Default objcopy executable to use.")
 272
 273 set(CLANG_DEFAULT_OPENMP_RUNTIME "libomp" CACHE STRING
 274   "Default OpenMP runtime used by -fopenmp.")
 275
 276 set(CLANG_SYSTEMZ_DEFAULT_ARCH "z10" CACHE STRING "SystemZ Default Arch")
 277
 278 set(CLANG_VENDOR ${PACKAGE_VENDOR} CACHE STRING
 279   "Vendor-specific text for showing with version information.")
 280
 281 set(CLANG_REPOSITORY_STRING "" CACHE STRING
 282   "Vendor-specific text for showing the repository the source is taken from.")
 283
 284 if(CLANG_REPOSITORY_STRING)
 285   add_definitions(-DCLANG_REPOSITORY_STRING="${CLANG_REPOSITORY_STRING}")
 286 endif()
 287
 288 set(CLANG_VENDOR_UTI "org.llvm.clang" CACHE STRING
 289   "Vendor-specific uti.")
 290
 291 set(CLANG_PYTHON_BINDINGS_VERSIONS "" CACHE STRING
 292     "Python versions to install libclang python bindings for")
 293
 294 set(CLANG_LINK_CLANG_DYLIB ${LLVM_LINK_LLVM_DYLIB} CACHE BOOL
 295     "Link tools against libclang-cpp.so")
 296
 297 if (NOT LLVM_LINK_LLVM_DYLIB AND CLANG_LINK_CLANG_DYLIB)
 298   message(FATAL_ERROR "Cannot set CLANG_LINK_CLANG_DYLIB=ON when "
 299                       "LLVM_LINK_LLVM_DYLIB=OFF")
 300 endif()
 301
 302 # The libdir suffix must exactly match whatever LLVM's configuration used.
 303 set(CLANG_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}")
 304
 305 set(CLANG_TOOLS_INSTALL_DIR "${CMAKE_INSTALL_BINDIR}" CACHE PATH
 306     "Path for binary subdirectory (defaults to '${CMAKE_INSTALL_BINDIR}')")
 307 mark_as_advanced(CLANG_TOOLS_INSTALL_DIR)
 308
 309 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 310 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 311
 312 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 313   message(FATAL_ERROR "In-source builds are not allowed. "
 314 "Please create a directory and run cmake "
 315 "from there, passing the path to this source directory as the last argument. "
 316 "This process created the file `CMakeCache.txt' and the directory "
 317 "`CMakeFiles'. Please delete them.")
 318 endif()
 319
 320 # If CLANG_VERSION_* is specified, use it, if not use LLVM_VERSION_*.
 321 if(NOT DEFINED CLANG_VERSION_MAJOR)
 322   set(CLANG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 323 endif()
 324 if(NOT DEFINED CLANG_VERSION_MINOR)
 325   set(CLANG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 326 endif()
 327 if(NOT DEFINED CLANG_VERSION_PATCHLEVEL)
 328   set(CLANG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 329 endif()
 330 if(NOT DEFINED CLANG_VERSION_SUFFIX)
 331   set(CLANG_VERSION_SUFFIX ${LLVM_VERSION_SUFFIX})
 332 endif()
 333 set(CLANG_VERSION "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}.${CLANG_VERSION_PATCHLEVEL}${CLANG_VERSION_SUFFIX}")
 334 set(MAX_CLANG_ABI_COMPAT_VERSION "${LLVM_VERSION_MAJOR}")
 335 message(STATUS "Clang version: ${CLANG_VERSION}")
 336
 337 # Configure the Version.inc file.
 338 configure_file(
 339   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 340   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 341
 342 # Add appropriate flags for GCC
 343 if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 344   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual")
 345   if (NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 346     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
 347   endif ()
 348
 349   # Enable -pedantic for Clang even if it's not enabled for LLVM.
 350   if (NOT LLVM_ENABLE_PEDANTIC)
 351     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-long-long")
 352   endif ()
 353
 354   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 355     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 356   endif ()
 357 endif ()
 358
 359 # Determine HOST_LINK_VERSION on Darwin.
 360 set(HOST_LINK_VERSION)
 361 if (APPLE AND NOT CMAKE_LINKER MATCHES ".*lld.*")
 362   get_darwin_linker_version(HOST_LINK_VERSION)
 363   message(STATUS "Host linker version: ${HOST_LINK_VERSION}")
 364 endif()
 365
 366 include(AddClang)
 367
 368 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 369
 370 include_directories(BEFORE
 371   ${CMAKE_CURRENT_BINARY_DIR}/include
 372   ${CMAKE_CURRENT_SOURCE_DIR}/include
 373   )
 374
 375 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 376   install(DIRECTORY include/clang include/clang-c
 377     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 378     COMPONENT clang-headers
 379     FILES_MATCHING
 380     PATTERN "*.def"
 381     PATTERN "*.h"
 382     PATTERN "config.h" EXCLUDE
 383     )
 384
 385   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/clang
 386     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 387     COMPONENT clang-headers
 388     FILES_MATCHING
 389     PATTERN "CMakeFiles" EXCLUDE
 390     PATTERN "*.inc"
 391     PATTERN "*.h"
 392     )
 393
 394   # Installing the headers needs to depend on generating any public
 395   # tablegen'd headers.
 396   add_custom_target(clang-headers DEPENDS clang-tablegen-targets)
 397   set_target_properties(clang-headers PROPERTIES FOLDER "Clang/Resources")
 398   if(NOT LLVM_ENABLE_IDE)
 399     add_llvm_install_targets(install-clang-headers
 400                              DEPENDS clang-headers
 401                              COMPONENT clang-headers)
 402   endif()
 403
 404   add_custom_target(bash-autocomplete DEPENDS utils/bash-autocomplete.sh)
 405   set_target_properties(bash-autocomplete PROPERTIES FOLDER "Clang/Misc")
 406   install(FILES utils/bash-autocomplete.sh
 407           DESTINATION "${CMAKE_INSTALL_DATADIR}/clang"
 408           COMPONENT bash-autocomplete)
 409   if(NOT LLVM_ENABLE_IDE)
 410     add_llvm_install_targets(install-bash-autocomplete
 411                              DEPENDS bash-autocomplete
 412                              COMPONENT bash-autocomplete)
 413   endif()
 414 endif()
 415
 416 option(CLANG_BUILD_TOOLS
 417   "Build the Clang tools. If OFF, just generate build targets." ON)
 418
 419 if(LLVM_ENABLE_PLUGINS OR LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 420   set(HAVE_CLANG_PLUGIN_SUPPORT ON)
 421 else()
 422   set(HAVE_CLANG_PLUGIN_SUPPORT OFF)
 423 endif()
 424 CMAKE_DEPENDENT_OPTION(CLANG_PLUGIN_SUPPORT
 425   "Build clang with plugin support" ON
 426   "HAVE_CLANG_PLUGIN_SUPPORT" OFF)
 427
 428 # If libstdc++ is statically linked, clang-repl needs to statically link libstdc++
 429 # itself, which is not possible in many platforms because of current limitations in
 430 # JIT stack. (more platforms need to be supported by JITLink)
 431 if(NOT LLVM_STATIC_LINK_CXX_STDLIB)
 432   set(HAVE_CLANG_REPL_SUPPORT ON)
 433 endif()
 434
 435 option(CLANG_ENABLE_OBJC_REWRITER "Build the Objective-C rewriter tool" OFF)
 436
 437 option(CLANG_ENABLE_STATIC_ANALYZER
 438   "Include static analyzer in clang binary." ON)
 439
 440 option(CLANG_ENABLE_PROTO_FUZZER "Build Clang protobuf fuzzer." OFF)
 441
 442 if (DEFINED CLANG_ENABLE_ARCMT)
 443   set(CLANG_ENABLE_OBJC_REWRITER ${CLANG_ENABLE_ARCMT})
 444   message(DEPRECATION "'CLANG_ENABLE_ARCMT' is deprecated as ARCMigrate has been removed from Clang. Please use 'CLANG_ENABLE_OBJC_REWRITER' instead to enable or disable the Objective-C rewriter.")
 445 endif()
 446
 447 # This option is a stop-gap, we should commit to removing this as
 448 # soon as possible. See discussion:
 449 # https://discourse.llvm.org/t/rationale-for-removing-versioned-libclang-middle-ground-to-keep-it-behind-option/
 450 option(CLANG_FORCE_MATCHING_LIBCLANG_SOVERSION
 451   "Force the SOVERSION of libclang to be equal to CLANG_MAJOR" ON)
 452
 453 # Clang version information
 454 set(CLANG_EXECUTABLE_VERSION
 455     "${CLANG_VERSION_MAJOR}" CACHE STRING
 456     "Major version number that will be appended to the clang executable name")
 457 set(LIBCLANG_LIBRARY_VERSION
 458     "${CLANG_VERSION_MAJOR}" CACHE STRING
 459     "Major version number that will be appended to the libclang library")
 460 mark_as_advanced(CLANG_EXECUTABLE_VERSION LIBCLANG_LIBRARY_VERSION)
 461
 462 option(CLANG_INCLUDE_TESTS
 463        "Generate build targets for the Clang unit tests."
 464        ${LLVM_INCLUDE_TESTS})
 465
 466 option(CLANG_ENABLE_HLSL "Include HLSL build products" Off)
 467 # While HLSL support is experimental this should stay hidden.
 468 mark_as_advanced(CLANG_ENABLE_HLSL)
 469
 470 add_subdirectory(utils/TableGen)
 471
 472 # Export CLANG_TABLEGEN_EXE for use by flang docs.
 473 set(CLANG_TABLEGEN_EXE "${CLANG_TABLEGEN_EXE}" CACHE INTERNAL "")
 474
 475 add_subdirectory(include)
 476
 477 # All targets below may depend on all tablegen'd files.
 478 get_property(CLANG_TABLEGEN_TARGETS GLOBAL PROPERTY CLANG_TABLEGEN_TARGETS)
 479 add_custom_target(clang-tablegen-targets
 480   DEPENDS
 481   omp_gen
 482   ClangDriverOptions
 483   ${CLANG_TABLEGEN_TARGETS})
 484 set_target_properties(clang-tablegen-targets PROPERTIES FOLDER "Clang/Tablegenning/Targets")
 485 list(APPEND LLVM_COMMON_DEPENDS clang-tablegen-targets)
 486
 487 # Force target to be built as soon as possible. Clang modules builds depend
 488 # header-wise on it as they ship all headers from the umbrella folders. Building
 489 # an entire module might include header, which depends on intrinsics_gen.
 490 if(LLVM_ENABLE_MODULES)
 491   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 492 endif()
 493
 494 add_subdirectory(lib)
 495 add_subdirectory(tools)
 496 add_subdirectory(runtime)
 497
 498 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs by default." OFF)
 499 add_subdirectory(examples)
 500
 501 if(APPLE)
 502   # this line is needed as a cleanup to ensure that any CMakeCaches with the old
 503   # default value get updated to the new default.
 504   if(CLANG_ORDER_FILE STREQUAL "")
 505     unset(CLANG_ORDER_FILE CACHE)
 506     unset(CLANG_ORDER_FILE)
 507   endif()
 508
 509
 510   set(CLANG_ORDER_FILE ${CMAKE_CURRENT_BINARY_DIR}/clang.order CACHE FILEPATH
 511     "Order file to use when compiling clang in order to improve startup time (Darwin Only - requires ld64).")
 512
 513   if(NOT EXISTS ${CLANG_ORDER_FILE})
 514     string(FIND "${CLANG_ORDER_FILE}" "${CMAKE_CURRENT_BINARY_DIR}" PATH_START)
 515     if(PATH_START EQUAL 0)
 516       file(WRITE ${CLANG_ORDER_FILE} "\n")
 517     else()
 518       message(FATAL_ERROR "Specified order file '${CLANG_ORDER_FILE}' does not exist.")
 519     endif()
 520   endif()
 521 endif()
 522
 523
 524 if( CLANG_INCLUDE_TESTS )
 525   find_package(Perl)
 526
 527   add_subdirectory(unittests)
 528   list(APPEND CLANG_TEST_DEPS ClangUnitTests)
 529   list(APPEND CLANG_TEST_PARAMS
 530     clang_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/test/Unit/lit.site.cfg
 531   )
 532   add_subdirectory(test)
 533   add_subdirectory(bindings/python/tests)
 534
 535   if(CLANG_BUILT_STANDALONE)
 536     umbrella_lit_testsuite_end(check-all)
 537   endif()
 538   add_subdirectory(utils/perf-training)
 539 endif()
 540
 541 option(CLANG_INCLUDE_DOCS "Generate build targets for the Clang docs."
 542   ${LLVM_INCLUDE_DOCS})
 543 if( CLANG_INCLUDE_DOCS )
 544   add_subdirectory(docs)
 545 endif()
 546
 547 # Custom target to install all clang libraries.
 548 add_custom_target(clang-libraries)
 549 set_target_properties(clang-libraries PROPERTIES FOLDER "Clang/Install")
 550
 551 if(NOT LLVM_ENABLE_IDE)
 552   add_llvm_install_targets(install-clang-libraries
 553                            DEPENDS clang-libraries
 554                            COMPONENT clang-libraries)
 555 endif()
 556
 557 get_property(CLANG_LIBS GLOBAL PROPERTY CLANG_LIBS)
 558 if(CLANG_LIBS)
 559   list(REMOVE_DUPLICATES CLANG_LIBS)
 560   foreach(lib ${CLANG_LIBS})
 561     add_dependencies(clang-libraries ${lib})
 562     if(NOT LLVM_ENABLE_IDE)
 563       add_dependencies(install-clang-libraries install-${lib})
 564       add_dependencies(install-clang-libraries-stripped install-${lib}-stripped)
 565     endif()
 566   endforeach()
 567 endif()
 568
 569 add_subdirectory(cmake/modules)
 570
 571 if(CLANG_STAGE)
 572   message(STATUS "Setting current clang stage to: ${CLANG_STAGE}")
 573 endif()
 574
 575 if (CLANG_ENABLE_BOOTSTRAP)
 576   include(ExternalProject)
 577
 578   add_custom_target(clang-bootstrap-deps DEPENDS clang)
 579
 580   if(NOT CLANG_STAGE)
 581     set(CLANG_STAGE stage1)
 582   endif()
 583
 584   string(REGEX MATCH "stage([0-9]*)" MATCHED_STAGE "${CLANG_STAGE}")
 585   if(MATCHED_STAGE)
 586     if(NOT LLVM_BUILD_INSTRUMENTED)
 587       math(EXPR STAGE_NUM "${CMAKE_MATCH_1} + 1")
 588       set(NEXT_CLANG_STAGE stage${STAGE_NUM})
 589     else()
 590       set(NEXT_CLANG_STAGE stage${CMAKE_MATCH_1})
 591     endif()
 592   else()
 593     set(NEXT_CLANG_STAGE bootstrap)
 594   endif()
 595
 596   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 597     set(NEXT_CLANG_STAGE ${NEXT_CLANG_STAGE}-instrumented)
 598   endif()
 599   message(STATUS "Setting next clang stage to: ${NEXT_CLANG_STAGE}")
 600
 601
 602   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-stamps/)
 603   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-bins/)
 604
 605   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 606     # adding lld to clang-bootstrap-deps without having it enabled in
 607     # LLVM_ENABLE_PROJECTS just generates a cryptic error message.
 608     if (NOT "lld" IN_LIST LLVM_ENABLE_PROJECTS)
 609       message(FATAL_ERROR "LLD is enabled in the bootstrap build, but lld is not in LLVM_ENABLE_PROJECTS")
 610     endif()
 611     add_dependencies(clang-bootstrap-deps lld)
 612   endif()
 613
 614   if (WIN32)
 615     # Build llvm-rc and llvm-mt which are needed by the Windows build.
 616     add_dependencies(clang-bootstrap-deps llvm-rc)
 617     if(LLVM_ENABLE_LIBXML2)
 618       add_dependencies(clang-bootstrap-deps llvm-mt)
 619     endif()
 620   endif()
 621
 622   # If the next stage is LTO we need to depend on LTO and possibly lld or LLVMgold
 623   if(BOOTSTRAP_LLVM_ENABLE_LTO OR LLVM_ENABLE_LTO AND NOT LLVM_BUILD_INSTRUMENTED)
 624     if(APPLE)
 625       add_dependencies(clang-bootstrap-deps LTO)
 626       # on Darwin we need to set DARWIN_LTO_LIBRARY so that -flto will work
 627       # using the just-built compiler, and we need to override DYLD_LIBRARY_PATH
 628       # so that the host object file tools will use the just-built libLTO.
 629       # However if System Integrity Protection is enabled the DYLD variables
 630       # will be scrubbed from the environment of any base system commands. This
 631       # includes /bin/sh, which ninja uses when executing build commands. To
 632       # work around the envar being filtered away we pass it in as a CMake
 633       # variable, and have LLVM's CMake append the envar to the archiver calls.
 634       set(LTO_LIBRARY -DDARWIN_LTO_LIBRARY=${LLVM_SHLIB_OUTPUT_INTDIR}/libLTO.dylib
 635         -DDYLD_LIBRARY_PATH=${LLVM_LIBRARY_OUTPUT_INTDIR})
 636     elseif(MSVC)
 637       add_dependencies(clang-bootstrap-deps llvm-lib)
 638       set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-lib)
 639     elseif(NOT WIN32)
 640       add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 641       if(NOT BOOTSTRAP_LLVM_ENABLE_LLD AND LLVM_BINUTILS_INCDIR)
 642         add_dependencies(clang-bootstrap-deps LLVMgold)
 643       endif()
 644       set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 645       set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 646     endif()
 647   endif()
 648
 649   if(CLANG_BOOTSTRAP_EXTRA_DEPS)
 650     add_dependencies(clang-bootstrap-deps ${CLANG_BOOTSTRAP_EXTRA_DEPS})
 651   endif()
 652
 653   add_custom_target(${NEXT_CLANG_STAGE}-clear
 654     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 655     )
 656   add_custom_command(
 657     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 658     DEPENDS clang-bootstrap-deps
 659     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
 660     COMMAND ${CMAKE_COMMAND} -E make_directory ${BINARY_DIR}
 661     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
 662     COMMAND ${CMAKE_COMMAND} -E make_directory ${STAMP_DIR}
 663     COMMENT "Clobberring ${NEXT_CLANG_STAGE} build and stamp directories"
 664     )
 665
 666   if(CMAKE_VERBOSE_MAKEFILE)
 667     set(verbose -DCMAKE_VERBOSE_MAKEFILE=On)
 668   endif()
 669
 670   set(_BOOTSTRAP_DEFAULT_PASSTHROUGH
 671     PACKAGE_VERSION
 672     PACKAGE_VENDOR
 673     LLVM_VERSION_MAJOR
 674     LLVM_VERSION_MINOR
 675     LLVM_VERSION_PATCH
 676     CLANG_VERSION_MAJOR
 677     CLANG_VERSION_MINOR
 678     CLANG_VERSION_PATCHLEVEL
 679     CLANG_VERSION_SUFFIX
 680     CLANG_VENDOR
 681     LLVM_VERSION_SUFFIX
 682     LLVM_BINUTILS_INCDIR
 683     CLANG_REPOSITORY_STRING
 684     CMAKE_MAKE_PROGRAM
 685     CMAKE_OSX_ARCHITECTURES
 686     CMAKE_BUILD_TYPE
 687     LLVM_ENABLE_PROJECTS
 688     LLVM_ENABLE_RUNTIMES)
 689
 690   # We don't need to depend on compiler-rt/libcxx if we're building instrumented
 691   # because the next stage will use the same compiler used to build this stage.
 692   if(NOT LLVM_BUILD_INSTRUMENTED)
 693     if(TARGET compiler-rt)
 694       add_dependencies(clang-bootstrap-deps compiler-rt)
 695     endif()
 696     if(TARGET cxx-headers)
 697       add_dependencies(clang-bootstrap-deps cxx-headers)
 698     endif()
 699   endif()
 700
 701   set(C_COMPILER "clang")
 702   set(CXX_COMPILER "clang++")
 703   if(WIN32)
 704     set(C_COMPILER "clang-cl.exe")
 705     set(CXX_COMPILER "clang-cl.exe")
 706   endif()
 707
 708   set(COMPILER_OPTIONS
 709     -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${CXX_COMPILER}
 710     -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 711     -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 712     -DCMAKE_ASM_COMPILER_ID=Clang)
 713
 714   # cmake requires CMAKE_LINKER to be specified if the compiler is MSVC-like,
 715   # otherwise it defaults the linker to be link.exe.
 716   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 717     if((WIN32 AND NOT BOOTSTRAP_CMAKE_SYSTEM_NAME) OR BOOTSTRAP_CMAKE_SYSTEM_NAME STREQUAL "Windows")
 718       set(${CLANG_STAGE}_LINKER -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/lld-link${CMAKE_EXECUTABLE_SUFFIX})
 719     endif()
 720   endif()
 721
 722   if(BOOTSTRAP_CMAKE_SYSTEM_NAME)
 723     set(${CLANG_STAGE}_TABLEGEN
 724       -DLLVM_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-tblgen
 725       -DCLANG_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-tblgen)
 726     if(BOOTSTRAP_CMAKE_SYSTEM_NAME STREQUAL "Linux")
 727       if(BOOTSTRAP_LLVM_ENABLE_LLD)
 728         set(${CLANG_STAGE}_LINKER -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/ld.lld)
 729       endif()
 730       if(NOT BOOTSTRAP_LLVM_ENABLE_LTO)
 731         add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 732         set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 733         set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 734       endif()
 735       add_dependencies(clang-bootstrap-deps llvm-objcopy llvm-strip)
 736       set(${CLANG_STAGE}_OBJCOPY -DCMAKE_OBJCOPY=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-objcopy)
 737       set(${CLANG_STAGE}_STRIP -DCMAKE_STRIP=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-strip)
 738       set(${CLANG_STAGE}_READELF -DCMAKE_READELF=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-readelf)
 739     endif()
 740   endif()
 741
 742   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 743     add_dependencies(clang-bootstrap-deps llvm-profdata)
 744     set(PGO_OPT -DLLVM_PROFDATA=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-profdata)
 745   endif()
 746
 747   if(LLVM_BUILD_INSTRUMENTED)
 748     add_dependencies(clang-bootstrap-deps generate-profdata)
 749     set(PGO_OPT -DLLVM_PROFDATA_FILE=${CMAKE_CURRENT_BINARY_DIR}/utils/perf-training/clang.profdata)
 750     # Use the current tools for LTO instead of the instrumented ones
 751     list(APPEND _BOOTSTRAP_DEFAULT_PASSTHROUGH
 752       CMAKE_CXX_COMPILER
 753       CMAKE_C_COMPILER
 754       CMAKE_ASM_COMPILER
 755       CMAKE_AR
 756       CMAKE_RANLIB
 757       DARWIN_LTO_LIBRARY
 758       DYLD_LIBRARY_PATH)
 759
 760     set(COMPILER_OPTIONS)
 761     set(LTO_LIBRARY)
 762     set(LTO_AR)
 763     set(LTO_RANLIB)
 764   endif()
 765
 766   # Populate the passthrough variables
 767   foreach(variableName ${CLANG_BOOTSTRAP_PASSTHROUGH} ${_BOOTSTRAP_DEFAULT_PASSTHROUGH})
 768     if(DEFINED ${variableName})
 769       if("${${variableName}}" STREQUAL "")
 770         set(value "")
 771       else()
 772         string(REPLACE ";" "|" value "${${variableName}}")
 773       endif()
 774       list(APPEND PASSTHROUGH_VARIABLES
 775         -D${variableName}=${value})
 776     endif()
 777   endforeach()
 778
 779   # Find all variables that start with BOOTSTRAP_ and populate a variable with
 780   # them.
 781   get_cmake_property(variableNames VARIABLES)
 782   foreach(variableName ${variableNames})
 783     if(variableName MATCHES "^BOOTSTRAP_")
 784       string(SUBSTRING ${variableName} 10 -1 varName)
 785       string(REPLACE ";" "|" value "${${variableName}}")
 786       list(APPEND PASSTHROUGH_VARIABLES
 787         -D${varName}=${value})
 788     endif()
 789     if(${variableName} AND variableName MATCHES "LLVM_EXTERNAL_.*_SOURCE_DIR")
 790       list(APPEND PASSTHROUGH_VARIABLES
 791         -D${variableName}=${${variableName}})
 792     endif()
 793   endforeach()
 794
 795   # Build arguments for native tool used in CMake.
 796   set(build_configuration "$<CONFIG>")
 797   set(build_tool_args "${LLVM_EXTERNAL_PROJECT_BUILD_TOOL_ARGS}")
 798   if(NOT build_tool_args STREQUAL "")
 799     string(PREPEND build_tool_args "-- ")
 800     separate_arguments(build_tool_args UNIX_COMMAND "${build_tool_args}")
 801   endif()
 802
 803   ExternalProject_Add(${NEXT_CLANG_STAGE}
 804     DEPENDS clang-bootstrap-deps
 805     PREFIX ${NEXT_CLANG_STAGE}
 806     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 807     STAMP_DIR ${STAMP_DIR}
 808     BINARY_DIR ${BINARY_DIR}
 809     EXCLUDE_FROM_ALL 1
 810     CMAKE_ARGS
 811                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 812                 # seem to work, so instead I'm passing this through
 813                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 814                 ${PASSTHROUGH_VARIABLES}
 815                 ${CLANG_BOOTSTRAP_CMAKE_ARGS}
 816                  -DCLANG_STAGE=${NEXT_CLANG_STAGE}
 817                 ${COMPILER_OPTIONS}
 818                 ${${CLANG_STAGE}_TABLEGEN}
 819                 ${LTO_LIBRARY} ${verbose} ${PGO_OPT}
 820                 ${${CLANG_STAGE}_LINKER}
 821                 ${${CLANG_STAGE}_AR}
 822                 ${${CLANG_STAGE}_RANLIB}
 823                 ${${CLANG_STAGE}_OBJCOPY}
 824                 ${${CLANG_STAGE}_STRIP}
 825     BUILD_COMMAND ${CMAKE_COMMAND} --build ${BINARY_DIR}
 826                                    --config ${build_configuration}
 827                                    ${build_tool_args}
 828     INSTALL_COMMAND ""
 829     STEP_TARGETS configure build
 830     USES_TERMINAL_CONFIGURE 1
 831     USES_TERMINAL_BUILD 1
 832     USES_TERMINAL_INSTALL 1
 833     LIST_SEPARATOR |
 834     )
 835
 836   # exclude really-install from main target
 837   set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_really-install_EXCLUDE_FROM_MAIN On)
 838   ExternalProject_Add_Step(${NEXT_CLANG_STAGE} really-install
 839     COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target install
 840     COMMENT "Performing install step for '${NEXT_CLANG_STAGE}'"
 841     DEPENDEES build
 842     USES_TERMINAL 1
 843   )
 844   ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} really-install)
 845   add_custom_target(${NEXT_CLANG_STAGE}-install DEPENDS ${NEXT_CLANG_STAGE}-really-install)
 846
 847   if(NOT CLANG_BOOTSTRAP_TARGETS)
 848     set(CLANG_BOOTSTRAP_TARGETS check-llvm check-clang check-all)
 849   endif()
 850   foreach(target ${CLANG_BOOTSTRAP_TARGETS})
 851
 852     ExternalProject_Add_Step(${NEXT_CLANG_STAGE} ${target}
 853       COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target ${target}
 854       COMMENT "Performing ${target} for '${NEXT_CLANG_STAGE}'"
 855       DEPENDEES configure
 856       # We need to set ALWAYS to ON here, otherwise these targets won't be
 857       # built on a second invocation of ninja.  The targets have their own
 858       # logic to determine if they should build or not so setting ALWAYS ON
 859       # here does not mean the targets will always rebuild it just means that
 860       # they will check their dependenices and see if they need to be built.
 861       ALWAYS ON
 862       EXCLUDE_FROM_MAIN ON
 863       USES_TERMINAL 1
 864     )
 865
 866     if(target MATCHES "^stage[0-9]*")
 867       add_custom_target(${target} DEPENDS ${NEXT_CLANG_STAGE}-${target})
 868     endif()
 869
 870     ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} ${target})
 871   endforeach()
 872 endif()
 873
 874 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 875   add_subdirectory(utils/ClangVisualizers)
 876 endif()
 877 add_subdirectory(utils/hmaptool)
 878
 879 if(CLANG_BUILT_STANDALONE)
 880   llvm_distribution_add_targets()
 881   process_llvm_pass_plugins()
 882 endif()
 883
 884 set(CLANG_INSTALL_LIBDIR_BASENAME "lib${CLANG_LIBDIR_SUFFIX}")
 885
 886 configure_file(
 887   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 888   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)