libunwind/CMakeLists.txt

   1 if (NOT IS_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}/../libcxx")
   2   message(FATAL_ERROR "libunwind requires being built in a monorepo layout with libcxx available")
   3 endif()
   4
   5 #===============================================================================
   6 # Setup Project
   7 #===============================================================================
   8
   9 cmake_minimum_required(VERSION 3.13.4)
  10
  11 include(GNUInstallDirs)
  12
  13 set(LLVM_COMMON_CMAKE_UTILS "${CMAKE_CURRENT_SOURCE_DIR}/../cmake")
  14
  15 # Add path for custom modules
  16 list(INSERT CMAKE_MODULE_PATH 0
  17   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  18   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
  19   "${LLVM_COMMON_CMAKE_UTILS}"
  20   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
  21   )
  22
  23 set(LIBUNWIND_SOURCE_DIR  ${CMAKE_CURRENT_SOURCE_DIR})
  24 set(LIBUNWIND_BINARY_DIR  ${CMAKE_CURRENT_BINARY_DIR})
  25 set(LIBUNWIND_LIBCXX_PATH "${CMAKE_CURRENT_LIST_DIR}/../libcxx" CACHE PATH
  26         "Specify path to libc++ source.")
  27
  28 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR OR LIBUNWIND_STANDALONE_BUILD)
  29   # We may have an incomplete toolchain - do language support tests without
  30   # linking.
  31   include(EnableLanguageNolink)
  32   project(libunwind LANGUAGES NONE)
  33   llvm_enable_language_nolink(C CXX ASM)
  34
  35   set(PACKAGE_NAME libunwind)
  36   set(PACKAGE_VERSION 14.0.0git)
  37   set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  38   set(PACKAGE_BUGREPORT "llvm-bugs@lists.llvm.org")
  39
  40   # Add the CMake module path of libcxx so we can reuse HandleOutOfTreeLLVM.cmake
  41   set(LIBUNWIND_LIBCXX_CMAKE_PATH "${LIBUNWIND_LIBCXX_PATH}/cmake/Modules")
  42   list(APPEND CMAKE_MODULE_PATH "${LIBUNWIND_LIBCXX_CMAKE_PATH}")
  43
  44   # In a standalone build, we don't have llvm to automatically generate the
  45   # llvm-lit script for us.  So we need to provide an explicit directory that
  46   # the configurator should write the script into.
  47   set(LIBUNWIND_STANDALONE_BUILD 1)
  48   set(LLVM_LIT_OUTPUT_DIR "${LIBUNWIND_BINARY_DIR}/bin")
  49
  50   # Find the LLVM sources and simulate LLVM CMake options.
  51   include(HandleOutOfTreeLLVM)
  52 else()
  53   set(LLVM_LIT "${CMAKE_SOURCE_DIR}/utils/lit/lit.py")
  54 endif()
  55
  56 #===============================================================================
  57 # Setup CMake Options
  58 #===============================================================================
  59 include(CMakeDependentOption)
  60 include(HandleCompilerRT)
  61
  62 # Define options.
  63 option(LIBUNWIND_BUILD_32_BITS "Build 32 bit multilib libunwind. This option is not supported anymore when building the runtimes. Please specify a full triple instead." ${LLVM_BUILD_32_BITS})
  64 if (LIBUNWIND_BUILD_32_BITS)
  65   message(FATAL_ERROR "LIBUNWIND_BUILD_32_BITS is not supported anymore when building the runtimes, please specify a full triple instead.")
  66 endif()
  67
  68 option(LIBUNWIND_ENABLE_CET "Build libunwind with CET enabled." OFF)
  69 option(LIBUNWIND_ENABLE_ASSERTIONS "Enable assertions independent of build mode." ON)
  70 option(LIBUNWIND_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
  71 option(LIBUNWIND_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
  72 option(LIBUNWIND_ENABLE_SHARED "Build libunwind as a shared library." ON)
  73 option(LIBUNWIND_ENABLE_STATIC "Build libunwind as a static library." ON)
  74 option(LIBUNWIND_ENABLE_CROSS_UNWINDING "Enable cross-platform unwinding support." OFF)
  75 option(LIBUNWIND_ENABLE_ARM_WMMX "Enable unwinding support for ARM WMMX registers." OFF)
  76 option(LIBUNWIND_ENABLE_THREADS "Build libunwind with threading support." ON)
  77 option(LIBUNWIND_WEAK_PTHREAD_LIB "Use weak references to refer to pthread functions." OFF)
  78 option(LIBUNWIND_USE_COMPILER_RT "Use compiler-rt instead of libgcc" OFF)
  79 option(LIBUNWIND_INCLUDE_DOCS "Build the libunwind documentation." ${LLVM_INCLUDE_DOCS})
  80 option(LIBUNWIND_INCLUDE_TESTS "Build the libunwind tests." ${LLVM_INCLUDE_TESTS})
  81 option(LIBUNWIND_IS_BAREMETAL "Build libunwind for baremetal targets." OFF)
  82 option(LIBUNWIND_USE_FRAME_HEADER_CACHE "Cache frame headers for unwinding. Requires locking dl_iterate_phdr." OFF)
  83 option(LIBUNWIND_REMEMBER_HEAP_ALLOC "Use heap instead of the stack for .cfi_remember_state." OFF)
  84 option(LIBUNWIND_INSTALL_HEADERS "Install the libunwind headers." OFF)
  85
  86 set(LIBUNWIND_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}" CACHE STRING
  87     "Define suffix of library directory name (32/64)")
  88 option(LIBUNWIND_INSTALL_LIBRARY "Install the libunwind library." ON)
  89 cmake_dependent_option(LIBUNWIND_INSTALL_STATIC_LIBRARY
  90   "Install the static libunwind library." ON
  91   "LIBUNWIND_ENABLE_STATIC;LIBUNWIND_INSTALL_LIBRARY" OFF)
  92 cmake_dependent_option(LIBUNWIND_INSTALL_SHARED_LIBRARY
  93   "Install the shared libunwind library." ON
  94   "LIBUNWIND_ENABLE_SHARED;LIBUNWIND_INSTALL_LIBRARY" OFF)
  95 if(CMAKE_CXX_COMPILER_TARGET)
  96   set(LIBUNWIND_DEFAULT_TARGET_TRIPLE "${CMAKE_CXX_COMPILER_TARGET}")
  97 else()
  98   set(LIBUNWIND_DEFAULT_TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
  99 endif()
 100 set(LIBUNWIND_TARGET_TRIPLE "${LIBUNWIND_DEFAULT_TARGET_TRIPLE}" CACHE STRING "Target triple for cross compiling.")
 101 set(LIBUNWIND_GCC_TOOLCHAIN "${CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN}" CACHE PATH "GCC toolchain for cross compiling.")
 102 set(LIBUNWIND_SYSROOT "${CMAKE_SYSROOT}" CACHE PATH "Sysroot for cross compiling.")
 103 set(LIBUNWIND_TEST_LINKER_FLAGS "" CACHE STRING
 104     "Additional linker flags for test programs.")
 105 set(LIBUNWIND_TEST_COMPILER_FLAGS "" CACHE STRING
 106     "Additional compiler flags for test programs.")
 107
 108 if (LIBUNWIND_ENABLE_SHARED)
 109   set(LIBUNWIND_DEFAULT_TEST_CONFIG "llvm-libunwind-shared.cfg.in")
 110 else()
 111   set(LIBUNWIND_DEFAULT_TEST_CONFIG "llvm-libunwind-static.cfg.in")
 112 endif()
 113 set(LIBUNWIND_TEST_CONFIG "${LIBUNWIND_DEFAULT_TEST_CONFIG}" CACHE STRING
 114   "The path to the Lit testing configuration to use when running the tests.
 115    If a relative path is provided, it is assumed to be relative to '<monorepo>/libunwind/test/configs'.")
 116 if (NOT IS_ABSOLUTE "${LIBUNWIND_TEST_CONFIG}")
 117   set(LIBUNWIND_TEST_CONFIG "${CMAKE_CURRENT_SOURCE_DIR}/test/configs/${LIBUNWIND_TEST_CONFIG}")
 118 endif()
 119 set(LIBUNWIND_TEST_PARAMS "" CACHE STRING
 120     "A list of parameters to run the Lit test suite with.")
 121
 122 if (NOT LIBUNWIND_ENABLE_SHARED AND NOT LIBUNWIND_ENABLE_STATIC)
 123   message(FATAL_ERROR "libunwind must be built as either a shared or static library.")
 124 endif()
 125
 126 if (LIBUNWIND_ENABLE_CET AND MSVC)
 127   message(FATAL_ERROR "libunwind CET support is not available for MSVC!")
 128 endif()
 129
 130 option(LIBUNWIND_HIDE_SYMBOLS
 131   "Do not export any symbols from the static library." OFF)
 132
 133 #===============================================================================
 134 # Configure System
 135 #===============================================================================
 136
 137 # Add path for custom modules
 138 set(CMAKE_MODULE_PATH
 139     "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 140     ${CMAKE_MODULE_PATH})
 141
 142 set(LIBUNWIND_INSTALL_INCLUDE_DIR "${CMAKE_INSTALL_INCLUDEDIR}" CACHE PATH
 143     "Path where built libunwind headers should be installed.")
 144 set(LIBUNWIND_INSTALL_RUNTIME_DIR "${CMAKE_INSTALL_BINDIR}" CACHE PATH
 145     "Path where built libunwind runtime libraries should be installed.")
 146
 147 if(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR AND NOT APPLE)
 148   set(LIBUNWIND_LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}/${LLVM_DEFAULT_TARGET_TRIPLE})
 149   set(LIBUNWIND_INSTALL_LIBRARY_DIR lib${LLVM_LIBDIR_SUFFIX}/${LLVM_DEFAULT_TARGET_TRIPLE} CACHE PATH
 150       "Path where built libunwind libraries should be installed.")
 151   if(LIBCXX_LIBDIR_SUBDIR)
 152     string(APPEND LIBUNWIND_LIBRARY_DIR /${LIBUNWIND_LIBDIR_SUBDIR})
 153     string(APPEND LIBUNWIND_INSTALL_LIBRARY_DIR /${LIBUNWIND_LIBDIR_SUBDIR})
 154   endif()
 155 else()
 156   if(LLVM_LIBRARY_OUTPUT_INTDIR)
 157     set(LIBUNWIND_LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 158   else()
 159     set(LIBUNWIND_LIBRARY_DIR ${CMAKE_BINARY_DIR}/lib${LIBUNWIND_LIBDIR_SUFFIX})
 160   endif()
 161   set(LIBUNWIND_INSTALL_LIBRARY_DIR lib${LIBUNWIND_LIBDIR_SUFFIX} CACHE PATH
 162       "Path where built libunwind libraries should be installed.")
 163 endif()
 164
 165 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LIBUNWIND_LIBRARY_DIR})
 166 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LIBUNWIND_LIBRARY_DIR})
 167 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LIBUNWIND_LIBRARY_DIR})
 168
 169 set(LIBUNWIND_C_FLAGS "")
 170 set(LIBUNWIND_CXX_FLAGS "")
 171 set(LIBUNWIND_COMPILE_FLAGS "")
 172 set(LIBUNWIND_LINK_FLAGS "")
 173
 174 # Include macros for adding and removing libunwind flags.
 175 include(HandleLibunwindFlags)
 176
 177 #===============================================================================
 178 # Setup Compiler Flags
 179 #===============================================================================
 180
 181 # Compiler tests may be failing if the compiler implicitly links in libunwind,
 182 # which doesn't exist yet. This gets waived by --unwindlib=none
 183 # later in config-ix below, but the tests for --target etc before that may
 184 # be failing due to it. Only test compilation, not linking, for these
 185 # tests here now.
 186 set(CMAKE_TRY_COMPILE_TARGET_TYPE_ORIG ${CMAKE_TRY_COMPILE_TARGET_TYPE})
 187 set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)
 188
 189 if(LIBUNWIND_TARGET_TRIPLE)
 190   add_target_flags_if_supported("--target=${LIBUNWIND_TARGET_TRIPLE}")
 191 endif()
 192 if(LIBUNWIND_GCC_TOOLCHAIN)
 193   add_target_flags_if_supported("--gcc-toolchain=${LIBUNWIND_GCC_TOOLCHAIN}")
 194 endif()
 195 if(LIBUNWIND_SYSROOT)
 196   add_target_flags_if_supported("--sysroot=${LIBUNWIND_SYSROOT}")
 197 endif()
 198 set(CMAKE_TRY_COMPILE_TARGET_TYPE ${CMAKE_TRY_COMPILE_TARGET_TYPE_ORIG})
 199
 200 # Configure compiler.
 201 include(config-ix)
 202
 203 if (LIBUNWIND_USE_COMPILER_RT AND NOT LIBUNWIND_HAS_NODEFAULTLIBS_FLAG)
 204   list(APPEND LIBUNWIND_LINK_FLAGS "-rtlib=compiler-rt")
 205 endif()
 206
 207 add_compile_flags_if_supported(-Werror=return-type)
 208
 209 if (LIBUNWIND_ENABLE_CET)
 210   add_compile_flags_if_supported(-fcf-protection=full)
 211   add_compile_flags_if_supported(-mshstk)
 212   if (NOT LIBUNWIND_SUPPORTS_FCF_PROTECTION_EQ_FULL_FLAG)
 213     message(SEND_ERROR "Compiler doesn't support CET -fcf-protection option!")
 214   endif()
 215   if (NOT LIBUNWIND_SUPPORTS_MSHSTK_FLAG)
 216     message(SEND_ERROR "Compiler doesn't support CET -mshstk option!")
 217   endif()
 218 endif()
 219
 220 # Get warning flags
 221 add_compile_flags_if_supported(-W)
 222 add_compile_flags_if_supported(-Wall)
 223 add_compile_flags_if_supported(-Wchar-subscripts)
 224 add_compile_flags_if_supported(-Wconversion)
 225 add_compile_flags_if_supported(-Wmismatched-tags)
 226 add_compile_flags_if_supported(-Wmissing-braces)
 227 add_compile_flags_if_supported(-Wnewline-eof)
 228 add_compile_flags_if_supported(-Wno-unused-function)
 229 add_compile_flags_if_supported(-Wshadow)
 230 add_compile_flags_if_supported(-Wshorten-64-to-32)
 231 add_compile_flags_if_supported(-Wsign-compare)
 232 add_compile_flags_if_supported(-Wsign-conversion)
 233 add_compile_flags_if_supported(-Wstrict-aliasing=2)
 234 add_compile_flags_if_supported(-Wstrict-overflow=4)
 235 add_compile_flags_if_supported(-Wunused-parameter)
 236 add_compile_flags_if_supported(-Wunused-variable)
 237 add_compile_flags_if_supported(-Wwrite-strings)
 238 add_compile_flags_if_supported(-Wundef)
 239
 240 add_compile_flags_if_supported(-Wno-suggest-override)
 241
 242 if (WIN32)
 243   # The headers lack matching dllexport attributes (_LIBUNWIND_EXPORT);
 244   # silence the warning instead of cluttering the headers (which aren't
 245   # necessarily the ones that the callers will use anyway) with the
 246   # attributes.
 247   add_compile_flags_if_supported(-Wno-dll-attribute-on-redeclaration)
 248 endif()
 249
 250 if (LIBUNWIND_ENABLE_WERROR)
 251   add_compile_flags_if_supported(-Werror)
 252   add_compile_flags_if_supported(-WX)
 253 else()
 254   add_compile_flags_if_supported(-Wno-error)
 255   add_compile_flags_if_supported(-WX-)
 256 endif()
 257
 258 if (LIBUNWIND_ENABLE_PEDANTIC)
 259   add_compile_flags_if_supported(-pedantic)
 260 endif()
 261
 262 # Get feature flags.
 263 # Exceptions
 264 # Catches C++ exceptions only and tells the compiler to assume that extern C
 265 # functions never throw a C++ exception.
 266 add_cxx_compile_flags_if_supported(-fstrict-aliasing)
 267 add_cxx_compile_flags_if_supported(-EHsc)
 268
 269 # Don't run the linker in this CMake check.
 270 #
 271 # The reason why this was added is that when building libunwind for
 272 # ARM Linux, we need to pass the -funwind-tables flag in order for it to
 273 # work properly with ARM EHABI.
 274 #
 275 # However, when performing CMake checks, adding this flag causes the check
 276 # to produce a false negative, because the compiler generates calls
 277 # to __aeabi_unwind_cpp_pr0, which is defined in libunwind itself,
 278 # which isn't built yet, so the linker complains about undefined symbols.
 279 #
 280 # This leads to libunwind not being built with this flag, which makes
 281 # libunwind quite useless in this setup.
 282 set(_previous_CMAKE_TRY_COMPILE_TARGET_TYPE ${CMAKE_TRY_COMPILE_TARGET_TYPE})
 283 set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)
 284 add_compile_flags_if_supported(-funwind-tables)
 285 set(CMAKE_TRY_COMPILE_TARGET_TYPE ${_previous_CMAKE_TRY_COMPILE_TARGET_TYPE})
 286
 287 if (LIBUNWIND_USES_ARM_EHABI AND NOT LIBUNWIND_SUPPORTS_FUNWIND_TABLES_FLAG)
 288   message(SEND_ERROR "The -funwind-tables flag must be supported "
 289                      "because this target uses ARM Exception Handling ABI")
 290 endif()
 291
 292 add_cxx_compile_flags_if_supported(-fno-exceptions)
 293 add_cxx_compile_flags_if_supported(-fno-rtti)
 294
 295 # Ensure that we don't depend on C++ standard library.
 296 if (LIBUNWIND_HAS_NOSTDINCXX_FLAG)
 297   list(APPEND LIBUNWIND_COMPILE_FLAGS -nostdinc++)
 298   # Remove -stdlib flags to prevent them from causing an unused flag warning.
 299   string(REPLACE "--stdlib=libc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 300   string(REPLACE "--stdlib=libstdc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 301   string(REPLACE "-stdlib=libc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 302   string(REPLACE "-stdlib=libstdc++" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 303 endif()
 304
 305 # Assert
 306 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 307 if (LIBUNWIND_ENABLE_ASSERTIONS)
 308   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
 309   if (NOT MSVC)
 310     add_compile_flags(-D_DEBUG)
 311   endif()
 312
 313   # On Release builds cmake automatically defines NDEBUG, so we
 314   # explicitly undefine it:
 315   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
 316     add_compile_flags(-UNDEBUG)
 317   endif()
 318 else()
 319   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
 320     add_compile_flags(-DNDEBUG)
 321   endif()
 322 endif()
 323
 324 # Cross-unwinding
 325 if (NOT LIBUNWIND_ENABLE_CROSS_UNWINDING)
 326   add_compile_flags(-D_LIBUNWIND_IS_NATIVE_ONLY)
 327 endif()
 328
 329 # Threading-support
 330 if (NOT LIBUNWIND_ENABLE_THREADS)
 331   add_compile_flags(-D_LIBUNWIND_HAS_NO_THREADS)
 332 endif()
 333
 334 # ARM WMMX register support
 335 if (LIBUNWIND_ENABLE_ARM_WMMX)
 336   # __ARM_WMMX is a compiler pre-define (as per the ACLE 2.0). Clang does not
 337   # define this macro for any supported target at present. Therefore, here we
 338   # provide the option to explicitly enable support for WMMX registers in the
 339   # unwinder.
 340   add_compile_flags(-D__ARM_WMMX)
 341 endif()
 342
 343 if(LIBUNWIND_IS_BAREMETAL)
 344   add_compile_definitions(_LIBUNWIND_IS_BAREMETAL)
 345 endif()
 346
 347 if(LIBUNWIND_USE_FRAME_HEADER_CACHE)
 348   add_compile_definitions(_LIBUNWIND_USE_FRAME_HEADER_CACHE)
 349 endif()
 350
 351 if(LIBUNWIND_REMEMBER_HEAP_ALLOC)
 352   add_compile_definitions(_LIBUNWIND_REMEMBER_HEAP_ALLOC)
 353 endif()
 354
 355 # This is the _ONLY_ place where add_definitions is called.
 356 if (MSVC)
 357   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 358 endif()
 359
 360 # Disable DLL annotations on Windows for static builds.
 361 if (WIN32 AND LIBUNWIND_ENABLE_STATIC AND NOT LIBUNWIND_ENABLE_SHARED)
 362   add_definitions(-D_LIBUNWIND_HIDE_SYMBOLS)
 363 endif()
 364
 365 if (LIBUNWIND_HAS_COMMENT_LIB_PRAGMA)
 366   if (LIBUNWIND_HAS_DL_LIB)
 367     add_definitions(-D_LIBUNWIND_LINK_DL_LIB)
 368   endif()
 369   if (LIBUNWIND_HAS_PTHREAD_LIB)
 370     add_definitions(-D_LIBUNWIND_LINK_PTHREAD_LIB)
 371   endif()
 372 endif()
 373
 374 #===============================================================================
 375 # Setup Source Code
 376 #===============================================================================
 377
 378 add_subdirectory(include)
 379
 380 add_subdirectory(src)
 381
 382 if (LIBUNWIND_INCLUDE_DOCS)
 383   add_subdirectory(docs)
 384 endif()
 385
 386 if (LIBUNWIND_INCLUDE_TESTS AND EXISTS ${LLVM_CMAKE_DIR})
 387   add_subdirectory(test)
 388 endif()