polly/CMakeLists.txt

   1 include(GNUInstallDirs)
   2
   3 # Check if this is a in tree build.
   4 if (NOT DEFINED LLVM_MAIN_SRC_DIR)
   5   project(Polly)
   6   cmake_minimum_required(VERSION 3.13.4)
   7
   8   # Where is LLVM installed?
   9   find_package(LLVM CONFIG REQUIRED)
  10   set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${LLVM_CMAKE_DIR})
  11   include(HandleLLVMOptions)
  12   include(AddLLVM)
  13
  14   # Add the llvm header path.
  15   include_directories(${LLVM_INCLUDE_DIRS})
  16
  17   # Sources available, too?
  18   if (LLVM_BUILD_MAIN_SRC_DIR)
  19     set(LLVM_SOURCE_ROOT ${LLVM_BUILD_MAIN_SRC_DIR} CACHE PATH
  20       "Path to LLVM source tree")
  21   else()
  22     execute_process(COMMAND "${LLVM_TOOLS_BINARY_DIR}/llvm-config" --src-root
  23       OUTPUT_VARIABLE MAIN_SRC_DIR
  24       OUTPUT_STRIP_TRAILING_WHITESPACE)
  25     set(LLVM_SOURCE_ROOT ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  26   endif()
  27
  28   # Enable unit tests if available.
  29   set(POLLY_GTEST_AVAIL 0)
  30   set(UNITTEST_DIR ${LLVM_SOURCE_ROOT}/utils/unittest)
  31   if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h)
  32     if (NOT TARGET gtest)
  33       add_subdirectory(${UNITTEST_DIR} utils/unittest)
  34     endif()
  35     set(POLLY_GTEST_AVAIL 1)
  36   endif()
  37
  38   if (LLVM_ENABLE_PIC)
  39     # Make sure the isl c files are built as fPIC if possible
  40     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
  41   endif ()
  42
  43   # Set directory for polly-isl-test.
  44   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/bin")
  45 else ()
  46   set(LLVM_SOURCE_ROOT "${LLVM_MAIN_SRC_DIR}")
  47   set(POLLY_GTEST_AVAIL 1)
  48 endif ()
  49
  50 set(POLLY_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  51 set(POLLY_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  52
  53 if(NOT DEFINED LLVM_COMMON_CMAKE_UTILS)
  54   set(LLVM_COMMON_CMAKE_UTILS ${POLLY_SOURCE_DIR}/../cmake)
  55 endif()
  56
  57 # Make sure that our source directory is on the current cmake module path so that
  58 # we can include cmake files from this directory.
  59 list(INSERT CMAKE_MODULE_PATH 0
  60   "${POLLY_SOURCE_DIR}/cmake"
  61   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
  62   )
  63
  64 include("polly_macros")
  65
  66 # Add appropriate flags for GCC
  67 if (CMAKE_COMPILER_IS_GNUCXX)
  68   # FIXME: Turn off exceptions, RTTI:
  69   # -fno-exceptions -fno-rtti
  70   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings -fno-exceptions -fno-rtti")
  71 elseif (MSVC)
  72   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHs-c-")
  73   add_definitions("-D_HAS_EXCEPTIONS=0")
  74 else ()
  75   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  76 endif ()
  77
  78 SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  79
  80 option(POLLY_ENABLE_GPGPU_CODEGEN "Enable GPGPU code generation feature" OFF)
  81 set(GPU_CODEGEN FALSE)
  82 if (POLLY_ENABLE_GPGPU_CODEGEN)
  83   # Do not require CUDA/OpenCL, as GPU code generation test cases can be run
  84   # without a CUDA/OpenCL library.
  85   if ("NVPTX" IN_LIST LLVM_TARGETS_TO_BUILD)
  86     FIND_PACKAGE(CUDA)
  87     FIND_PACKAGE(OpenCL)
  88     set(GPU_CODEGEN TRUE)
  89   else()
  90     message(WARNING "The LLVM NVPTX target is required for GPU code generation")
  91   endif()
  92 endif(POLLY_ENABLE_GPGPU_CODEGEN)
  93
  94
  95 # Support GPGPU code generation if the library is available.
  96 if (CUDA_FOUND)
  97   add_definitions(-DHAS_LIBCUDART)
  98   INCLUDE_DIRECTORIES( ${CUDA_INCLUDE_DIRS} )
  99 endif(CUDA_FOUND)
 100 if (OpenCL_FOUND)
 101   add_definitions(-DHAS_LIBOPENCL)
 102   INCLUDE_DIRECTORIES( ${OpenCL_INCLUDE_DIR} )
 103 endif(OpenCL_FOUND)
 104
 105 option(POLLY_BUNDLED_ISL "Use the bundled version of libisl included in Polly" ON)
 106 if (NOT POLLY_BUNDLED_ISL)
 107   find_package(ISL MODULE REQUIRED)
 108   message(STATUS "Using external libisl ${ISL_VERSION} in: ${ISL_PREFIX}")
 109   set(ISL_TARGET ISL)
 110 else()
 111   set(ISL_INCLUDE_DIRS
 112     ${CMAKE_CURRENT_BINARY_DIR}/lib/External/isl/include
 113     ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/isl/include
 114   )
 115   set(ISL_TARGET PollyISL)
 116 endif()
 117
 118 include_directories(
 119   BEFORE
 120   ${CMAKE_CURRENT_SOURCE_DIR}/include
 121   ${ISL_INCLUDE_DIRS}
 122   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/pet/include
 123   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External
 124   ${CMAKE_CURRENT_BINARY_DIR}/include
 125   )
 126
 127 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 128   install(DIRECTORY include/
 129     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 130     FILES_MATCHING
 131     PATTERN "*.h"
 132     )
 133
 134   install(DIRECTORY ${POLLY_BINARY_DIR}/include/
 135     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 136     FILES_MATCHING
 137     PATTERN "*.h"
 138     PATTERN "CMakeFiles" EXCLUDE
 139     )
 140 endif()
 141
 142 add_definitions( -D_GNU_SOURCE )
 143
 144 add_subdirectory(docs)
 145 add_subdirectory(lib)
 146 add_subdirectory(test)
 147 if (POLLY_GTEST_AVAIL)
 148   add_subdirectory(unittests)
 149 endif ()
 150 add_subdirectory(tools)
 151 add_subdirectory(cmake)
 152 # TODO: docs.
 153
 154
 155 configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/include/polly/Config/config.h.cmake
 156                 ${POLLY_BINARY_DIR}/include/polly/Config/config.h )
 157
 158 # Add target to check formatting of polly files
 159 file( GLOB_RECURSE files *.h lib/*.cpp lib/*.c tools/*.cpp tools/*.c tools/*.h unittests/*.cpp)
 160 file( GLOB_RECURSE external lib/External/*.h lib/External/*.c lib/External/*.cpp isl_config.h)
 161 list( REMOVE_ITEM files ${external})
 162
 163 set(check_format_depends)
 164 set(update_format_depends)
 165 set(i 0)
 166 foreach (file IN LISTS files)
 167   add_custom_command(OUTPUT polly-check-format${i}
 168     COMMAND clang-format -sort-includes -style=llvm ${file} | diff -u ${file} -
 169     VERBATIM
 170     COMMENT "Checking format of ${file}..."
 171   )
 172   list(APPEND check_format_depends "polly-check-format${i}")
 173
 174   add_custom_command(OUTPUT polly-update-format${i}
 175     COMMAND clang-format -sort-includes -i -style=llvm ${file}
 176     VERBATIM
 177     COMMENT "Updating format of ${file}..."
 178   )
 179   list(APPEND update_format_depends "polly-update-format${i}")
 180
 181   math(EXPR i ${i}+1)
 182 endforeach ()
 183
 184 add_custom_target(polly-check-format DEPENDS ${check_format_depends})
 185 set_target_properties(polly-check-format PROPERTIES FOLDER "Polly")
 186
 187 add_custom_target(polly-update-format DEPENDS ${update_format_depends})
 188 set_target_properties(polly-update-format PROPERTIES FOLDER "Polly")
 189