polly/CMakeLists.txt

   1 # Check if this is a in tree build.
   2 if (NOT DEFINED LLVM_MAIN_SRC_DIR)
   3   project(Polly)
   4   cmake_minimum_required(VERSION 3.20.0)
   5   set(POLLY_STANDALONE_BUILD TRUE)
   6 endif()
   7 set(LLVM_SUBPROJECT_TITLE "Polly")
   8
   9 # Must go below project(..)
  10 include(GNUInstallDirs)
  11
  12 if(POLLY_STANDALONE_BUILD)
  13   # Where is LLVM installed?
  14   find_package(LLVM CONFIG REQUIRED)
  15   set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${LLVM_CMAKE_DIR})
  16   include(HandleLLVMOptions)
  17   include(AddLLVM)
  18
  19   # Add the llvm header path.
  20   include_directories(${LLVM_INCLUDE_DIRS})
  21
  22   # Sources available, too?
  23   if (LLVM_BUILD_MAIN_SRC_DIR)
  24     set(default_llvm_src "${LLVM_BUILD_MAIN_SRC_DIR}")
  25   else()
  26     set(default_llvm_src "${CMAKE_CURRENT_SOURCE_DIR}/../llvm")
  27   endif()
  28   set(LLVM_SOURCE_ROOT ${default_llvm_src} CACHE PATH "Path to LLVM source tree")
  29
  30   # Enable unit tests if available.
  31   set(POLLY_GTEST_AVAIL 0)
  32   if(TARGET llvm_gtest)
  33     set(POLLY_GTEST_AVAIL 1)
  34   endif()
  35
  36   if (LLVM_ENABLE_PIC)
  37     # Make sure the isl c files are built as fPIC if possible
  38     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
  39   endif ()
  40
  41   # Set directory for polly-isl-test.
  42   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/bin")
  43 else ()
  44   set(LLVM_SOURCE_ROOT "${LLVM_MAIN_SRC_DIR}")
  45   set(POLLY_GTEST_AVAIL 1)
  46 endif ()
  47
  48 set(POLLY_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  49 set(POLLY_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  50
  51 if(NOT DEFINED LLVM_COMMON_CMAKE_UTILS)
  52   set(LLVM_COMMON_CMAKE_UTILS ${POLLY_SOURCE_DIR}/../cmake)
  53 endif()
  54
  55 # Make sure that our source directory is on the current cmake module path so that
  56 # we can include cmake files from this directory.
  57 list(INSERT CMAKE_MODULE_PATH 0
  58   "${POLLY_SOURCE_DIR}/cmake"
  59   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
  60   )
  61
  62 include("polly_macros")
  63
  64 # Add appropriate flags for GCC
  65 if (CMAKE_COMPILER_IS_GNUCXX)
  66   # FIXME: Turn off exceptions, RTTI:
  67   # -fno-exceptions -fno-rtti
  68   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings -fno-exceptions -fno-rtti")
  69 elseif (MSVC)
  70   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHs-c-")
  71   add_definitions("-D_HAS_EXCEPTIONS=0")
  72 else ()
  73   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  74 endif ()
  75
  76 SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  77
  78 option(POLLY_BUNDLED_ISL "Use the bundled version of libisl included in Polly" ON)
  79 if (NOT POLLY_BUNDLED_ISL)
  80   find_package(ISL MODULE REQUIRED)
  81   message(STATUS "Using external libisl ${ISL_VERSION} in: ${ISL_PREFIX}")
  82   set(ISL_TARGET ISL)
  83 else()
  84   set(ISL_INCLUDE_DIRS
  85     ${CMAKE_CURRENT_BINARY_DIR}/lib/External/isl/include
  86     ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/isl/include
  87   )
  88   set(ISL_TARGET PollyISL)
  89 endif()
  90
  91 include_directories(
  92   BEFORE
  93   ${CMAKE_CURRENT_SOURCE_DIR}/include
  94   ${ISL_INCLUDE_DIRS}
  95   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/pet/include
  96   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External
  97   ${CMAKE_CURRENT_BINARY_DIR}/include
  98   )
  99
 100 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 101   install(DIRECTORY include/
 102     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 103     FILES_MATCHING
 104     PATTERN "*.h"
 105     )
 106
 107   install(DIRECTORY ${POLLY_BINARY_DIR}/include/
 108     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 109     FILES_MATCHING
 110     PATTERN "*.h"
 111     PATTERN "CMakeFiles" EXCLUDE
 112     )
 113 endif()
 114
 115 # add_llvm_pass_plugin() already declares the option, but we need access to
 116 # it earlier than that.
 117 set(link_into_tools_default OFF)
 118 if (LLVM_TOOL_POLLY_BUILD)
 119   set(link_into_tools_default ON)
 120 endif()
 121 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ${link_into_tools_default})
 122
 123 add_definitions( -D_GNU_SOURCE )
 124
 125 add_subdirectory(docs)
 126 add_subdirectory(lib)
 127 add_subdirectory(test)
 128 if (POLLY_GTEST_AVAIL)
 129   add_subdirectory(unittests)
 130 endif ()
 131 add_subdirectory(cmake)
 132 # TODO: docs.
 133
 134
 135 configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/include/polly/Config/config.h.cmake
 136                 ${POLLY_BINARY_DIR}/include/polly/Config/config.h )
 137
 138 # Add target to check formatting of polly files
 139 file( GLOB_RECURSE files *.h lib/*.cpp lib/*.c tools/*.cpp tools/*.c tools/*.h unittests/*.cpp)
 140 file( GLOB_RECURSE external lib/External/*.h lib/External/*.c lib/External/*.cpp isl_config.h)
 141 list( REMOVE_ITEM files ${external})
 142
 143 set(check_format_depends)
 144 set(update_format_depends)
 145 set(i 0)
 146 foreach (file IN LISTS files)
 147   add_custom_command(OUTPUT polly-check-format${i}
 148     COMMAND clang-format -sort-includes -style=llvm ${file} | diff -u ${file} -
 149     VERBATIM
 150     COMMENT "Checking format of ${file}..."
 151   )
 152   list(APPEND check_format_depends "polly-check-format${i}")
 153
 154   add_custom_command(OUTPUT polly-update-format${i}
 155     COMMAND clang-format -sort-includes -i -style=llvm ${file}
 156     VERBATIM
 157     COMMENT "Updating format of ${file}..."
 158   )
 159   list(APPEND update_format_depends "polly-update-format${i}")
 160
 161   math(EXPR i ${i}+1)
 162 endforeach ()
 163
 164 add_custom_target(polly-check-format DEPENDS ${check_format_depends})
 165 set_target_properties(polly-check-format PROPERTIES FOLDER "Polly/Metatargets")
 166
 167 add_custom_target(polly-update-format DEPENDS ${update_format_depends})
 168 set_target_properties(polly-update-format PROPERTIES FOLDER "Polly/Metatargets")