llvm/test/Transforms/StraightLineStrengthReduce/slsr-gep.ll

   1 ; RUN: opt < %s -slsr -gvn -S | FileCheck %s
   2 ; RUN: opt < %s -passes='slsr,gvn' -S | FileCheck %s
   3
   4 target datalayout = "e-i64:64-v16:16-v32:32-n16:32:64-p:64:64:64-p1:32:32:32"
   5
   6 ; foo(input[0]);
   7 ; foo(input[s]);
   8 ; foo(input[s * 2]);
   9 ;   =>
  10 ; p0 = &input[0];
  11 ; foo(*p);
  12 ; p1 = p0 + s;
  13 ; foo(*p1);
  14 ; p2 = p1 + s;
  15 ; foo(*p2);
  16 define void @slsr_gep(i32* %input, i64 %s) {
  17 ; CHECK-LABEL: @slsr_gep(
  18   ; v0 = input[0];
  19   %p0 = getelementptr inbounds i32, i32* %input, i64 0
  20   call void @foo(i32* %p0)
  21
  22   ; v1 = input[s];
  23   %p1 = getelementptr inbounds i32, i32* %input, i64 %s
  24 ; CHECK: %p1 = getelementptr inbounds i32, i32* %input, i64 %s
  25   call void @foo(i32* %p1)
  26
  27   ; v2 = input[s * 2];
  28   %s2 = shl nsw i64 %s, 1
  29   %p2 = getelementptr inbounds i32, i32* %input, i64 %s2
  30 ; CHECK: %p2 = getelementptr inbounds i32, i32* %p1, i64 %s
  31   call void @foo(i32* %p2)
  32
  33   ret void
  34 }
  35
  36 ; foo(input[0]);
  37 ; foo(input[(long)s]);
  38 ; foo(input[(long)(s * 2)]);
  39 ;   =>
  40 ; p0 = &input[0];
  41 ; foo(*p);
  42 ; p1 = p0 + (long)s;
  43 ; foo(*p1);
  44 ; p2 = p1 + (long)s;
  45 ; foo(*p2);
  46 define void @slsr_gep_sext(i32* %input, i32 %s) {
  47 ; CHECK-LABEL: @slsr_gep_sext(
  48   ; v0 = input[0];
  49   %p0 = getelementptr inbounds i32, i32* %input, i64 0
  50   call void @foo(i32* %p0)
  51
  52   ; v1 = input[s];
  53   %t = sext i32 %s to i64
  54   %p1 = getelementptr inbounds i32, i32* %input, i64 %t
  55 ; CHECK: %p1 = getelementptr inbounds i32, i32* %input, i64 %t
  56   call void @foo(i32* %p1)
  57
  58   ; v2 = input[s * 2];
  59   %s2 = shl nsw i32 %s, 1
  60   %t2 = sext i32 %s2 to i64
  61   %p2 = getelementptr inbounds i32, i32* %input, i64 %t2
  62 ; CHECK: %p2 = getelementptr inbounds i32, i32* %p1, i64 %t
  63   call void @foo(i32* %p2)
  64
  65   ret void
  66 }
  67
  68 ; int input[10][5];
  69 ; foo(input[s][t]);
  70 ; foo(input[s * 2][t]);
  71 ; foo(input[s * 3][t]);
  72 ;   =>
  73 ; p0 = &input[s][t];
  74 ; foo(*p0);
  75 ; p1 = p0 + 5s;
  76 ; foo(*p1);
  77 ; p2 = p1 + 5s;
  78 ; foo(*p2);
  79 define void @slsr_gep_2d([10 x [5 x i32]]* %input, i64 %s, i64 %t) {
  80 ; CHECK-LABEL: @slsr_gep_2d(
  81   ; v0 = input[s][t];
  82   %p0 = getelementptr inbounds [10 x [5 x i32]], [10 x [5 x i32]]* %input, i64 0, i64 %s, i64 %t
  83   call void @foo(i32* %p0)
  84
  85   ; v1 = input[s * 2][t];
  86   %s2 = shl nsw i64 %s, 1
  87 ; CHECK: [[BUMP:%[a-zA-Z0-9]+]] = mul i64 %s, 5
  88   %p1 = getelementptr inbounds [10 x [5 x i32]], [10 x [5 x i32]]* %input, i64 0, i64 %s2, i64 %t
  89 ; CHECK: %p1 = getelementptr inbounds i32, i32* %p0, i64 [[BUMP]]
  90   call void @foo(i32* %p1)
  91
  92   ; v3 = input[s * 3][t];
  93   %s3 = mul nsw i64 %s, 3
  94   %p2 = getelementptr inbounds [10 x [5 x i32]], [10 x [5 x i32]]* %input, i64 0, i64 %s3, i64 %t
  95 ; CHECK: %p2 = getelementptr inbounds i32, i32* %p1, i64 [[BUMP]]
  96   call void @foo(i32* %p2)
  97
  98   ret void
  99 }
 100
 101 %struct.S = type <{ i64, i32 }>
 102
 103 ; In this case, the bump
 104 ;     = (char *)&input[s * 2][t].f1 - (char *)&input[s][t].f1
 105 ;     = 60 * s
 106 ; which may not be divisible by typeof(input[s][t].f1) = 8. Therefore, we
 107 ; rewrite the candidates using byte offset instead of index offset as in
 108 ; @slsr_gep_2d.
 109 define void @slsr_gep_uglygep([10 x [5 x %struct.S]]* %input, i64 %s, i64 %t) {
 110 ; CHECK-LABEL: @slsr_gep_uglygep(
 111   ; v0 = input[s][t].f1;
 112   %p0 = getelementptr inbounds [10 x [5 x %struct.S]], [10 x [5 x %struct.S]]* %input, i64 0, i64 %s, i64 %t, i32 0
 113   call void @bar(i64* %p0)
 114
 115   ; v1 = input[s * 2][t].f1;
 116   %s2 = shl nsw i64 %s, 1
 117 ; CHECK: [[BUMP:%[a-zA-Z0-9]+]] = mul i64 %s, 60
 118   %p1 = getelementptr inbounds [10 x [5 x %struct.S]], [10 x [5 x %struct.S]]* %input, i64 0, i64 %s2, i64 %t, i32 0
 119 ; CHECK: getelementptr inbounds i8, i8* %{{[0-9]+}}, i64 [[BUMP]]
 120   call void @bar(i64* %p1)
 121
 122   ; v2 = input[s * 3][t].f1;
 123   %s3 = mul nsw i64 %s, 3
 124   %p2 = getelementptr inbounds [10 x [5 x %struct.S]], [10 x [5 x %struct.S]]* %input, i64 0, i64 %s3, i64 %t, i32 0
 125 ; CHECK: getelementptr inbounds i8, i8* %{{[0-9]+}}, i64 [[BUMP]]
 126   call void @bar(i64* %p2)
 127
 128   ret void
 129 }
 130
 131 define void @slsr_out_of_bounds_gep(i32* %input, i32 %s) {
 132 ; CHECK-LABEL: @slsr_out_of_bounds_gep(
 133   ; v0 = input[0];
 134   %p0 = getelementptr i32, i32* %input, i64 0
 135   call void @foo(i32* %p0)
 136
 137   ; v1 = input[(long)s];
 138   %t = sext i32 %s to i64
 139   %p1 = getelementptr i32, i32* %input, i64 %t
 140 ; CHECK: %p1 = getelementptr i32, i32* %input, i64 %t
 141   call void @foo(i32* %p1)
 142
 143   ; v2 = input[(long)(s * 2)];
 144   %s2 = shl nsw i32 %s, 1
 145   %t2 = sext i32 %s2 to i64
 146   %p2 = getelementptr i32, i32* %input, i64 %t2
 147 ; CHECK: %p2 = getelementptr i32, i32* %p1, i64 %t
 148   call void @foo(i32* %p2)
 149
 150   ret void
 151 }
 152
 153 define void @slsr_gep_128bit_index(i32* %input, i128 %s) {
 154 ; CHECK-LABEL: @slsr_gep_128bit_index(
 155   ; p0 = &input[0]
 156   %p0 = getelementptr inbounds i32, i32* %input, i128 0
 157   call void @foo(i32* %p0)
 158
 159   ; p1 = &input[s << 125]
 160   %s125 = shl nsw i128 %s, 125
 161   %p1 = getelementptr inbounds i32, i32* %input, i128 %s125
 162 ; CHECK: %p1 = getelementptr inbounds i32, i32* %input, i128 %s125
 163   call void @foo(i32* %p1)
 164
 165   ; p2 = &input[s << 126]
 166   %s126 = shl nsw i128 %s, 126
 167   %p2 = getelementptr inbounds i32, i32* %input, i128 %s126
 168 ; CHECK: %p2 = getelementptr inbounds i32, i32* %input, i128 %s126
 169   call void @foo(i32* %p2)
 170
 171   ret void
 172 }
 173
 174 define void @slsr_gep_32bit_pointer(i32 addrspace(1)* %input, i64 %s) {
 175 ; CHECK-LABEL: @slsr_gep_32bit_pointer(
 176   ; p1 = &input[s]
 177   %p1 = getelementptr inbounds i32, i32 addrspace(1)* %input, i64 %s
 178   call void @baz(i32 addrspace(1)* %p1)
 179
 180   ; p2 = &input[s * 2]
 181   %s2 = mul nsw i64 %s, 2
 182   %p2 = getelementptr inbounds i32, i32 addrspace(1)* %input, i64 %s2
 183   ; %s2 is wider than the pointer size of addrspace(1), so do not factor it.
 184 ; CHECK: %p2 = getelementptr inbounds i32, i32 addrspace(1)* %input, i64 %s2
 185   call void @baz(i32 addrspace(1)* %p2)
 186
 187   ret void
 188 }
 189
 190 declare void @foo(i32*)
 191 declare void @bar(i64*)
 192 declare void @baz(i32 addrspace(1)*)