llvm/test/Transforms/InstCombine/bitcast-store.ll

   1 ; RUN: opt -S -instcombine < %s | FileCheck %s
   2
   3 ; Instcombine should preserve metadata and alignment while
   4 ; folding a bitcast into a store.
   5
   6 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64"
   7
   8 %struct.A = type { i32 (...)** }
   9
  10 @G = external constant [5 x i8*]
  11
  12 ; CHECK-LABEL: @foo
  13 ; CHECK: store i32 %x, i32* %{{.*}}, align 16, !noalias !0, !llvm.access.group !3
  14 define void @foo(i32 %x, float* %p) nounwind {
  15 entry:
  16   %x.cast = bitcast i32 %x to float
  17   store float %x.cast, float* %p, align 16, !noalias !0, !llvm.access.group !3
  18   ret void
  19 }
  20
  21 ; Check instcombine doesn't try and fold the following bitcast into the store.
  22 ; This transformation would not be safe since we would need to use addrspacecast
  23 ; and addrspacecast is not guaranteed to be a no-op cast.
  24
  25 ; CHECK-LABEL: @bar
  26 ; CHECK: %cast = bitcast i8** %b to i8 addrspace(1)**
  27 ; CHECK: store i8 addrspace(1)* %a, i8 addrspace(1)** %cast
  28 define void @bar(i8 addrspace(1)* %a, i8** %b) nounwind {
  29 entry:
  30   %cast = bitcast i8** %b to i8 addrspace(1)**
  31   store i8 addrspace(1)* %a, i8 addrspace(1)** %cast
  32   ret void
  33 }
  34
  35 ; Check that we don't combine the bitcast into the store. This would create a
  36 ; bitcast of the swifterror which is invalid.
  37
  38 ; CHECK-LABEL: @swifterror_store
  39 ; CHECK: bitcast i64
  40 ; CHECK: store %swift.error
  41
  42 %swift.error = type opaque
  43 define void @swifterror_store(i64* %x, %swift.error** swifterror %err) {
  44 entry:
  45   %casted = bitcast i64* %x to %swift.error*
  46   store %swift.error* %casted, %swift.error** %err
  47   ret void
  48 }
  49
  50 ; CHECK-LABEL: @ppcf128_ones_store
  51 ; CHECK: store ppc_fp128 0xMFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF, ppc_fp128* %dest, align 16
  52 define void @ppcf128_ones_store(ppc_fp128* %dest) {
  53 entry:
  54   %int = or i128 0, 340282366920938463463374607431768211455 ; 128 ones
  55   %val = bitcast i128 %int to ppc_fp128
  56   store ppc_fp128 %val, ppc_fp128* %dest, align 16
  57   ret void
  58 }
  59
  60 !0 = !{!1}
  61 !1 = !{!1, !2}
  62 !2 = !{!2}
  63 !3 = !{}