llvm/CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.20.0)
   4
   5 set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
   6 include(${LLVM_COMMON_CMAKE_UTILS}/Modules/CMakePolicy.cmake
   7   NO_POLICY_SCOPE)
   8
   9 # Builds with custom install names and installation rpath setups may not work
  10 # in the build tree. Allow these cases to use CMake's default build tree
  11 # behavior by setting `LLVM_NO_INSTALL_NAME_DIR_FOR_BUILD_TREE` to do this.
  12 option(LLVM_NO_INSTALL_NAME_DIR_FOR_BUILD_TREE "If set, use CMake's default build tree install name directory logic (Darwin only)" OFF)
  13 mark_as_advanced(LLVM_NO_INSTALL_NAME_DIR_FOR_BUILD_TREE)
  14 if(NOT LLVM_NO_INSTALL_NAME_DIR_FOR_BUILD_TREE)
  15   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 18)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX git)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if(NOT DEFINED LLVM_SHLIB_SYMBOL_VERSION)
  37   # "Symbol version prefix for libLLVM.so"
  38   set(LLVM_SHLIB_SYMBOL_VERSION "LLVM_${LLVM_VERSION_MAJOR}")
  39 endif()
  40
  41 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (MSVC_TOOLSET_VERSION LESS 142) AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  42   message(WARNING "Visual Studio generators use the x86 host compiler by "
  43                   "default, even for 64-bit targets. This can result in linker "
  44                   "instability and out of memory errors. To use the 64-bit "
  45                   "host compiler, pass -Thost=x64 on the CMake command line.")
  46 endif()
  47
  48 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
  49   # Some CMake features like object libraries get confused if you don't
  50   # explicitly specify an architecture setting with the Xcode generator.
  51   set(CMAKE_OSX_ARCHITECTURES "x86_64")
  52 endif()
  53
  54 project(LLVM
  55   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  56   LANGUAGES C CXX ASM)
  57
  58 if (NOT DEFINED CMAKE_INSTALL_LIBDIR AND DEFINED LLVM_LIBDIR_SUFFIX)
  59   # Must go before `include(GNUInstallDirs)`.
  60   set(CMAKE_INSTALL_LIBDIR "lib${LLVM_LIBDIR_SUFFIX}")
  61 endif()
  62
  63 # Must go after `DEFINED LLVM_LIBDIR_SUFFIX` check.
  64 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  65
  66 # Must go after `project(..)`.
  67 include(GNUInstallDirs)
  68
  69 # This C++ standard is required to build LLVM.
  70 set(LLVM_REQUIRED_CXX_STANDARD 17)
  71
  72 # If we find that the cache contains CMAKE_CXX_STANDARD it means that it's a old CMakeCache.txt
  73 # and we can just inform the user and then reset it.
  74 if($CACHE{CMAKE_CXX_STANDARD} AND $CACHE{CMAKE_CXX_STANDARD} LESS ${LLVM_REQUIRED_CXX_STANDARD})
  75   message(WARNING "Resetting cache value for CMAKE_CXX_STANDARD to ${LLVM_REQUIRED_CXX_STANDARD}")
  76   unset(CMAKE_CXX_STANDARD CACHE)
  77 endif()
  78
  79 # if CMAKE_CXX_STANDARD is still set after the cache unset above it means that the user requested it
  80 # and we allow it to be set to something newer than the required standard but otherwise we fail.
  81 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD LESS ${LLVM_REQUIRED_CXX_STANDARD})
  82   message(FATAL_ERROR "Requested CMAKE_CXX_STANDARD=${CMAKE_CXX_STANDARD} which is less than the required ${LLVM_REQUIRED_CXX_STANDARD}.")
  83 endif()
  84
  85 set(CMAKE_CXX_STANDARD ${LLVM_REQUIRED_CXX_STANDARD} CACHE STRING "C++ standard to conform to")
  86 set(CMAKE_CXX_STANDARD_REQUIRED YES)
  87
  88 if (CYGWIN)
  89   # Cygwin is a bit stricter and lack things like 'strdup', 'stricmp', etc in
  90   # c++xx mode.
  91   set(CMAKE_CXX_EXTENSIONS YES)
  92 else()
  93   set(CMAKE_CXX_EXTENSIONS NO)
  94 endif()
  95
  96 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  97   message(FATAL_ERROR "
  98 No build type selected. You need to pass -DCMAKE_BUILD_TYPE=<type> in order to configure LLVM.
  99 Available options are:
 100   * -DCMAKE_BUILD_TYPE=Release - For an optimized build with no assertions or debug info.
 101   * -DCMAKE_BUILD_TYPE=Debug - For an unoptimized build with assertions and debug info.
 102   * -DCMAKE_BUILD_TYPE=RelWithDebInfo - For an optimized build with no assertions but with debug info.
 103   * -DCMAKE_BUILD_TYPE=MinSizeRel - For a build optimized for size instead of speed.
 104 Learn more about these options in our documentation at https://llvm.org/docs/CMake.html#cmake-build-type
 105 ")
 106 endif()
 107
 108 # Set default build type for cmake's try_compile module.
 109 # CMake 3.17 or newer sets CMAKE_DEFAULT_BUILD_TYPE to one of the
 110 # items from CMAKE_CONFIGURATION_TYPES. Logic below can be further
 111 # simplified once LLVM's minimum CMake version is updated to 3.17.
 112 if(CMAKE_DEFAULT_BUILD_TYPE)
 113   set(CMAKE_TRY_COMPILE_CONFIGURATION ${CMAKE_DEFAULT_BUILD_TYPE})
 114 else()
 115   if(CMAKE_CONFIGURATION_TYPES)
 116     list(GET CMAKE_CONFIGURATION_TYPES 0 CMAKE_TRY_COMPILE_CONFIGURATION)
 117   elseif(CMAKE_BUILD_TYPE)
 118     set(CMAKE_TRY_COMPILE_CONFIGURATION ${CMAKE_BUILD_TYPE})
 119   endif()
 120 endif()
 121
 122 # Side-by-side subprojects layout: automatically set the
 123 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 124 # This allows an easy way of setting up a build directory for llvm and another
 125 # one for llvm+clang+... using the same sources.
 126 set(LLVM_ALL_PROJECTS "bolt;clang;clang-tools-extra;compiler-rt;cross-project-tests;libc;libclc;lld;lldb;mlir;openmp;polly;pstl")
 127 # The flang project is not yet part of "all" projects (see C++ requirements)
 128 set(LLVM_EXTRA_PROJECTS "flang")
 129 # List of all known projects in the mono repo
 130 set(LLVM_KNOWN_PROJECTS "${LLVM_ALL_PROJECTS};${LLVM_EXTRA_PROJECTS}")
 131 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 132     "Semicolon-separated list of projects to build (${LLVM_KNOWN_PROJECTS}), or \"all\".")
 133 # Make sure expansion happens first to not handle "all" in rest of the checks.
 134 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 135   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 136 endif()
 137 foreach(proj ${LLVM_ENABLE_PROJECTS})
 138   if (NOT proj STREQUAL "llvm" AND NOT "${proj}" IN_LIST LLVM_KNOWN_PROJECTS)
 139      MESSAGE(FATAL_ERROR "${proj} isn't a known project: ${LLVM_KNOWN_PROJECTS}. Did you mean to enable it as a runtime in LLVM_ENABLE_RUNTIMES?")
 140   endif()
 141 endforeach()
 142
 143 if ("flang" IN_LIST LLVM_ENABLE_PROJECTS)
 144   if (NOT "mlir" IN_LIST LLVM_ENABLE_PROJECTS)
 145     message(STATUS "Enabling MLIR as a dependency to flang")
 146     list(APPEND LLVM_ENABLE_PROJECTS "mlir")
 147   endif()
 148
 149   if (NOT "clang" IN_LIST LLVM_ENABLE_PROJECTS)
 150     message(FATAL_ERROR "Clang is not enabled, but is required for the Flang driver")
 151   endif()
 152 endif()
 153
 154 # Select the runtimes to build
 155 #
 156 # As we migrate runtimes to using the bootstrapping build, the set of default runtimes
 157 # should grow as we remove those runtimes from LLVM_ENABLE_PROJECTS above.
 158 set(LLVM_DEFAULT_RUNTIMES "libcxx;libcxxabi;libunwind")
 159 set(LLVM_SUPPORTED_RUNTIMES "libc;libunwind;libcxxabi;pstl;libcxx;compiler-rt;openmp;llvm-libgcc")
 160 set(LLVM_ENABLE_RUNTIMES "" CACHE STRING
 161   "Semicolon-separated list of runtimes to build, or \"all\" (${LLVM_DEFAULT_RUNTIMES}). Supported runtimes are ${LLVM_SUPPORTED_RUNTIMES}.")
 162 if(LLVM_ENABLE_RUNTIMES STREQUAL "all")
 163   set(LLVM_ENABLE_RUNTIMES ${LLVM_DEFAULT_RUNTIMES})
 164 endif()
 165 foreach(proj IN LISTS LLVM_ENABLE_RUNTIMES)
 166   if (NOT "${proj}" IN_LIST LLVM_SUPPORTED_RUNTIMES)
 167     message(FATAL_ERROR "Runtime \"${proj}\" is not a supported runtime. Supported runtimes are: ${LLVM_SUPPORTED_RUNTIMES}")
 168   endif()
 169 endforeach()
 170
 171 if ("libc" IN_LIST LLVM_ENABLE_RUNTIMES)
 172   # To build the libc runtime, we need to be able to build few libc build
 173   # tools from the "libc" project. So, we add it to the list of enabled
 174   # projects.
 175   if (NOT "libc" IN_LIST LLVM_ENABLE_PROJECTS)
 176     message(STATUS "Enabling libc project to build libc build tools")
 177     list(APPEND LLVM_ENABLE_PROJECTS "libc")
 178   endif()
 179 endif()
 180
 181 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
 182 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
 183 # several reasons:
 184 #
 185 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
 186 # source of truth for which projects to build. This means we will ignore user
 187 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
 188 # them.
 189 #
 190 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
 191 # non-empty list but now the user wishes to disable building all other projects
 192 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
 193 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
 194 # building all the projects that were previously enabled.
 195 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
 196 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
 197
 198 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
 199   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
 200   foreach(proj ${LLVM_KNOWN_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
 201     string(TOUPPER "${proj}" upper_proj)
 202     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 203     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
 204       message(STATUS "${proj} project is enabled")
 205       set(SHOULD_ENABLE_PROJECT TRUE)
 206       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 207       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 208         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 209       endif()
 210       if( LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR STREQUAL "" )
 211         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "" FORCE)
 212       else()
 213         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "")
 214       endif()
 215     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
 216       message(STATUS "${proj} project is enabled")
 217       set(SHOULD_ENABLE_PROJECT TRUE)
 218     else()
 219       message(STATUS "${proj} project is disabled")
 220       set(SHOULD_ENABLE_PROJECT FALSE)
 221     endif()
 222     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 223     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 224     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 225     # we should deprecate allowing users to set these variables by turning them
 226     # into normal CMake variables rather than cache variables.
 227     set(LLVM_TOOL_${upper_proj}_BUILD
 228       ${SHOULD_ENABLE_PROJECT}
 229       CACHE
 230       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 231     )
 232   endforeach()
 233 endif()
 234 unset(SHOULD_ENABLE_PROJECT)
 235
 236 # Build llvm with ccache if the package is present
 237 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 238 if(LLVM_CCACHE_BUILD)
 239   find_program(CCACHE_PROGRAM ccache)
 240   if(CCACHE_PROGRAM)
 241     set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 242     set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 243     set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 244         CACHE STRING "Parameters to pass through to ccache")
 245
 246     if(NOT CMAKE_SYSTEM_NAME MATCHES "Windows")
 247       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 248       if (LLVM_CCACHE_MAXSIZE)
 249         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 250       endif()
 251       if (LLVM_CCACHE_DIR)
 252         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 253       endif()
 254       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 255     else()
 256       if(LLVM_CCACHE_MAXSIZE OR LLVM_CCACHE_DIR OR
 257          NOT LLVM_CCACHE_PARAMS MATCHES "CCACHE_CPP2=yes CCACHE_HASHDIR=yes")
 258         message(FATAL_ERROR "Ccache configuration through CMake is not supported on Windows. Please use environment variables.")
 259       endif()
 260       # RULE_LAUNCH_COMPILE should work with Ninja but currently has issues
 261       # with cmd.exe and some MSVC tools other than cl.exe
 262       set(CMAKE_C_COMPILER_LAUNCHER ${CCACHE_PROGRAM})
 263       set(CMAKE_CXX_COMPILER_LAUNCHER ${CCACHE_PROGRAM})
 264     endif()
 265   else()
 266     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 267   endif()
 268 endif()
 269
 270 set(LLVM_EXTERNAL_PROJECT_BUILD_TOOL_ARGS "" CACHE STRING
 271   "Optional arguments for the native tool used in CMake --build invocations for external projects.")
 272 mark_as_advanced(LLVM_EXTERNAL_PROJECT_BUILD_TOOL_ARGS)
 273
 274 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 275
 276 # Some features of the LLVM build may be disallowed when dependency debugging is
 277 # enabled. In particular you cannot use ccache because we want to force compile
 278 # operations to always happen.
 279 if(LLVM_DEPENDENCY_DEBUGGING)
 280   if(NOT CMAKE_HOST_APPLE)
 281     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 282   endif()
 283   if(LLVM_CCACHE_BUILD)
 284     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 285   endif()
 286 endif()
 287
 288 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 289 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 290 if(LLVM_ENABLE_GISEL_COV)
 291   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 292 endif()
 293
 294 # Add path for custom modules
 295 list(INSERT CMAKE_MODULE_PATH 0
 296   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 297   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 298   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
 299   )
 300
 301 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 302 # for use by clang_complete, YouCompleteMe, etc.
 303 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 304
 305 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 306   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 307
 308 option(LLVM_INSTALL_CCTOOLS_SYMLINKS
 309   "Install symlinks from the cctools tool names to the corresponding LLVM tools." OFF)
 310
 311 # By default we use symlinks on Unix platforms and copy binaries on Windows
 312 # If you have the correct setup on Windows you can use this option to enable
 313 # symlinks and save a lot of diskspace.
 314 option(LLVM_USE_SYMLINKS "Use symlinks instead of copying binaries" ${CMAKE_HOST_UNIX})
 315
 316 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 317
 318 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 319
 320 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 321 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 322 # the installation by default. See llvm.org/PR31905.
 323 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 324
 325 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 326 if ( LLVM_USE_FOLDERS )
 327   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 328 endif()
 329
 330 include(VersionFromVCS)
 331
 332 option(LLVM_APPEND_VC_REV
 333   "Embed the version control system revision in LLVM" ON)
 334
 335 set(LLVM_FORCE_VC_REVISION
 336   "" CACHE STRING "Force custom VC revision for LLVM_APPEND_VC_REV")
 337
 338 set(LLVM_FORCE_VC_REPOSITORY
 339   "" CACHE STRING "Force custom VC repository for LLVM_APPEND_VC_REV")
 340
 341 option(LLVM_TOOL_LLVM_DRIVER_BUILD "Enables building the llvm multicall tool" OFF)
 342
 343 set(PACKAGE_NAME LLVM)
 344 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 345 set(PACKAGE_BUGREPORT "https://github.com/llvm/llvm-project/issues/")
 346
 347 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 348   "Default URL where bug reports are to be submitted.")
 349
 350 # Configure CPack.
 351 if(NOT DEFINED CPACK_PACKAGE_INSTALL_DIRECTORY)
 352   set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 353 endif()
 354 if(NOT DEFINED CPACK_PACKAGE_VENDOR)
 355   set(CPACK_PACKAGE_VENDOR "LLVM")
 356 endif()
 357 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 358 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 359 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 360 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 361 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 362 if(WIN32 AND NOT UNIX)
 363   set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 364   if(NOT DEFINED CPACK_PACKAGE_INSTALL_REGISTRY_KEY)
 365     set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 366   endif()
 367   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 368   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 369   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 370   set(CPACK_NSIS_MODIFY_PATH "ON")
 371   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 372   if( CMAKE_CL_64 )
 373     if(NOT DEFINED CPACK_NSIS_INSTALL_ROOT)
 374       set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 375     endif()
 376   endif()
 377 endif()
 378 include(CPack)
 379
 380 # Sanity check our source directory to make sure that we are not trying to
 381 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 382 # sure that we don't have any stray generated files lying around in the tree
 383 # (which would end up getting picked up by header search, instead of the correct
 384 # versions).
 385 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 386   message(FATAL_ERROR "In-source builds are not allowed.
 387 Please create a directory and run cmake from there, passing the path
 388 to this source directory as the last argument.
 389 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 390 Please delete them.")
 391 endif()
 392
 393 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 394
 395 option(LLVM_ADDITIONAL_BUILD_TYPES "Additional build types that are allowed to be passed into CMAKE_BUILD_TYPE" "")
 396
 397 set(ALLOWED_BUILD_TYPES DEBUG RELEASE RELWITHDEBINFO MINSIZEREL ${LLVM_ADDITIONAL_BUILD_TYPES})
 398 string (REPLACE ";" "|" ALLOWED_BUILD_TYPES_STRING "${ALLOWED_BUILD_TYPES}")
 399 string (TOUPPER "${ALLOWED_BUILD_TYPES_STRING}" uppercase_ALLOWED_BUILD_TYPES)
 400
 401 if (CMAKE_BUILD_TYPE AND
 402     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(${uppercase_ALLOWED_BUILD_TYPES})$")
 403   message(FATAL_ERROR "Unknown value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 404 endif()
 405
 406 # LLVM_INSTALL_PACKAGE_DIR needs to be declared prior to adding the tools
 407 # subdirectory in order to have the value available for llvm-config.
 408 include(GNUInstallPackageDir)
 409 set(LLVM_INSTALL_PACKAGE_DIR "${CMAKE_INSTALL_PACKAGEDIR}/llvm" CACHE STRING
 410   "Path for CMake subdirectory for LLVM (defaults to '${CMAKE_INSTALL_PACKAGEDIR}/llvm')")
 411
 412 set(LLVM_TOOLS_INSTALL_DIR "${CMAKE_INSTALL_BINDIR}" CACHE STRING
 413     "Path for binary subdirectory (defaults to '${CMAKE_INSTALL_BINDIR}')")
 414 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 415
 416 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 417     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 418 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 419
 420 set(LLVM_EXAMPLES_INSTALL_DIR "examples" CACHE STRING
 421     "Path for examples subdirectory (enabled by LLVM_BUILD_EXAMPLES=ON) (defaults to 'examples')")
 422 mark_as_advanced(LLVM_EXAMPLES_INSTALL_DIR)
 423
 424 # They are used as destination of target generators.
 425 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 426 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 427 if(WIN32 OR CYGWIN)
 428   # DLL platform -- put DLLs into bin.
 429   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 430 else()
 431   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 432 endif()
 433
 434 # Each of them corresponds to llvm-config's.
 435 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 436 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 437 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 438 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 439 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 440
 441
 442 # Note: LLVM_CMAKE_DIR does not include generated files
 443 set(LLVM_CMAKE_DIR ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 444 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 445 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 446
 447 # List of all targets to be built by default:
 448 set(LLVM_ALL_TARGETS
 449   AArch64
 450   AMDGPU
 451   ARM
 452   AVR
 453   BPF
 454   Hexagon
 455   Lanai
 456   LoongArch
 457   Mips
 458   MSP430
 459   NVPTX
 460   PowerPC
 461   RISCV
 462   Sparc
 463   SystemZ
 464   VE
 465   WebAssembly
 466   X86
 467   XCore
 468   )
 469
 470 set(LLVM_ALL_EXPERIMENTAL_TARGETS
 471   ARC
 472   CSKY
 473   DirectX
 474   M68k
 475   SPIRV
 476   Xtensa
 477 )
 478
 479 # List of targets with JIT support:
 480 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 481
 482 set(LLVM_TARGETS_TO_BUILD "all"
 483     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 484
 485 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 486     CACHE STRING "Semicolon-separated list of experimental targets to build, or \"all\".")
 487
 488 option(BUILD_SHARED_LIBS
 489   "Build all libraries as shared libraries instead of static" OFF)
 490
 491 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 492 if(LLVM_ENABLE_BACKTRACES)
 493   set(ENABLE_BACKTRACES 1)
 494 endif()
 495
 496 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 497
 498 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 499 if(LLVM_ENABLE_CRASH_OVERRIDES)
 500   set(ENABLE_CRASH_OVERRIDES 1)
 501 endif()
 502
 503 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 504
 505 set(WINDOWS_PREFER_FORWARD_SLASH_DEFAULT OFF)
 506 if (MINGW)
 507   # Cygwin doesn't identify itself as Windows, and thus gets path::Style::posix
 508   # as native path style, regardless of what this is set to.
 509   set(WINDOWS_PREFER_FORWARD_SLASH_DEFAULT ON)
 510 endif()
 511 option(LLVM_WINDOWS_PREFER_FORWARD_SLASH "Prefer path names with forward slashes on Windows." ${WINDOWS_PREFER_FORWARD_SLASH_DEFAULT})
 512
 513 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 514 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 515 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 516
 517 set(LLVM_TARGET_ARCH "host"
 518   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 519
 520 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 521
 522 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 523
 524 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 525
 526 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 527
 528 # On z/OS, threads cannot be used because TLS is not supported.
 529 if (CMAKE_SYSTEM_NAME MATCHES "OS390")
 530   option(LLVM_ENABLE_THREADS "Use threads if available." OFF)
 531 else()
 532   option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 533 endif()
 534
 535 set(LLVM_ENABLE_ZLIB "ON" CACHE STRING "Use zlib for compression/decompression if available. Can be ON, OFF, or FORCE_ON")
 536
 537 set(LLVM_ENABLE_ZSTD "ON" CACHE STRING "Use zstd for compression/decompression if available. Can be ON, OFF, or FORCE_ON")
 538
 539 set(LLVM_USE_STATIC_ZSTD FALSE CACHE BOOL "Use static version of zstd. Can be TRUE, FALSE")
 540
 541 set(LLVM_ENABLE_CURL "OFF" CACHE STRING "Use libcurl for the HTTP client if available. Can be ON, OFF, or FORCE_ON")
 542
 543 set(LLVM_ENABLE_HTTPLIB "OFF" CACHE STRING "Use cpp-httplib HTTP server library if available. Can be ON, OFF, or FORCE_ON")
 544
 545 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 546
 547 option(LLVM_ENABLE_Z3_SOLVER
 548   "Enable Support for the Z3 constraint solver in LLVM."
 549   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 550 )
 551
 552 if (LLVM_ENABLE_Z3_SOLVER)
 553   find_package(Z3 4.7.1)
 554
 555   if (LLVM_Z3_INSTALL_DIR)
 556     if (NOT Z3_FOUND)
 557       message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 558     endif()
 559   endif()
 560
 561   if (NOT Z3_FOUND)
 562     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 563   endif()
 564
 565   set(LLVM_WITH_Z3 1)
 566 endif()
 567
 568 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 569
 570
 571 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 572   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 573 endif()
 574
 575 if(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD STREQUAL "all")
 576   set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${LLVM_ALL_EXPERIMENTAL_TARGETS})
 577 endif()
 578
 579 set(LLVM_TARGETS_TO_BUILD
 580    ${LLVM_TARGETS_TO_BUILD}
 581    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 582 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 583
 584 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 585 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 586 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 587   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 588 else()
 589   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 590 endif()
 591 option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 592 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 593 option(LLVM_ENABLE_LLVM_LIBC "Set to on to link all LLVM executables against LLVM libc, assuming it is accessible by the host compiler." OFF)
 594 option(LLVM_STATIC_LINK_CXX_STDLIB "Statically link the standard library." OFF)
 595 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 596 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 597 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 598
 599 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 600 option(LLVM_UNREACHABLE_OPTIMIZE "Optimize llvm_unreachable() as undefined behavior (default), guaranteed trap when OFF" ON)
 601
 602 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 603   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 604 else()
 605   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 606 endif()
 607
 608 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 609
 610 # While adding scalable vector support to LLVM, we temporarily want to
 611 # allow an implicit conversion of TypeSize to uint64_t, and to allow
 612 # code to get the fixed number of elements from a possibly scalable vector.
 613 # This CMake flag enables a more strict mode where it asserts that the type
 614 # is not a scalable vector type.
 615 #
 616 # Enabling this flag makes it easier to find cases where the compiler makes
 617 # assumptions on the size being 'fixed size', when building tests for
 618 # SVE/SVE2 or other scalable vector architectures.
 619 option(LLVM_ENABLE_STRICT_FIXED_SIZE_VECTORS
 620        "Enable assertions that type is not scalable in implicit conversion from TypeSize to uint64_t and calls to getNumElements" OFF)
 621
 622 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 623   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 624
 625 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 626        "Set to ON to force using an old, unsupported host toolchain." OFF)
 627
 628 set(LLVM_LOCAL_RPATH "" CACHE FILEPATH
 629   "If set, an absolute path added as rpath on binaries that do not already contain an executable-relative rpath.")
 630
 631 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 632        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 633
 634 option(LLVM_USE_INTEL_JITEVENTS
 635   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 636   OFF)
 637
 638 if( LLVM_USE_INTEL_JITEVENTS )
 639   # Verify we are on a supported platform
 640   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 641     message(FATAL_ERROR
 642       "Intel JIT API support is available on Linux and Windows only.")
 643   endif()
 644 endif( LLVM_USE_INTEL_JITEVENTS )
 645
 646 option(LLVM_USE_OPROFILE
 647   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 648
 649 option(LLVM_EXTERNALIZE_DEBUGINFO
 650   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 651
 652 option(LLVM_EXPERIMENTAL_DEBUGINFO_ITERATORS
 653   "Add extra Booleans to ilist_iterators to communicate facts for debug-info" OFF)
 654
 655 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 656   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 657
 658 # If enabled, verify we are on a platform that supports oprofile.
 659 if( LLVM_USE_OPROFILE )
 660   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 661     message(FATAL_ERROR "OProfile support is available on Linux only.")
 662   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 663 endif( LLVM_USE_OPROFILE )
 664
 665 option(LLVM_USE_PERF
 666   "Use perf JIT interface to inform perf about JIT code" OFF)
 667
 668 # If enabled, verify we are on a platform that supports perf.
 669 if( LLVM_USE_PERF )
 670   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 671     message(FATAL_ERROR "perf support is available on Linux only.")
 672   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 673 endif( LLVM_USE_PERF )
 674
 675 set(LLVM_USE_SANITIZER "" CACHE STRING
 676   "Define the sanitizer used to build binaries and tests.")
 677 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 678 set(LLVM_UBSAN_FLAGS
 679     "-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 680     CACHE STRING
 681     "Compile flags set to enable UBSan. Only used if LLVM_USE_SANITIZER contains 'Undefined'.")
 682 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 683   "Path to fuzzing library for linking with fuzz targets")
 684
 685 option(LLVM_USE_SPLIT_DWARF
 686   "Use -gsplit-dwarf when compiling llvm and --gdb-index when linking." OFF)
 687
 688 # Define an option controlling whether we should build for 32-bit on 64-bit
 689 # platforms, where supported.
 690 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT (WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX"))
 691   # TODO: support other platforms and toolchains.
 692   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 693 endif()
 694
 695 # Define the default arguments to use with 'lit', and an option for the user to
 696 # override.
 697 set(LIT_ARGS_DEFAULT "-sv")
 698 if (MSVC_IDE OR XCODE)
 699   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 700 endif()
 701 if(LLVM_INDIVIDUAL_TEST_COVERAGE)
 702    set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --per-test-coverage")
 703 endif()
 704 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 705
 706 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 707 if( WIN32 AND NOT CYGWIN )
 708   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 709 endif()
 710 set(LLVM_NATIVE_TOOL_DIR "" CACHE PATH "Path to a directory containing prebuilt matching native tools (such as llvm-tblgen)")
 711
 712 set(LLVM_INTEGRATED_CRT_ALLOC "" CACHE PATH "Replace the Windows CRT allocator with any of {rpmalloc|mimalloc|snmalloc}. Only works with CMAKE_MSVC_RUNTIME_LIBRARY=MultiThreaded.")
 713 if(LLVM_INTEGRATED_CRT_ALLOC)
 714   if(NOT WIN32)
 715     message(FATAL_ERROR "LLVM_INTEGRATED_CRT_ALLOC is only supported on Windows.")
 716   endif()
 717   if(LLVM_USE_SANITIZER)
 718     message(FATAL_ERROR "LLVM_INTEGRATED_CRT_ALLOC cannot be used along with LLVM_USE_SANITIZER!")
 719   endif()
 720   if(CMAKE_BUILD_TYPE AND uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 721     message(FATAL_ERROR "The Debug target isn't supported along with LLVM_INTEGRATED_CRT_ALLOC!")
 722   endif()
 723 endif()
 724
 725 # Define options to control the inclusion and default build behavior for
 726 # components which may not strictly be necessary (tools, examples, and tests).
 727 #
 728 # This is primarily to support building smaller or faster project files.
 729 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 730 option(LLVM_BUILD_TOOLS
 731   "Build the LLVM tools. If OFF, just generate build targets." ON)
 732
 733 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 734 option(LLVM_BUILD_UTILS
 735   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 736
 737 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 738 option(LLVM_BUILD_RUNTIMES
 739   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 740
 741 option(LLVM_BUILD_RUNTIME
 742   "Build the LLVM runtime libraries." ON)
 743 option(LLVM_BUILD_EXAMPLES
 744   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 745 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 746
 747 if(LLVM_BUILD_EXAMPLES)
 748   add_compile_definitions(BUILD_EXAMPLES)
 749 endif(LLVM_BUILD_EXAMPLES)
 750
 751 option(LLVM_BUILD_TESTS
 752   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 753 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 754
 755 option(LLVM_INSTALL_GTEST
 756   "Install the llvm gtest library.  This should be on if you want to do
 757    stand-alone builds of the other projects and run their unit tests." OFF)
 758
 759 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 760 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 761 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 762
 763 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 764 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 765 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 766 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 767 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 768 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 769
 770 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "${CMAKE_INSTALL_DOCDIR}/llvm/doxygen-html"
 771     CACHE STRING "Doxygen-generated HTML documentation install directory")
 772 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "${CMAKE_INSTALL_DOCDIR}/llvm/ocaml-html"
 773     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 774
 775 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 776   "Build compiler-rt as an external project." OFF)
 777
 778 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 779   "Show target and host info when tools are invoked with --version." ON)
 780
 781 # You can configure which libraries from LLVM you want to include in the
 782 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 783 # list of LLVM components. All component names handled by llvm-config are valid.
 784 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 785   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 786     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 787 endif()
 788
 789 if(MSVC)
 790   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 791   # Set this variable to OFF here so it can't be set with a command-line
 792   # argument.
 793   set (LLVM_LINK_LLVM_DYLIB OFF)
 794   if (BUILD_SHARED_LIBS)
 795     message(FATAL_ERROR "BUILD_SHARED_LIBS options is not supported on Windows.")
 796   endif()
 797 else()
 798   option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 799   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 800   set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 801   if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 802     set(LLVM_BUILD_LLVM_DYLIB_default ON)
 803   endif()
 804   option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 805 endif()
 806
 807 if (LLVM_LINK_LLVM_DYLIB AND BUILD_SHARED_LIBS)
 808   message(FATAL_ERROR "Cannot enable BUILD_SHARED_LIBS with LLVM_LINK_LLVM_DYLIB.  We recommend disabling BUILD_SHARED_LIBS.")
 809 endif()
 810
 811 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 812 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 813   set(LLVM_USE_HOST_TOOLS ON)
 814 endif()
 815
 816 option(LLVM_OMIT_DAGISEL_COMMENTS "Do not add comments to DAG ISel" ON)
 817 if (CMAKE_BUILD_TYPE AND uppercase_CMAKE_BUILD_TYPE MATCHES "^(RELWITHDEBINFO|DEBUG)$")
 818   set(LLVM_OMIT_DAGISEL_COMMENTS OFF)
 819 endif()
 820
 821 if (MSVC_IDE)
 822   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 823 endif()
 824
 825 if(NOT LLVM_INDIVIDUAL_TEST_COVERAGE)
 826   if(LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR LLVM_ENABLE_IR_PGO)
 827     if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 828       # A pool size of 1-2 is probably sufficient on an SSD. 3-4 should be fine
 829       # for spinning disks. Anything higher may only help on slower mediums.
 830       set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 831     endif()
 832     if(NOT LLVM_PROFILE_FILE_PATTERN)
 833       if(NOT LLVM_PROFILE_DATA_DIR)
 834         file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 835       endif()
 836       file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 837     endif()
 838     if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 839       if(NOT LLVM_CSPROFILE_DATA_DIR)
 840         file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 841       endif()
 842       file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 843     endif()
 844   endif()
 845 endif()
 846
 847 if (LLVM_BUILD_STATIC)
 848   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 849   # Remove shared library suffixes from use in find_library
 850   foreach (shared_lib_suffix ${CMAKE_SHARED_LIBRARY_SUFFIX} ${CMAKE_IMPORT_LIBRARY_SUFFIX})
 851     list(FIND CMAKE_FIND_LIBRARY_SUFFIXES ${shared_lib_suffix} shared_lib_suffix_idx)
 852     if(NOT ${shared_lib_suffix_idx} EQUAL -1)
 853       list(REMOVE_AT CMAKE_FIND_LIBRARY_SUFFIXES ${shared_lib_suffix_idx})
 854     endif()
 855   endforeach()
 856 endif()
 857
 858 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 859 if(CMAKE_HOST_APPLE AND APPLE)
 860   include(UseLibtool)
 861 endif()
 862
 863 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 864 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 865 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 866
 867 if(CMAKE_SYSTEM_NAME MATCHES "BSD|Linux|OS390")
 868   set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR_default ON)
 869 else()
 870   set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR_default OFF)
 871 endif()
 872 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR ${LLVM_ENABLE_PER_TARGET_RUNTIME_DIR_default} CACHE BOOL
 873   "Enable per-target runtimes directory")
 874
 875 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 876   "Profiling data file to use when compiling in order to improve runtime performance.")
 877
 878 if(LLVM_INCLUDE_TESTS)
 879   # Lit test suite requires at least python 3.6
 880   set(LLVM_MINIMUM_PYTHON_VERSION 3.6)
 881 else()
 882   # FIXME: it is unknown if this is the actual minimum bound
 883   set(LLVM_MINIMUM_PYTHON_VERSION 3.0)
 884 endif()
 885
 886 # Find python before including config-ix, since it needs to be able to search
 887 # for python modules.
 888 find_package(Python3 ${LLVM_MINIMUM_PYTHON_VERSION} REQUIRED
 889     COMPONENTS Interpreter)
 890
 891 # All options referred to from HandleLLVMOptions have to be specified
 892 # BEFORE this include, otherwise options will not be correctly set on
 893 # first cmake run
 894 include(config-ix)
 895
 896 # By default, we target the host, but this can be overridden at CMake
 897 # invocation time. Except on 64-bit AIX, where the system toolchain
 898 # expect 32-bit objects by default.
 899 if("${LLVM_HOST_TRIPLE}" MATCHES "^powerpc64-ibm-aix")
 900   string(REGEX REPLACE "^powerpc64" "powerpc" LLVM_DEFAULT_TARGET_TRIPLE_DEFAULT "${LLVM_HOST_TRIPLE}")
 901 else()
 902   # Only set default triple when native target is enabled.
 903   if (LLVM_NATIVE_TARGET)
 904     set(LLVM_DEFAULT_TARGET_TRIPLE_DEFAULT "${LLVM_HOST_TRIPLE}")
 905   endif()
 906 endif()
 907
 908 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE_DEFAULT}" CACHE STRING
 909     "Default target for which LLVM will generate code." )
 910 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 911
 912 set(LLVM_TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 913
 914 if(WIN32 OR CYGWIN)
 915   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 916     set(LLVM_ENABLE_PLUGINS_default ON)
 917   else()
 918     set(LLVM_ENABLE_PLUGINS_default OFF)
 919   endif()
 920 else()
 921   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 922 endif()
 923 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 924
 925 set(LLVM_ENABLE_NEW_PASS_MANAGER TRUE CACHE BOOL
 926   "Enable the new pass manager by default.")
 927 if(NOT LLVM_ENABLE_NEW_PASS_MANAGER)
 928   message(FATAL_ERROR "Enabling the legacy pass manager on the cmake level is"
 929                       " no longer supported.")
 930 endif()
 931
 932 include(HandleLLVMOptions)
 933
 934 ######
 935
 936 # Configure all of the various header file fragments LLVM uses which depend on
 937 # configuration variables.
 938 set(LLVM_ENUM_TARGETS "")
 939 set(LLVM_ENUM_ASM_PRINTERS "")
 940 set(LLVM_ENUM_ASM_PARSERS "")
 941 set(LLVM_ENUM_DISASSEMBLERS "")
 942 set(LLVM_ENUM_TARGETMCAS "")
 943 set(LLVM_ENUM_EXEGESIS "")
 944 foreach(t ${LLVM_TARGETS_TO_BUILD})
 945   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 946
 947   # Make sure that any experimental targets were passed via
 948   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 949   # We allow experimental targets that are not in LLVM_ALL_EXPERIMENTAL_TARGETS,
 950   # as long as they are passed via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.
 951   if ( NOT "${t}" IN_LIST LLVM_ALL_TARGETS AND NOT "${t}" IN_LIST LLVM_EXPERIMENTAL_TARGETS_TO_BUILD )
 952     if( "${t}" IN_LIST LLVM_ALL_EXPERIMENTAL_TARGETS )
 953       message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 954         "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 955     else()
 956       message(FATAL_ERROR "The target `${t}' is not a core tier target. It may be "
 957         "experimental, if so it must be passed via "
 958         "LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.\n"
 959         "Core tier targets: ${LLVM_ALL_TARGETS}\n"
 960         "Known experimental targets: ${LLVM_ALL_EXPERIMENTAL_TARGETS}")
 961     endif()
 962   else()
 963     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 964     string(TOUPPER ${t} T_UPPER)
 965     set(LLVM_HAS_${T_UPPER}_TARGET 1)
 966   endif()
 967
 968   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 969   if( asmp_file )
 970     set(LLVM_ENUM_ASM_PRINTERS
 971       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 972   endif()
 973   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 974     set(LLVM_ENUM_ASM_PARSERS
 975       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 976   endif()
 977   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 978     set(LLVM_ENUM_DISASSEMBLERS
 979       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 980   endif()
 981   if( EXISTS ${td}/MCA/CMakeLists.txt )
 982     set(LLVM_ENUM_TARGETMCAS
 983       "${LLVM_ENUM_TARGETMCAS}LLVM_TARGETMCA(${t})\n")
 984   endif()
 985   if( EXISTS ${LLVM_MAIN_SRC_DIR}/tools/llvm-exegesis/lib/${t}/CMakeLists.txt )
 986     set(LLVM_ENUM_EXEGESIS
 987       "${LLVM_ENUM_EXEGESIS}LLVM_EXEGESIS(${t})\n")
 988   endif()
 989 endforeach(t)
 990
 991 # Provide an LLVM_ namespaced alias for use in #cmakedefine.
 992 set(LLVM_BUILD_SHARED_LIBS ${BUILD_SHARED_LIBS})
 993
 994 # Produce the target definition files, which provide a way for clients to easily
 995 # include various classes of targets.
 996 configure_file(
 997   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 998   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 999   )
1000 configure_file(
1001   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
1002   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
1003   )
1004 configure_file(
1005   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
1006   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
1007   )
1008 configure_file(
1009   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
1010   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
1011   )
1012 configure_file(
1013   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/TargetMCAs.def.in
1014   ${LLVM_INCLUDE_DIR}/llvm/Config/TargetMCAs.def
1015   )
1016 configure_file(
1017   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/TargetExegesis.def.in
1018   ${LLVM_INCLUDE_DIR}/llvm/Config/TargetExegesis.def
1019   )
1020
1021 # They are not referenced. See set_output_directory().
1022 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
1023 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_LIBRARY_DIR} )
1024 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_LIBRARY_DIR} )
1025
1026 # For up-to-date instructions for installing the TFLite dependency, refer to
1027 # the bot setup script: https://github.com/google/ml-compiler-opt/blob/main/buildbot/buildbot_init.sh
1028 set(LLVM_HAVE_TFLITE "" CACHE BOOL "Use tflite")
1029 if (LLVM_HAVE_TFLITE)
1030   find_package(tensorflow-lite REQUIRED)
1031 endif()
1032
1033 # For up-to-date instructions for installing the Tensorflow dependency, refer to
1034 # the bot setup script: https://github.com/google/ml-compiler-opt/blob/main/buildbot/buildbot_init.sh
1035 # Specifically, assuming python3 is installed:
1036 # python3 -m pip install --upgrade pip && python3 -m pip install --user tf_nightly==2.3.0.dev20200528
1037 # Then set TENSORFLOW_AOT_PATH to the package install - usually it's ~/.local/lib/python3.7/site-packages/tensorflow
1038 #
1039 set(TENSORFLOW_AOT_PATH "" CACHE PATH "Path to TensorFlow pip install dir")
1040
1041 if (NOT TENSORFLOW_AOT_PATH STREQUAL "")
1042   set(LLVM_HAVE_TF_AOT "ON" CACHE BOOL "Tensorflow AOT available")
1043   set(TENSORFLOW_AOT_COMPILER
1044     "${TENSORFLOW_AOT_PATH}/../../../../bin/saved_model_cli"
1045     CACHE PATH "Path to the Tensorflow AOT compiler")
1046   include_directories(${TENSORFLOW_AOT_PATH}/include)
1047   add_subdirectory(${TENSORFLOW_AOT_PATH}/xla_aot_runtime_src
1048     ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/tf_runtime)
1049   install(TARGETS tf_xla_runtime EXPORT LLVMExports
1050     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX} COMPONENT tf_xla_runtime)
1051   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS tf_xla_runtime)
1052   # Once we add more modules, we should handle this more automatically.
1053   if (DEFINED LLVM_OVERRIDE_MODEL_HEADER_INLINERSIZEMODEL)
1054     set(LLVM_INLINER_MODEL_PATH "none")
1055   elseif(NOT DEFINED LLVM_INLINER_MODEL_PATH
1056       OR "${LLVM_INLINER_MODEL_PATH}" STREQUAL ""
1057       OR "${LLVM_INLINER_MODEL_PATH}" STREQUAL "autogenerate")
1058     set(LLVM_INLINER_MODEL_PATH "autogenerate")
1059     set(LLVM_INLINER_MODEL_AUTOGENERATED 1)
1060   endif()
1061   if (DEFINED LLVM_OVERRIDE_MODEL_HEADER_REGALLOCEVICTMODEL)
1062     set(LLVM_RAEVICT_MODEL_PATH "none")
1063   elseif(NOT DEFINED LLVM_RAEVICT_MODEL_PATH
1064       OR "${LLVM_RAEVICT_MODEL_PATH}" STREQUAL ""
1065       OR "${LLVM_RAEVICT_MODEL_PATH}" STREQUAL "autogenerate")
1066     set(LLVM_RAEVICT_MODEL_PATH "autogenerate")
1067     set(LLVM_RAEVICT_MODEL_AUTOGENERATED 1)
1068   endif()
1069
1070 endif()
1071
1072 # Configure the three LLVM configuration header files.
1073 configure_file(
1074   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
1075   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
1076 configure_file(
1077   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
1078   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
1079 configure_file(
1080   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
1081   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
1082
1083 # Add target for generating source rpm package.
1084 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
1085     CACHE FILEPATH ".spec file to use for srpm generation")
1086 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
1087 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
1088
1089 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
1090 string(LENGTH "${revision}" revision_length)
1091 set(LLVM_RPM_SPEC_REVISION "${revision}")
1092
1093 configure_file(
1094   ${LLVM_SRPM_USER_BINARY_SPECFILE}
1095   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
1096
1097 add_custom_target(srpm
1098   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
1099   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
1100 set_target_properties(srpm PROPERTIES FOLDER "Misc")
1101
1102 if(APPLE AND DARWIN_LTO_LIBRARY)
1103   set(CMAKE_EXE_LINKER_FLAGS
1104     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
1105   set(CMAKE_SHARED_LINKER_FLAGS
1106     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
1107   set(CMAKE_MODULE_LINKER_FLAGS
1108     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
1109 endif()
1110
1111 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
1112 # break things. In this case we need to enable the large-file API as well.
1113 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
1114           add_compile_definitions(_XOPEN_SOURCE=700)
1115           add_compile_definitions(_LARGE_FILE_API)
1116
1117   # Modules should be built with -shared -Wl,-G, so we can use runtime linking
1118   # with plugins.
1119   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -shared -Wl,-G")
1120
1121   # Also set the correct flags for building shared libraries.
1122   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -shared")
1123 endif()
1124
1125 # Build with _XOPEN_SOURCE on z/OS.
1126 if (CMAKE_SYSTEM_NAME MATCHES "OS390")
1127   add_compile_definitions(_XOPEN_SOURCE=600)
1128   add_compile_definitions(_OPEN_SYS) # Needed for process information.
1129   add_compile_definitions(_OPEN_SYS_FILE_EXT) # Needed for EBCDIC I/O.
1130 endif()
1131
1132 # Build with _FILE_OFFSET_BITS=64 on Solaris to match g++ >= 9.
1133 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
1134           add_compile_definitions(_FILE_OFFSET_BITS=64)
1135 endif()
1136
1137 set(CMAKE_INCLUDE_CURRENT_DIR ON)
1138
1139 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
1140
1141 # when crosscompiling import the executable targets from a file
1142 if(LLVM_USE_HOST_TOOLS)
1143   include(CrossCompile)
1144   llvm_create_cross_target(LLVM NATIVE "" Release)
1145 endif(LLVM_USE_HOST_TOOLS)
1146 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
1147 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
1148 # (this is a variable that CrossCompile sets on recursive invocations)
1149 endif()
1150
1151 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
1152    # special hack for Solaris to handle crazy system sys/regset.h
1153    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
1154 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
1155
1156 # Make sure we don't get -rdynamic in every binary. For those that need it,
1157 # use export_executable_symbols(target).
1158 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
1159
1160 include(AddLLVM)
1161 include(TableGen)
1162
1163 include(LLVMDistributionSupport)
1164
1165 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
1166   # People report that -O3 is unreliable on MinGW. The traditional
1167   # build also uses -O2 for that reason:
1168   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
1169 endif()
1170
1171 if(LLVM_INCLUDE_TESTS)
1172   umbrella_lit_testsuite_begin(check-all)
1173 endif()
1174
1175 # Put this before tblgen. Else we have a circular dependence.
1176 add_subdirectory(lib/Demangle)
1177 add_subdirectory(lib/Support)
1178 add_subdirectory(lib/TableGen)
1179
1180 add_subdirectory(utils/TableGen)
1181
1182 add_subdirectory(include)
1183
1184 add_subdirectory(lib)
1185
1186 if( LLVM_INCLUDE_UTILS )
1187   add_subdirectory(utils/FileCheck)
1188   add_subdirectory(utils/PerfectShuffle)
1189   add_subdirectory(utils/count)
1190   add_subdirectory(utils/not)
1191   add_subdirectory(utils/UnicodeData)
1192   add_subdirectory(utils/yaml-bench)
1193   add_subdirectory(utils/split-file)
1194   if( LLVM_INCLUDE_TESTS )
1195     add_subdirectory(${LLVM_THIRD_PARTY_DIR}/unittest ${CMAKE_CURRENT_BINARY_DIR}/third-party/unittest)
1196   endif()
1197 else()
1198   if ( LLVM_INCLUDE_TESTS )
1199     message(FATAL_ERROR "Including tests when not building utils will not work.
1200     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
1201   endif()
1202 endif()
1203
1204 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
1205 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
1206   add_subdirectory(utils/LLVMVisualizers)
1207 endif()
1208
1209 foreach( binding ${LLVM_BINDINGS_LIST} )
1210   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
1211     add_subdirectory(bindings/${binding})
1212   endif()
1213 endforeach()
1214
1215 add_subdirectory(projects)
1216
1217 if( LLVM_INCLUDE_TOOLS )
1218   add_subdirectory(tools)
1219 endif()
1220
1221 if( LLVM_INCLUDE_RUNTIMES )
1222   add_subdirectory(runtimes)
1223 endif()
1224
1225 if( LLVM_INCLUDE_EXAMPLES )
1226   add_subdirectory(examples)
1227 endif()
1228
1229 if( LLVM_INCLUDE_TESTS )
1230   set(LLVM_GTEST_RUN_UNDER
1231     "" CACHE STRING
1232     "Define the wrapper program that LLVM unit tests should be run under.")
1233   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
1234     include(LLVMExternalProjectUtils)
1235     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
1236       USE_TOOLCHAIN
1237       EXCLUDE_FROM_ALL
1238       NO_INSTALL
1239       ALWAYS_CLEAN)
1240   endif()
1241   add_subdirectory(utils/lit)
1242   add_subdirectory(test)
1243   add_subdirectory(unittests)
1244
1245   if (WIN32)
1246     # This utility is used to prevent crashing tests from calling Dr. Watson on
1247     # Windows.
1248     add_subdirectory(utils/KillTheDoctor)
1249   endif()
1250
1251   umbrella_lit_testsuite_end(check-all)
1252   get_property(LLVM_ALL_LIT_DEPENDS GLOBAL PROPERTY LLVM_ALL_LIT_DEPENDS)
1253   get_property(LLVM_ALL_ADDITIONAL_TEST_DEPENDS
1254       GLOBAL PROPERTY LLVM_ALL_ADDITIONAL_TEST_DEPENDS)
1255   add_custom_target(test-depends
1256       DEPENDS ${LLVM_ALL_LIT_DEPENDS} ${LLVM_ALL_ADDITIONAL_TEST_DEPENDS})
1257   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
1258   add_dependencies(check-all test-depends)
1259 endif()
1260
1261 if (LLVM_INCLUDE_DOCS)
1262   add_subdirectory(docs)
1263 endif()
1264
1265 add_subdirectory(cmake/modules)
1266
1267 # Do this last so that all lit targets have already been created.
1268 if (LLVM_INCLUDE_UTILS)
1269   add_subdirectory(utils/llvm-lit)
1270 endif()
1271
1272 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1273   install(DIRECTORY include/llvm include/llvm-c
1274     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1275     COMPONENT llvm-headers
1276     FILES_MATCHING
1277     PATTERN "*.def"
1278     PATTERN "*.h"
1279     PATTERN "*.td"
1280     PATTERN "*.inc"
1281     PATTERN "LICENSE.TXT"
1282     )
1283
1284   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1285     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1286     COMPONENT llvm-headers
1287     FILES_MATCHING
1288     PATTERN "*.def"
1289     PATTERN "*.h"
1290     PATTERN "*.gen"
1291     PATTERN "*.inc"
1292     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1293     PATTERN "CMakeFiles" EXCLUDE
1294     PATTERN "config.h" EXCLUDE
1295     )
1296
1297   if (LLVM_INSTALL_MODULEMAPS)
1298     install(DIRECTORY include
1299             DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1300             COMPONENT llvm-headers
1301             FILES_MATCHING
1302             PATTERN "module.modulemap"
1303             )
1304     install(FILES include/module.install.modulemap
1305             DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
1306             COMPONENT llvm-headers
1307             RENAME "module.extern.modulemap"
1308             )
1309   endif(LLVM_INSTALL_MODULEMAPS)
1310
1311   # Installing the headers needs to depend on generating any public
1312   # tablegen'd headers.
1313   add_custom_target(llvm-headers DEPENDS intrinsics_gen omp_gen)
1314   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1315
1316   if (NOT LLVM_ENABLE_IDE)
1317     add_llvm_install_targets(install-llvm-headers
1318                              DEPENDS llvm-headers
1319                              COMPONENT llvm-headers)
1320   endif()
1321
1322   # Custom target to install all libraries.
1323   add_custom_target(llvm-libraries)
1324   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1325
1326   if (NOT LLVM_ENABLE_IDE)
1327     add_llvm_install_targets(install-llvm-libraries
1328                              DEPENDS llvm-libraries
1329                              COMPONENT llvm-libraries)
1330   endif()
1331
1332   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1333   if(LLVM_LIBS)
1334     list(REMOVE_DUPLICATES LLVM_LIBS)
1335     foreach(lib ${LLVM_LIBS})
1336       add_dependencies(llvm-libraries ${lib})
1337       if (NOT LLVM_ENABLE_IDE)
1338         add_dependencies(install-llvm-libraries install-${lib})
1339         add_dependencies(install-llvm-libraries-stripped install-${lib}-stripped)
1340       endif()
1341     endforeach()
1342   endif()
1343 endif()
1344
1345 # This must be at the end of the LLVM root CMakeLists file because it must run
1346 # after all targets are created.
1347 llvm_distribution_add_targets()
1348 process_llvm_pass_plugins(GEN_CONFIG)
1349 include(CoverageReport)
1350
1351 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1352 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1353   include(InstallRequiredSystemLibraries)
1354 endif()
1355
1356 if (LLVM_INCLUDE_BENCHMARKS)
1357   # Override benchmark defaults so that when the library itself is updated these
1358   # modifications are not lost.
1359   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1360   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1361   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1362   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1363   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1364   set(BENCHMARK_ENABLE_WERROR ${LLVM_ENABLE_WERROR} CACHE BOOL
1365     "Handle -Werror for Google Benchmark based on LLVM_ENABLE_WERROR" FORCE)
1366   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1367   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1368   add_subdirectory(${LLVM_THIRD_PARTY_DIR}/benchmark
1369     ${CMAKE_CURRENT_BINARY_DIR}/third-party/benchmark)
1370   add_subdirectory(benchmarks)
1371 endif()
1372
1373 if (LLVM_INCLUDE_UTILS AND LLVM_INCLUDE_TOOLS)
1374   add_subdirectory(utils/llvm-locstats)
1375 endif()